Formel gesucht: beste Zweitplatzierte Mannschaft gesucht

[Jobi81]

Hallo Forum

Ich arbeite aktuell an einer Excel-Tabelle und komme an einer Formel nicht weiter.

Zur Ausgangssituation:
Es geht um ein Fußballturnier mit 3 Gruppen a 4 Mannschaften. Diese spielen in der Vorrunde gegeneinander. Anschließend werden die Gruppen neu gemischt und zwar in der Form, dass die drei Erstplatzierten in eine Gruppe kommen sowie der beste Zweitplatzierte.
In die nächste Gruppe kommen die anderen beiden Zweitplatzierten sowie die zwei der besten Drittplatzierten und in die letzte Gruppe kommt der schlechteste Dritte sowie alle Letztplatzierten (Ich hoffe das war verständlich )
Die Berechnung soll im ersten Schritt nach den erzielten Punkten gehen und anschließend nach den erzielten Toren.
Durch eine Hintergrundberechnung habe ich bereits den Tabellenstand mit einem Wert ermittelt, der die Punkte und Tore berechnet.

Im Prinzip möchte ich EXCEL sagen, dass mir aus den drei Tabellen der höchsten Wert heraussucht wird und dann den Namen dazu ausweist. Das Gleiche dann für den zweithöchsten Wert usw...
Vermutlich kann ich mich am Besten auf die Zahlen unter dem Wert "Tore Differenz" beziehen, der nicht farblich unterlegt ist.

Vielen Dank für die Hilfe.
Tobias

[BoskoBiati]

Hallo,

Deine Bildchen sind absolut nicht hilfreich! Stelle die Datei vor.

[Jobi81]

Ist hochgeladen!

[Jockel]

Hallo, schau mal hier --> http://www.herber.de/excelformeln und bitte suchen .../formeln.html?welcher=283 das geht doch in deine Richtung, oder?

[Jockel]

Hallo, meine Vermutung scheint's ja nicht ganz zu treffen, aber trotzdem geht's scheinbar hier --> http://www.office-loesung.de/p/viewtopic.php?f=166&t=749410 weiter; damit bin ich raus...

[shift-del]

Tobias,

ein wenig inspiriert vom Vorschlag von slowboarder bei OL.

	A	B	C	D	E	F	G	H
1
2	ID1	ID2	Spieler1	Spieler2	Tore S1	Tore S2	Punkte S1	Punkte S2
3	1	2	Fritz	Peter	2	2	1	1
4	3	4	Max	Bill	1	0	3	0
5	1	3	Fritz	Max	2	4	0	3
6	2	4	Peter	Bill	2	0	3	0
7	1	4	Fritz	Bill	1	0	3	0
8	2	3	Peter	Max	3	1	3	0
9
10	ID1	ID2	Spieler	Punkte	Tordiff.		Platz
11	1		Fritz	4	-1	3,9999	3	2003,9999
12	2		Peter	7	4	7,0004	1	4007,0004
13	3		Max	6	1	6,0001	2	3006,0001
14	4		Bill	0	-4	-0,0004	4	999,9996
15
16
17	ID1	ID2	Spieler1	Spieler2	Tore S1	Tore S2	Punkte S1	Punkte S2
18	1	2	Horst	Doris	7	4	3	0
19	3	4	Norbert	Rita	3	3	1	1
20	1	3	Horst	Norbert	3	2	3	0
21	2	4	Doris	Rita	2	3	0	3
22	1	4	Horst	Rita	1	2	0	3
23	2	3	Doris	Norbert	2	2	1	1
24
25	ID1	ID2	Spieler	Punkte	Tordiff.		Platz
26	1		Horst	6	3	6,0003	2	3006,0003
27	2		Doris	1	-4	0,9996	4	1000,9996
28	3		Norbert	2	-1	1,9999	3	2001,9999
29	4		Rita	7	2	7,0002	1	4007,0002
30
31
32	ID1	ID2	Spieler1	Spieler2	Tore S1	Tore S2	Punkte S1	Punkte S2
33	1	2	Tina	Erwin	3	2	3	0
34	3	4	Jochen	Klaus	1	1	1	1
35	1	3	Tina	Jochen	4	2	3	0
36	2	4	Erwin	Klaus	6	4	3	0
37	1	4	Tina	Klaus	0	3	0	3
38	2	3	Erwin	Jochen	1	1	1	1
39
40	ID1	ID2	Spieler	Punkte	Tordiff.		Platz
41	1		Tina	6	0	6	1	4006
42	2		Erwin	4	1	4,0001	2	3004,0001
43	3		Jochen	2	-2	1,9998	4	1001,9998
44	4		Klaus	4	1	4,0001	2	3004,0001
45
46
47	Qualifiziert für die nächste Runde:
48
49			Spieler	Gruppe
50	1	11	Peter	Gruppe A				4007,0004
51	2	28	Rita	Gruppe B				4007,0002
52	3	40	Tina	Gruppe C				4006
53	4	25	Horst	Gruppe B				3006,0003

Zelle	Formel
C3	=INDEX(Gruppenauslosung!$B$3:$B$6;A3)
D3	=INDEX(Gruppenauslosung!$B$3:$B$6;B3)
G3	=SUMME(ZÄHLENWENN(E3;{"<";"=";">"}&F3)*{0;1;3})
H3	=SUMME(ZÄHLENWENN(F3;{"<";"=";">"}&E3)*{0;1;3})
C11	=INDEX(Gruppenauslosung!$B$3:$B$6;A11)
D11	=SUMMEWENNS($G$3:$G$8;$C$3:$C$8;C11)+SUMMEWENNS($H$3:$H$8;$D$3:$D$8;C11)
E11	=SUMMEWENNS($E$3:$E$8;$C$3:$C$8;C11)-SUMMEWENNS($F$3:$F$8;$C$3:$C$8;C11)+SUMMEWENNS($F$3:$F$8;$D$3:$D$8;C11)-SUMMEWENNS($E$3:$E$8;$D$3:$D$8;C11)
F11	=D11+E11%%
G11	=RANG.GLEICH(F11;$F$11:$F$14)
H11	=(5-G11) *1000 + F11
B50	=VERGLEICH(H50;$H$2:$H$44;0)
C50	=INDEX($C$2:$C$44;B50)
D50	=VERWEIS(B50;{1;16;31};{"Gruppe A";"Gruppe B";"Gruppe C"})
H50	=KGRÖSSTE(($H$11:$H$14;$H$26:$H$29;$H$41:$H$44);A50)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Die Formeln der Blöcke 2 und 3 sind analog zu Block 1.

[Jobi81]

Habe eine Lösung gefunden. Thema kann geschlossen werden.
Danke.

[Jockel]

Hallo, vielleicht verrätst du noch die Quelle..? Auf jeden Fall ist das unten verbesserungswürdig..:

Arbeitsblatt mit dem Namen 'Vorrunde'
	I
5	5
6	4
7	1
8	2
9	3
10	0

Zelle	Formel
I5	=WENN(N5>N6;1;0)+WENN(N5>N7;1;0)+WENN(N5>N8;1;0)+WENN(N5>N9;1;0)+WENN(N5>N10;1;0)
I6	=WENN(N6>N5;1;0)+WENN(N6>N7;1;0)+WENN(N6>N8;1;0)+WENN(N6>N9;1;0)+WENN(N6>N10;1;0)
I7	=WENN(N7>N5;1;0)+WENN(N7>N6;1;0)+WENN(N7>N8;1;0)+WENN(N7>N9;1;0)+WENN(N7>N10;1;0)
I8	=WENN(N8>N5;1;0)+WENN(N8>N6;1;0)+WENN(N8>N7;1;0)+WENN(N8>N9;1;0)+WENN(N8>N10;1;0)
I9	=WENN(N9>N5;1;0)+WENN(N9>N6;1;0)+WENN(N9>N7;1;0)+WENN(N9>N8;1;0)+WENN(N9>N10;1;0)
I10	=WENN(N10>N5;1;0)+WENN(N10>N6;1;0)+WENN(N10>N7;1;0)+WENN(N10>N8;1;0)+WENN(N10>N9;1;0)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Jobi81]

Es gibt quasi keine Quelle. Das ist aus meinem eigenen Mist gewachsen.

Ich habe den Turniermodus verändert, so dass das "Ursprungsproblem" nicht mehr das Thema ist. Aus drei Gruppen habe ich zwei gemacht. Dann kam ich mit meinen eigenen Kenntnissen weiter, obwohl das sicherlich nicht optimal ist, wie du schon geschrieben hast. Es funktioniert zumindest...