Formel bei 0 Wert funktioniert nicht

[samsamsam]

Hallo zusammen,

 ich wollte gerne eine Formel schreiben, die die Wichtigkeit anzeigt.

ich habe das geschafft.
=WENN(ISTZAHL([@[Erledigt am:]]);"4 Erledigt";WENN(ODER(ZAHLENWERT([@[Deadline in Tage ]])<0; UND(ZAHLENWERT([@[Deadline in Tage ]])>0; (ZAHLENWERT([@[Deadline in Tage ]])<4))); "1 Sehr Wichtig ";WENN(UND(ZAHLENWERT([@[Deadline in Tage ]]) >3;ZAHLENWERT([@[Deadline in Tage ]])<18);"2 Wichtig";WENN(UND(ZAHLENWERT([@[Deadline in Tage ]]) > 17;ZAHLENWERT([@[Deadline in Tage ]])<32);"3 Normal";""))))

Leider bekomme ich es einfach nicht hin das die 0 auch "1 sehr wichtig" bekommt.

Wenn ich bei "deatline in Tagen" ein Wert eingebe, dann funktioniert das alles. Nu mit dem Wert Null nicht. ich habe viele Formel versucht leider kein Erfolg.

Dezimalzahlen habe ich auch schon probiert, Excel sagt das die formel nicht stabil währe.

Ich hänge euch mal meine Exceldatei mal an.

Vielen Dank im voraus


  test.xlsm (Größe: 35,63 KB / Downloads: 11)

[BoskoBiati]

Hi,

vielleicht so:

Code:

=WENN(ISTZAHL([@[Erledigt am:]]);"4 Erledigt";WENN(ODER(ZAHLENWERT([@[Deadline in Tage ]])<0; UND(ZAHLENWERT([@[Deadline in Tage ]])>=0; (ZAHLENWERT([@[Deadline in Tage ]])<4))); "1 Sehr Wichtig ";WENN(UND(ZAHLENWERT([@[Deadline in Tage ]]) >3;ZAHLENWERT([@[Deadline in Tage ]])<18);"2 Wichtig";WENN(UND(ZAHLENWERT([@[Deadline in Tage ]]) > 17;ZAHLENWERT([@[Deadline in Tage ]])<32);"3 Normal";""))))

Eigentlich sollte aber das reichen:

Code:

=WENN(ISTZAHL([@[Erledigt am:]]);"4 Erledigt";WENN(ZAHLENWERT([@[Deadline in Tage ]])<4; "1 Sehr Wichtig ";WENN(ZAHLENWERT([@[Deadline in Tage ]])<18;"2 Wichtig";WENN(ZAHLENWERT([@[Deadline in Tage ]])<32;"3 Normal";""))))
oder das:
=WENN(ISTZAHL([@[Erledigt am:]]);"4 Erledigt";VERWEIS(ZAHLENWERT([@[Deadline in Tage ]]);{-999;4;18;32};{"1 Sehr Wichtig ";"2 Wichtig";"3 Normal";""}))

=WENN([@[Erledigt am:]]<>"";"4 Erledigt";SVERWEIS(ZAHLENWERT([@[Deadline in Tage ]]);{-999."1 Sehr Wichtig ";4."2 Wichtig";18."3 Normal";32.""};2;1))

Und wenn Du dafür sorgst, dass nur Zahlen in Deadline eingetragen werden können, dann erübrigt sich auch das ZAHLENWERT!

[oee]

Kein Wunder, denn du hast einmal kleiner 0 und einmal grösser 0 - WO ist gleich 0?
Mach aus ">0" das hier: ">=0" und schon klappt es.

[samsamsam]

Erstmals vielen vielen lieben Dank euch allen.

Ich habe die erste Formel getestet. Es funktioniert teilweise. Die Null wird nun erkannt. Vielen Dank

Wenn aber nichts im Feld unter "Deadline in Tage" steht, soll die Wichtigkeit auch nicht erscheinen.

   

Die Formel sagt ja am ende

Code:

""))))

das klappt noch nicht und das ist dadran wo ich mir den kopf zerbreche und weiß nicht warum

[BoskoBiati]

Hi,

Code:

=WENN([@[Deadline in Tage ]]="";"";WENN([@[Erledigt am:]]<>"";"4 Erledigt";SVERWEIS(ZAHLENWERT([@[Deadline in Tage ]]);{-999."1 Sehr Wichtig ";4."2 Wichtig";18."3 Normal";32.""};2;1)))

[samsamsam]

Hallo nochmal,

Entschuldigung hatte die letzten Tage wenig Zeit um die Formel zu testen.

Code:

=WENN(ISTZAHL([@[Erledigt am:]]);"4 Erledigt";WENN(ZAHLENWERT([@[Deadline in Tage ]])<4; "1 Sehr Wichtig ";WENN(ZAHLENWERT([@[Deadline in Tage ]])<18;"2 Wichtig";WENN(ZAHLENWERT([@[Deadline in Tage ]])<32;"3 Normal";""))))

Dieser Code funktioniert leider auch nur teilweise für meine Bedürfnisse und hat eine Andere Logik.

gegenüber diesen code:

Code:

=WENN(ISTZAHL([@[Erledigt am:]]);"4 Erledigt";WENN(ZAHLENWERT([@[Deadline in Tage ]])<4; "1 Sehr Wichtig ";WENN(ZAHLENWERT([@[Deadline in Tage ]])<18;"2 Wichtig";WENN(ZAHLENWERT([@[Deadline in Tage ]])<32;"3 Normal";""))))

Der code hier ist perfekt. Hier funktionier nur nicht dieser teil --->            ;"")))) . Heißt wenn nichts drin steht, darf auch keine wichtigkeitsstufe angezeigt werden.
So wie ich das sehe liegt es daran das die Prüfung auf Zahlenwert nicht funktioniert. Deshalb steht von vorhinein immer "1sehr wichtig" drin.

Ich habe da mir die Zeit genommen um die Formel umzuschreiben, ich bin leider aber zu keinem Ergebnis gekommen.

Wie kann ich das beheben?

Danke vielmals

[oee]

Die beiden Codes sind doch IDENTISCH.

[samsamsam]

Entschuldigung mein Fehler: 

ich habe ausversehen 2 mal die Selbe Formel geschrieben.

erste Formel

Code:

=WENN([@[Deadline in Tage ]]="";"";WENN([@[Erledigt am:]]<>"";"4 Erledigt";SVERWEIS(ZAHLENWERT([@[Deadline in Tage ]]);{-999."1 Sehr Wichtig ";4."2 Wichtig";18."3 Normal";32.""};2;1)))

hier habe ich das problem: hier ist immer die Voraussetzung das ein Wert im "Deadline in Tagen" steht, sonst passiert nichts.

ist in der unteren Formel anders.


zweite Formel

Code:

=WENN(ISTZAHL([@[Erledigt am:]]);"4 Erledigt";WENN(ZAHLENWERT([@[Deadline in Tage ]])<4; "1 Sehr Wichtig ";WENN(ZAHLENWERT([@[Deadline in Tage ]])<18;"2 Wichtig";WENN(ZAHLENWERT([@[Deadline in Tage ]])<32;"3 Normal";""))))

diese beiden Formel sind unterschiedlich.

die zweite Formel ist die ich anstrebe.

aber wie gesagt:

Zitat von mir:

Der code hier ist perfekt. Hier funktionier nur nicht dieser teil --->            ;"")))) . Heißt wenn nichts drin steht, darf auch keine wichtigkeitsstufe angezeigt werden.
So wie ich das sehe liegt es daran das die Prüfung auf Zahlenwert nicht funktioniert. Deshalb steht von vorhinein immer "1sehr wichtig" drin.

Ich habe da mir die Zeit genommen um die Formel umzuschreiben, ich bin leider aber zu keinem Ergebnis gekommen.

Wie kann ich das beheben?

Danke vielmals

Danke und Entschuldigung für das Durcheinander.

[samsamsam]

Hallo zusammen,

ich habe verstanden was mein Hauptproblem ist.

Das Hauptproblem ist der Wert 0.

Die Wenn-Funktion beim Prüfen des ZAHLENWERT erkennt 0=0 und Leere Spalte =0

Das bedeutet das die Prüfung hier nicht richtig Funktioniert.

Problem verstanden nur wie kann ich das beheben für meine Formel?

Danke nochmals

[BoskoBiati]

Hi,

Keine Null reinschreiben, sondern leer lassen.