Filtern aus 2 Spalten

[marilin837]

Hallo...
bitte um Hilfe..
Anbei die Datei.

In Tabellenblatt 1 - die Daten

• Standort
  
• Kreditor 
  
• Betrag
  
• Text (manche Kreditoren haben verschiedene Buchungstexte)
  

Tabellenblatt 2
hier sollen die Ergebnisse eingetragen werden

Ich habe hier auch von euch schon einen Formel erhalten - die bestens funktioniert.
Jedoch kommt jetzt noch hinzu, dass manche Kreditoren verschiedene Texte haben
und wie in Rot markiert - bekomme ich nur die Gesamtsumme vom Kreditor - und natürlich - ohne Formel - nicht summiert nach Buchungstext.

Ich hoffe, ihr versteht was ich meine.

Tab.1 - Daten
Tab.2 - Ergebnisse - gefiltert nach - Kreditor und Text - Besonderheit - alle Kreditoren mit 970 sollen summiert werden! (funktioniert aber bereits mit der alten Formel)
'=SUMMENPRODUKT((Tabelle1!$A$2:$A$1000=Tabelle2!B$1)*(LINKS(Tabelle1!$B$2:$B$1000;LÄNGE($A2))=Tabelle2!$A2&"")*(Tabelle1!$C$2:$C$1000))


Danke und
LG :)

[steve1da]

Hola,
einfach als weitere Bedingung hinzufügen.

Code:

=SUMMENPRODUKT((Tabelle1!$A$2:$A$1000=Tabelle2!C$1)*(LINKS(Tabelle1!$B$2:$B$1000;LÄNGE($A2))=Tabelle2!$A2&"")*(Tabelle1!$D$2:$D$1000=B2)*(Tabelle1!$C$2:$C$1000))

Gruß,
steve1da

[Egon12]

Hallo,

wenn ich es richtig verstanden habe, wäre dies eine von diversen Möglichkeiten:

Code:

=WENNFEHLER(SUMME(FILTER(Tabelle1!$C$2:$C$1000;(Tabelle1!$B$2:$B$1000=$A2)*(Tabelle1!$D$2:$D$1000=$B2)*(Tabelle1!$A$2:$A$1000=C$1)));"-")

Gruß Uwe

[Andreas Killer]

Du machst Dir selber das Leben schwer, kuck mal:

   

Ganz stumpf und ohne Schnickschnack in 2 Minuten gemacht:


  Testmappe 030226.xlsx (Größe: 32,55 KB / Downloads: 6)

Andreas.

[Egon12]

Hallo Marlin,

anbei mal die Sache dynamisiert mit Auswahl was ausgegeben werden soll.
Die Formeln funktionieren ab O2024.

  Auswertung dynamisch.xlsx (Größe: 22,89 KB / Downloads: 3)

Gruß Uwe

[EA1950]

Hallo, 

ich habe dir im Arbeitsblatt "Tabelle1" in Zelle G1 folgende Formel eingefügt:
=LET(m;$A:.$D; EINDEUTIG(SPALTENWAHL(m;2;4)))

Sie erzeugt jede vorhandene eindeutige Kombination aus Kreditor-Nummer und Text (Spalten B und D) in den Spalten G und H.
Dazu kannst du dann in Spalte I ein Gruppen-Kennzeichen definieren (blau formatierte Spalte).

Dieses Gruppenkennzeichen wird dann im Arbeitsblatt "Tabelle3" als Kombination von Gruppe und Text verwendet, um die Aufsummierungen danach zusammen mit dem Standorten auszuführen. Dazu habe ich dir in Zelle B1 folgende Formel eingefügt:
=LET(m; Tabelle1!$A:.$D; f; Tabelle1!$G:.$I;
   KredText; SPALTENWAHL(m; 2; 4); StandOrt; INDEX(m; 0; 1); Betraege; INDEX(m; 0; 3);
   f_KrdTxt; INDEX(f; 0; 1) & "|" & INDEX(f; 0; 2); f_Auswhl; INDEX(f; 0; 3);
   Gruppe; LAMBDA(xy; LET(x; INDEX(xy; 0; 1); y; INDEX(xy; 0; 2); g; XVERWEIS(x & "|" & y; f_KrdTxt; f_Auswhl; ""); HSTAPELN(g; y)));
PIVOTMIT(Gruppe(KredText); StandOrt; Betraege; SUMME; 3; A1))

Diese Formel erzeugt automatisch alle Summierungen in den Spalten B bis L. Zusammen mit der normalen Zellformatierung ist auch eine bedingte Formatierung hinterlegt, die die Summenzeilen dynamisch erkennt und formatiert.

Über die Zelle A1 (gelb eingefärbt) kann man steuern, ob und welche Summenzeilen angezeigt werden:
- Bei Einstellung 0 wird keine Summenzeile angezeigt, 
- bei Einstellung 1 wird nur eine Gesamtsummenzeile als letzte Zeile angezeigt,
- bei Einstellung 2 werden zusätzlich zur Gesamtzeile Gruppensummenzeilen (basierend auf Spalte B) erzeugt.