Fehler in Summewenn-Formel

[hugo333]

Hallo zusammen,

Excel gibt mir eine nicht näher spezifizierten Fehler in dieser Summewenn-Formel aus:

=SUMMEWENN(A1:C3; "*" & A5 & "*"; LINKS(A1:C3;1)*1)

Es soll in B5 in Abhängigkeit von dem Inhalt in A5 die Summe der zugehörigen Zellen aus A1:C3 bilden (siehe Tabelle im Bild). Die “8” ist nicht berechnet, müsste aber als Ergebnis der Formel rauskommen.

An falscher Systemeinstellung bezgl. der Trennzeichen , oder ; liegt es nicht.

Hat jemand eine Idee? Die einzelnen Teile der Formel funktionieren, aber nicht im Zusammenspiel.

[RPP63]

Moin!
Schließe die Formel mal als Matrix ab.
Strg+Umschalt+Enter statt nur mittels Enter

Begründung ohne Test:
LINKS(A1:C3;1)*1 liefert nur das erste Ergebnis

Gruß Ralf

---

Jetzt getestet:
=SUMMENPRODUKT((LINKS(A1:C3;1)*1)*(WENNFEHLER(SUCHEN(A5;A1:C3)>1;0)))

	A	B	C
1	2 mom	3 hoh	4 tut
2	2 hoh	4 tut	3 mom
3	3 hoh	5 tut	4 mom
4
5	hoh	8

Zelle	Formel
B5	=SUMMENPRODUKT((LINKS(A1:C3;1)*1)*(WENNFEHLER(SUCHEN(A5;A1:C3)>1;0)))

[BoskoBiati]

Hi,

oder so:

Code:

=SUMME(WENN(ISTZAHL(SUCHEN(A5;A1:C3));--LINKS(A1:C3;1)))

ggf. Matrixformel!

[HKindler]

Hi,

bei den bisherigen Formeln wird aber nur die erste Ziffer gewertet. 12 hoh würde als 1 gezählt.

Statt LINKS(A1:C3;1) müsste man LINKS(A1:C3;LÄNGE(A1:C3)-LÄNGE(A5)+1) verwenden (ungetestet, eventuell muss man da noch eine Kleinigkeit anpassen).

[BoskoBiati]

Hi,

so war die Vorgabe des TE:

LINKS(A1:C3;1)

[HKindler]

Es wäre nicht das erste mal, dass sich en TE in den Vorgaben irrt...

[BoskoBiati]

Hi,

Code:

=SUMME(WENN(ISTZAHL(SUCHEN(A5;A1:C3));--LINKS(A1:C3;suchen(" ";a1:c3)-1)))

oder auch so:

Code:

=LET(a;VSTAPELN(A1:A3;B1:B3;C1:C3);b;FILTER(a;ISTZAHL(SUCHEN(A5;a)));SUMME(--WECHSELN(b;A5;"")))

[{Boris}]

Hi,

unabhängig von den bereits geposteten Lösungen, hier noch eine Erklärung zu:

Excel gibt mir eine nicht näher spezifizierten Fehler in dieser Summewenn-Formel aus:

=SUMMEWENN(A1:C3; "*" & A5 & "*"; LINKS(A1:C3;1)*1)

SUMMEWENN benötigt beim ersten und letzten Parameter zwingend einen (Zell-)Bezug und kein Array.
LINKS(A1:C3;1) liefert aber ein Array - und damit kann SUMMEWENN nix anfangen.

Wenn Du z.B. die Zahlen in einer Spiegeltabelle separat ausliest, dann kannst Du auch SUMMEWENN verwenden.

Also z.B. in G1:
=--LINKS(A1;1)
und bis I3 kopieren.

Dazu dann:
=SUMMEWENN(A1:C3;"*"&A5&"*";G1:I3)

[Kuwer]

Hallo,

oder auch so?

=SUMME(WENNFEHLER(--WECHSELN(A1:C3;" "&$A$5;"");0))

Gruß, Uwe

[hugo333]

Ich glaube, ich habe mich in dem richtigen Forum angemeldet:

ALLE von euch vorgeschlagenen Formeln funktionieren!

Und da es so unterschiedliche Vorgehensweisen sind, lerne ich auch gleich noch ein paar neue Funktionen dazu, perfekt!

Ich befürchte nur, ich werde noch viele Fragen haben, ohne mich großartig auch mal revanchieren zu können, wovon so ein Forum ja lebt. Aber wer weiß, ich bleibe am Ball.

Viele Dank auf jeden Fall an alle, die sich meines Problems angenommen haben!