FILTER( Ausgabe auf Variablen Max Wert beschränken

[stefan69]

Hallo beisammen,

wie kann ich der Filter Formel sagen Sie soll von den einzuschießenden gefilterten nur zb. die ersten 2 ausgeben.

=FILTER(A2:B15;B2:B15>2;"")

LG Stefan

[RPP63]

=FILTER(A2:B15;B2:B15>=KGRÖSSTE(B2:B15;2))

[stefan69]

=FILTER(A2:B15;B2:B15>=KGRÖSSTE(B2:B15;2))

so geht mir aber die Einschränkung B2:B15>2 verloren. Wert in B muss gößer 2 sein.
Die Max Ausgabe Beschränkung müsste Übrergeordnet sein, sodass alle anderen "Einschließen Kriterien" beibehalten bleiben.
Siehe Wunschergebnis in Datei.

[RPP63]

Ich bin gleich am Rechner.
Bitte ein wenig Geduld.

---

So, jetzt am Rechner und folglich mit Begrüßung.

Moin! ;)
Dein Wunschergebnis erhalte ich mit
=ZEILENWAHL(FILTER(A2:B20;B2:B20>2);1;2)

Und da Du die Anzahl ja offensichtlich variabel haben willst:
=ZEILENWAHL(FILTER(A2:B20;B2:B20>2);SEQUENZ(I1))

Gruß Ralf

---

Und jetzt mit Fehlerbehandlung:
=LET(f;FILTER(A2:B20;B2:B20>2;"");ZEILENWAHL(f;SEQUENZ(MIN(ZEILEN(f);I1))))

[HKindler]

Hi,

ich würde ja

=ÜBERNEHMEN(FILTER(A2:B15;B2:B15>2;"");I1)

empfehlen. Übrigens: auch die letzten x Zeilen kann man sich damit zurückgeben lassen. Dazu einfach negative Zahlen verwenden. Gilt für viele der Spill-Funktionen.

EDIT: Hier braucht es KEINE Fehlerbehandlung. Wenn es weniger Zeilen gibt, werden halt die angezeigt, die es gibt (bei "" halt einfach nur "").

[RPP63]

Yepp!
"Etwas" kürzer und viel besser!

Gruß Ralf

[stefan69]

.. super Sache, vielen dank

LG Stefan