=FILTER
#1
Hallo beisammen,

möchte mit der Filter Funktion Spalte D filter. Also ich möchte alle Werte sehen die nicht in C stehen.
Beide Spalten enthalten als Text formatierte Zahlen.

Hier mein erfolgloser Versucht.

=FILTER($D$1:$D$93;(D$1:$D$93<>$C$1:$C$93);"")

Kann mir wer helfen?

LG Stefan
Antworten Top
#2
Hallo,

die selben Texte müssen in der gleichen Zeile stehen, damit sie erkannt und gefiltert wird.
Gastlich
Antworten Top
#3
Hi,

hier mal zwei Varianten:


.xlsx   Einzelne_suchen.xlsx (Größe: 9,47 KB / Downloads: 6)
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Antworten Top
#4
Hi,

in der Datei von Edgar reicht auch
Code:
=FILTER(D1:D7;ZÄHLENWENN(C1:C7;D1:D7)=0)
Gruß,
Helmut

Win10 - Office365 / MacOS - Office365
Antworten Top
#5
Das ist exponenzielle Seuche. Besser:

=LET(y;--D1:D93;x;SORTIEREN(--C1:C93);FILTER(y;ISTNV(XVERWEIS(y;x;x;#NV;0;2))))

Erklärung: Bei 100.000 Paaren wären es bei HKindler + Bosko
10.000.000.000 Vergleiche. Hier sind es aber nur ca.
00.001.700.000 Vergleiche.
WIN/MSO schicken angeblich alle 5 Sekunden Deinen Screen heim zu Papa (recall-Klausel). 
Antworten Top
#6
Hi,

wieso dann noch den XVerweis statt des einfacheren XVergleich? Der ist bestimmt noch einen Tick schneller.

=LET(y;--D1:D7;x;SORTIEREN(--C1:C7);FILTER(y;ISTNV(XVERGLEICH(y;x;0;2))))
Gruß,
Helmut

Win10 - Office365 / MacOS - Office365
Antworten Top
#7
Hatte ich auch zuerst. Dann wollte ich die Ergebnisse anzeigen, und habe vergessen, zurückzuändern.

Aber schön, dass Du bei mir bist.

=LET(y;--D1:D93;FILTER(y;ISTNV(XVERGLEICH(y;SORTIEREN(--C1:C93);0;2))))
WIN/MSO schicken angeblich alle 5 Sekunden Deinen Screen heim zu Papa (recall-Klausel). 
Antworten Top
#8
Hi,

und wenn man davon ausgeht, dass bei 100.000 Einträgen der eine oder andere auch doppelt vorkommen kann, dann ist
=LET(y;D1:D7;x;SORTIEREN(EINDEUTIG(C1:C7));FILTER(y;ISTNV(XVERGLEICH(y;x;0;2))))
noch schneller.

Jetzt ist nur noch die Frage: Ist SORTIEREN(EINDEUTIG(xxx)) oder EINDEUTIG(SORTIEREN(xxx)) schneller...
Für einen Menschen sicherlich letzteres, für einen Computer vermutlich das Erste. Es sei denn, der Computer "weiß" irgendwie, dass die Liste sortiert ist. Aber das ist bei EINDEUTIG mMn nicht dokumentiert.
Gruß,
Helmut

Win10 - Office365 / MacOS - Office365
Antworten Top
#9
EINDEUTIG verwendet SORTIEREN vermutlich intern (mit "Lagezeile" zum Zurücksortieren). Könnte man hier in die Funktion eingreifen ohne das Zurücksortieren, würden sogar zwei Sorts wegfallen.

EINDEUTIG(D1:D7) bringt bei vielen Wiederholern auch noch mal (linear) etwas.
WIN/MSO schicken angeblich alle 5 Sekunden Deinen Screen heim zu Papa (recall-Klausel). 
Antworten Top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste