Excel Spalte trennen

[Atram]

Ich stehe vor einem Komfort Problem welches ich bisher nicht lösen kann.

Gibt es ein Makro oder Formel mit welcher ich den Text in einer Spalte splitten kann?

Folgendes Bsp.

               A                              B
1       Adresse                     Name
2       Forstweg 1           Herr Karl August
3       Blumstr. 2            Frau Eva Adam


Ich möchte jetzt Spalte B so trennen, dass "Herr" "Karl" "August" in jeweil einer eigenen Spalte stehen.

Vielen Dank für eure Hilfe

[steve1da]

Hola,

entweder über Daten - Text in Spalten, oder:

http://www.herber.de/excelformeln und bitte suchen .../formeln.html?welcher=326

Gruß,
steve1da

[Atram]

Vielen Dank

wie ist es wenn sich aber etwas ändert:

z.B. wenn Herr Dr. Karl August da steht. Kann man dies spezifizieren oder mit Regeln splitten?

[steve1da]

Hola,

dann musst du schon erklären, warum das spezifisch ist.

Gruß,
steve1da

[chris-ka]

Hi,

für Daten trennen hätte ich auch was

Arbeitsblatt mit dem Namen 'Tabelle1'
Adresse	Name
Forstweg 1	Herr Karl August	Herr	Karl	August
Blumstr. 2	Frau Eva Adam	Frau	Eva	Adam

Zelle	Formel
C2	=GLÄTTEN(TEIL(WECHSELN($B2;" ";WIEDERHOLEN(" ";99));99*(SPALTE(A1)-1)+1;99))
D2	=GLÄTTEN(TEIL(WECHSELN($B2;" ";WIEDERHOLEN(" ";99));99*(SPALTE(B1)-1)+1;99))
E2	=GLÄTTEN(TEIL(WECHSELN($B2;" ";WIEDERHOLEN(" ";99));99*(SPALTE(C1)-1)+1;99))
C3	=GLÄTTEN(TEIL(WECHSELN($B3;" ";WIEDERHOLEN(" ";99));99*(SPALTE(A2)-1)+1;99))
D3	=GLÄTTEN(TEIL(WECHSELN($B3;" ";WIEDERHOLEN(" ";99));99*(SPALTE(B2)-1)+1;99))
E3	=GLÄTTEN(TEIL(WECHSELN($B3;" ";WIEDERHOLEN(" ";99));99*(SPALTE(C2)-1)+1;99))

Diese Tabelle wurde mit Tab2Html (v2.5.0) erstellt. ©Gerd alias Bamberg

nur das mit den Regeln.... ;)

[Atram]

Hola,

dann musst du schon erklären, warum das spezifisch ist.

Gruß,
steve1da

in der Spalte A steht z.B:

Herr Karl August
Frau Eva Adam
Herr Dr. Uwe Bein

usw.

mit der Formel würde er den Vornamen mit dem "Dr." übernehmen.

[Wilfried Höttl]

Hallo!
Meinst du es so?


Tabelle4

	A	B	C	D	E	F
1	Titel und Name trennen
2
3	Voller Name		Titel	Vorname	Name	mögl. Titel
4	Herr Ing. Heinz Mustermann		Herr Ing.	Heinz	Mustermann	Herr Dr.
5	Herr Dr. Thomas Mittermeier		Herr Dr.	Thomas	Mittermeier	Frau Dr.
6	Heinz Silberbauer			Heinz	Silberbauer	Herr Prof.
7	Frau Prof.  Gabi Maier		Frau Prof.	Gabi	Maier	Frau Prof.
8	Frau Ing. Renate Huber		Frau Ing.	Renate	Huber	Herr Ing.
9	Herr Prof.  Jens Huber		Herr Prof.	Jens	Huber	Frau Ing.
10	Vermittlung Martin Huber		Vermittlung	Martin	Huber	Vermittlung
11	Buchhaltung Anna Meister		Buchhaltung	Anna	Meister	Buchhaltung
12	ABC Heidi Gruber		ABC	Heidi	Gruber
13
14						ABC

Formeln der Tabelle

Zelle Formel C4 {=WENN(MAX(WENN((F$4:F$21>"")*ISTZAHL(SUCHEN(F$4:F$21;A4)*1);ZEILE($4:$21)-ZEILE(F$4)+1;))=0;"";INDEX(F$4:F$21;MAX(WENN((F$4:F$21>"")*ISTZAHL(SUCHEN(F$4:F$21;A4)*1);ZEILE($4:$21)-ZEILE(F$4)+1;))))} D4 =TEIL(A4;LÄNGE(C4)+(C4>"")+1;LÄNGE(A4)-LÄNGE(C4&E4)-(C4>"")-1) E4 {=TEIL(A4;MAX((TEIL(A4;SPALTE(1:1);1)=" ")*SPALTE(1:1))+1;999)}

Enthält Matrixformel: Umrandende { } nicht miteingeben, sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4

Gruß
Wilfried

[WillWissen]

Hi,

wo siehst du denn ein Problem?

Tabelle3

	A	B	C	D	E	F
1	Adresse	Name
2	Forstweg 1	Herr Dr. Karl August	Herr	Dr.	Karl	August
3	Blumstr. 2	Frau Eva Adam	Frau	Eva	Adam

Formeln der Tabelle

Zelle Formel C2 =GLÄTTEN(TEIL(WECHSELN($B2;" ";WIEDERHOLEN(" ";99));99*(SPALTE(A1)-1)+1;99)) D2 =GLÄTTEN(TEIL(WECHSELN($B2;" ";WIEDERHOLEN(" ";99));99*(SPALTE(B1)-1)+1;99)) E2 =GLÄTTEN(TEIL(WECHSELN($B2;" ";WIEDERHOLEN(" ";99));99*(SPALTE(C1)-1)+1;99)) F2 =GLÄTTEN(TEIL(WECHSELN($B2;" ";WIEDERHOLEN(" ";99));99*(SPALTE(D1)-1)+1;99)) C3 =GLÄTTEN(TEIL(WECHSELN($B3;" ";WIEDERHOLEN(" ";99));99*(SPALTE(A2)-1)+1;99)) D3 =GLÄTTEN(TEIL(WECHSELN($B3;" ";WIEDERHOLEN(" ";99));99*(SPALTE(B2)-1)+1;99)) E3 =GLÄTTEN(TEIL(WECHSELN($B3;" ";WIEDERHOLEN(" ";99));99*(SPALTE(C2)-1)+1;99)) F3 =GLÄTTEN(TEIL(WECHSELN($B3;" ";WIEDERHOLEN(" ";99));99*(SPALTE(D2)-1)+1;99))

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Der Titel steht halt nun ebenfalls in einer separaten Zelle.

[schauan]

Hallo Günter,

das Problem wird wohl sein, dass in der Vornamenspalte der Dr. steht, in der Familiennamenspalte der Vorname und der Familienname dann außerhalb der "Tabelle"

[WillWissen]

Hi André,

das ist zwar richtig. Doch dieses Problem wird er auch haben, wenn die Person mehrere Vornamen hat.