Excel-Rechnung mit Zellverweis

[AS2]

Hallo,
ich bin auf der Suche nach einer Formel für folgende Rechnung:
 
In einer Tabelle habe ich verschiedene Werte vorliegen, z. B.
 
Zelle A1          50.000             Zelle B1           20.000
Zelle A2          100.000           Zelle B2           25.000
Zelle A3          150.000           Zelle B3           30.000
Zelle A4          200.000           Zelle B4           35.000
 
Nun habe ich einen Wert vorliegen und Excel soll diese Rechnung selbstständig durchführen:
 
Vorliegender Wert: 122.000
Das System sollte nun wissen, dass es mit den Werten in den Zellen A2/B2 und A3/B3 rechnen muss.
 
Rechnung:
(B3) 30.000 – (B2) 25.000 = 5.000
122.000 – (A2) 100.000 = 22.000
(A3) 150.000 – (A2) 100.000 = 50.000
 
5.000 * 22.000 = 110.000.000
110.000.000 / 50.000 = 2.200
 
2.200 + 25.000 = 27.200
 
27.200 = Wert, der angezeigt werden soll (z.B. in einer Zelle neben den 122.000)
 
Ist das möglich? Und wenn ja, wie?
Vielen Dank für eure Hilfe!

[echo]

Hallo
mir erschließt sich die Logik dahinter nicht, wieso Excel jetzt genau diesen Wert nimmt.
Die Formeln selbst kannst du natürlich in jeder leeren Zelle berechnen lassen 
Fürs Ergebnis: Bei mir steht 122.000 in D1

=((B3-B2)*(D1-A2))/(A3-A2)+B2

Gruß Holger

[Ego]

Hallo A..,

warum schreibst du nicht einfach, dass du in den Abschnitten linear interpolieren willst?

Hier die Formel wenn der gesuchte X-Wert in E1 steht:

=INDEX(B1:B4;VERGLEICH(E1;A1:A4;1))+(E1-INDEX(A1:A4;VERGLEICH(E1;A1:A4;1)))*(INDEX(B1:B4;VERGLEICH(E1;A1:A4;1)+1)-INDEX(B1:B4;VERGLEICH(E1;A1:A4;1)))/(INDEX(A1:A4;VERGLEICH(E1;A1:A4;1)+1)-INDEX(A1:A4;VERGLEICH(E1;A1:A4;1)))

Ich würde für die Indexnummer VERGLEICH(E1;A1:A4;1) eine Zelle "opfern" (hier F1) und 6mal diesen Text durch einen Bezug auf diese Zelle ersetzen.

=INDEX(B1:B4;F1)+(E1-INDEX(A1:A4;F1))*(INDEX(B1:B4;F1+1)-INDEX(B1:B4;F1))/(INDEX(A1:A4;F1+1)-INDEX(A1:A4;F1))

[AS2]

Vielen lieben Dank! Das hat soweit schon mal funktioniert.
Leider gibt Excel mir, wenn ich nun in Zelle E1 "200.000" angebe, nur #BEZUG! an. Ich habe daraufhin die Formel abgeändert, und zwar überall, wo vorher A4 oder B4 eingetragen war, in A5 bzw. B5.
Daraufhin bekomme ich bei Eingabe von 200.000 auch die 35.000 ausgeworfen, wie es sein soll. Leider rechnet Excel nun aber selbstständig weiter. Sprich, wenn ich eine Zahl größer als 200.000 angebe, erscheint ein Wert. Hier wünsche ich mir, dass Excel "nicht verfügbar" o.ä. anzeigt, wie es auch der Fall ist, wenn ich einen Wert kleiner als 5.000 angebe.
Kann mir jemand sagen, wo nun mein Fehler liegt?
Vielen Dank schonmal!

[WillWissen]

Hi,

Kann mir jemand sagen, wo nun mein Fehler liegt?

nur wenn du eine Kristallkugel mitlieferst. Eventuell reicht eine Beispieldatei, in der dein Fehler nachvollziehbar ist.

[schauan]

Hallöchen,

für so was gibt es WENNFEHLER

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F
1	50.000	20.000			175000	32500
2	100.000	25.000			55000	20500
3	150.000	30.000			5000	Außer Bereich
4	200.000	35.000			222000	Außer Bereich

Zelle	Formel
F1	=WENNFEHLER(INDEX($B$1:$B$4;VERGLEICH(E1;$A$1:$A$4;1))+(E1-INDEX($A$1:$A$4;VERGLEICH(E1;$A$1:$A$4;1)))*(INDEX($B$1:$B$4;VERGLEICH(E1;$A$1:$A$4;1)+1)-INDEX($B$1:$B$4;VERGLEICH(E1;$A$1:$A$4;1)))/(INDEX($A$1:$A$4;VERGLEICH(E1;$A$1:$A$4;1)+1)-INDEX($A$1:$A$4;VERGLEICH(E1;$A$1:$A$4;1)));"Außer Bereich")

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg

[AS2]

   

...mein Problemchen ist gerade, dass bei dem Wert 200.000 folgendes angezeigt werden soll: 35.000

Angezeigt wird mir allerdings "Außer Bereich".

Ändere ich die Formel nun auf =WENNFEHLER(INDEX($B$1:$B$5;VERGLEICH(E8;$A$1:$A$5;1))+(E8-INDEX($A$1:$A$5;VERGLEICH(E8;$A$1:$A$5;1)))*(INDEX($B$1:$B$5;VERGLEICH(E8;$A$1:$A$5;1)+1)-INDEX($B$1:$B$5; erhalte ich den korrekten Wert (35.000).

Gebe ich nun einen Wert größer als 200.000 an, bekomme ich einen errechneten Wert, den ich allerdings gar nicht haben möchte. Hier sollte tatsächlich "Außer Bereich" angegeben werden. 

Ist eine Kombination der Formeln irgendwie möglich?

Vielen herzlichen Dank für die schnellen Antworten!!!

[Ego]

Hallo A...,

wie du festgestellt hast funktioniert meine Formel nicht an der unteren Grenze des Bereiches, da ich für eine "echte" Interpoaltion immer zwei Werte benötige und für die Entscheidung immer die obere Zeile suche.

Dies kannst du doch in einer einfachen Wenn-Funktion abfangen:

Wenn(der gesuchte Wert dem X-Wert der letzte Zeile entspricht; dann nimm den Y-Wert der letzten Zeile; ansonsten nutze die Formel)

=WENN(E2=$A$5;$B$5;WENNFEHLER(INDEX($B$2:$B$5;F2)+(E2-INDEX($A$2:$A$5;F2))*(INDEX($B$2:$B$5;F2+1)-INDEX($B$2:$B$5;F2))/(INDEX($A$2:$A$5;F2+1)-INDEX($A$2:$A$5;F2));"Außer Bereich"))

[AS2]

Super, das funktioniert!

Ganz herzlichen Dank :)