Excel-Formel

[excel2016]

Hallo. Ich habe folgende Frage. Im angehängten Dokument steht hinter Zelle G6 folgende Formel: 


=WENN(B6<>"";B6;WENN(C6<>"";C6;WENN(D6<>"";D6;WENN(E6<>"";E6;0))))

Ich möchte also die Werte, die in verschiedenen Spalten in verschiedenen Zeilen stehen, in eine Spalte untereinander stehen haben. In der Datei um die es geht sind es allerdings ca. 30 Spalten. Die Formel, wie ich sie mir ausgedacht habe wäre also extrem lang. Geht das auch kürzer/ einfacher?

Vielen Dank im Voraus!



  Mappe1.xlsx (Größe: 10,03 KB / Downloads: 3)

[excel2016]

Gerade habe ich noch gemerkt, dass Excel so viele Verschachtelungen nicht zulässt. Also brauche ich dringend eine andere Lösung.

[Ego]

Hallo e...,

zB. so:

Code:

{
=INDEX(B6:F6;VERGLEICH(1;--(B6:F6<>"");0))
}

Achtung! Matrixformel. Die geschweiften Klammern werden nicht mit eingegeben, sondern jede Bearbeitung mit Strg+Shift+Enter abgeschlossen.

[Käpt'n Blaubär]

Hallo,

Gerade habe ich noch gemerkt, dass Excel so viele Verschachtelungen nicht zulässt. Also brauche ich dringend eine andere Lösung.

Ich habe mit Formeln nicht sehr viel am Hut, darum bin ich sehr vorsichtig mit meiner Antwort.
Soviel ich weiß ist bei einer Verschachtelungstiefe von maximal sieben Schluß. 
Das kann man Aushebeln, wenn man nach der siebenten Verschachtelung die Weiteren mit "+"
unterbricht. Vielleicht haben aber die Formeljonglöre einen viel besseren Rat für Dich.

[WillWissen]

Hallo zusammen,

seit XL2007 sind 64 Verschachtelungsebenen möglich; ob das allerdings noch Sinn macht, bezweifle ich.

[Käpt'n Blaubär]

Hallo Günter,

danke für den Hinweis, ich werde nun meine veralteten Vorstellungen revidieren. Versprochen  :19:

[WillWissen]

Hi,

ich würde das Problem so lösen (kein CSE nötig):

Arbeitsblatt mit dem Namen 'Tabelle1'
	B	C	D	E	F	G
5	Eins	Zwei	Drei	Vier		Ergebnis
6			10			10
7	30					30
8		50				50
9				50		50
10	20					20

Zelle	Formel
G6	=VERWEIS(2;1/($B6:$F6<>"");$B6:$F6)

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Voraussetzung ist allerdings, dass, wie im Beispiel, auch tatsächlich nur eine einzige Zahl in der Zeile steht.

[LCohen]

=INDEX(B6:F6;VERGLEICH(WAHR;INDEX(B6:F6<>"";);))

WillWissen gibt den ersten Treffer mit VERWEIS von hinten; diese Formel normal von vorn. Also hat man auch hier noch Auswahl!

[excel2016]

Perfekt. Vielen Dank!