Excel Blöcke sortieren

[BoskoBiati]

Hi Detlef,

Du hast recht:

Code:

=LET(xa;SEQUENZ(24;1;1;0,25);xb;A1:C24;xc;HSTAPELN(xa;xb);xd;FILTER(xc;REST(xa;1)=0);xe;SORTIEREN(xd;2);xf;SEQUENZ(6;1,1;1);xg;HSTAPELN(xe;xf);yb;WECHSELN(xa;--LINKS(xa;1);SVERWEIS(--LINKS(xa;1);xg;5;0));SPALTENWAHL(WECHSELN(SORTIEREN(HSTAPELN(yb;xb));0;"");2;3;4))

[RPP63]

Da wir niemals erfahren werden, was der TE wirklich will, hier mal meine Interpretation des Wunsches.

• Die "Blöcke" sind durch Leerzeilen getrennt
• die "Blockgröße" ist bei mir beliebig
• ich benötige eine Hilfsspalte D mit simpler Formel, um die "Blockzugehörigkeit" zu kennzeichnen

	A	B	C	D	E	F	G	H	I
1	Spalte1	Spalte2	Spalte3	1		Spalte1	Spalte2	Spalte3
2	F	Y	U	1		F	Y	U
3	G	K	Q	1		G	K	Q
4	J	M	S	1		J	M	S
5				2
6	M	P	T	2		G	I	C
7	X	I	Y	2		M	P	T
8	G	I	C	2		Q	I	L
9	Q	I	L	2		X	I	Y
10				3
11	I	X	S	3		B	E	P
12	N	H	X	3		I	X	S
13	B	E	P	3		I	M	X
14	R	F	I	3		N	H	X
15	I	M	X	3		R	F	I
16				4
17	Q	J	D	4		B	N	H
18	B	N	H	4		H	E	G
19	H	E	G	4		O	C	G
20	O	C	G	4		Q	J	D
21	U	K	Q	4		U	K	Q
22

Zelle	Formel
D2	=WENN(C2="";D1+1;D1)
F1	=LET(xm;WENN(A:.D="";"";A:.D); Header;WEGLASSEN(ZEILENWAHL(xm;1);;-1); Matrix;WEGLASSEN(xm;1); Matrix_Sort;SORTIERENNACH(Matrix;SPALTENWAHL(Matrix;4);1;SPALTENWAHL(Matrix;1);1); VSTAPELN(Header;WEGLASSEN(Matrix_Sort;;-1)))

Gruß Ralf

[Klaus-Dieter]

Hallo Ralf,

ich hatte es so verstanden, das er die Blöcke untereinander alphabetisch sortieren wollte, nicht nur die Blöcke in sich.

[RPP63]

Ja, wir wissen es halt nicht …
Falls der TE passiv mitliest, wird er hoffentlich bezüglich eventueller zukünftiger Threads aus diesem lernen, was eine zielgerichtete Fragestellung ausmacht.

[EA1950]

Hallo,

ausgehend von der Variante von Ralf, kann man auch ohne Arbeitsblatt-Hilfsspalte nur mit einem LET-internen Array auskommen. Ich habe dieses "block" genannt:

PHP-Code:

=LET(
    xm; WENN(A:.C = ""; ""; A:.C);
    block; SCAN(; SEQUENZ(ZEILEN(xm)); LAMBDA(Akk; i; (INDEX(xm; i; 3) = "") + Akk));
    kopf; ZEILENWAHL(xm; 1);
    xmat; WEGLASSEN(HSTAPELN(xm; block); 1);
    smat; SORTIERENNACH(xmat; SPALTENWAHL(xmat; 4); 1; SPALTENWAHL(xmat; 1); 1);
    VSTAPELN(kopf; WEGLASSEN(smat; ; -1))
) 


[RPP63]

Nice!
Ich gestehe, dass ich mit SCAN und MAP noch Schwierigkeiten habe.
Da sollte ich zeitnah dran arbeiten.

[Luschi]

Hallo Excel-Fan's,

solche Aufgaben löse ich lieber mit Power Query, denn die Zwischenkontrollen sind viel einfacher als bei den neumodischen E-365-Formeln.

Gruß von Luschi
aus klein-Paris

[Lausbub]

Seit Kurzem engagiere ich mich ehrenamtlich für einen Verein. Täglich kommen neue Aufgaben und Herausforderungen auf mich zu – da wollte ich sichergehen, nichts zu vergessen. Ursprünglich hatte ich den Wunsch, ein Ticketsystem mit Excel aufzubauen, habe diese Idee inzwischen jedoch verworfen.

Ich danke allen, die mir dabei mit ihrem Beitrag weitergeholfen haben!


Vielen Dank 
Lausbub

[ws-53]

Jetzt bin ich mal gespannt, mit welchen der vielen Lösungen, die bisher nur vage formulierte Anforderungen, am besten passen.

Nachtrag: Eine, wie ich meine, ziemlich ernüchternde Antwort für so viel Engagement!