Enddatum

[Werner K]

Hallo Frage zum Enddatum
In der Spalte A stehen untereinander die Datumsangaben.
Vom untersten Eintrag also das jüngste Datum möchte ich z.B 15 Monate aufrechnen.
Die Formel für Enddatum ist mir wohl bekannt aber nicht im Zusammenhang mit dem untersten Eintrag in einer Spalte.

 Danke für eure Hilfe

[ReginaR]

Hi,

teste mal so:

=EDATUM(INDIREKT("A"&ANZAHL2(A:A));15)

VG Regina

[BoskoBiati]

Hi,

Code:

=EDATUM(INDEX(A:A;VERWEIS(9;1/(A1:A1000<>"");ZEILE(A1:A1000)));15)

[RPP63]

In der Spalte A stehen untereinander die Datumsangaben.
Vom untersten Eintrag also das jüngste Datum möchte ich z.B 15 Monate aufrechnen.

Das jüngste Datum ist das höchste.
Folglich:
=EDATUM(MAX(A:A);15)

Gruß Ralf

[Werner K]

Danke an alle es hat funktioniert 
Grüße Werner

[RPP63]

Nur, um es klarzustellen:
Die drei Lösungen gehen von unterschiedlichen Voraussetzungen aus.
Wenn alle funktionieren, nimm meine!
Reginas Lösung versagt bei Leerzellen,
Edgars nimmt grundsätzlich den letzten Eintrag.
Meiner geht davon aus, dass das Datum aufsteigend eingetragen wird.

[Werner K]

Hallo ehrlich gesagt ich habe nicht alle ausprobiert aber ihre Antwort erschien mir am einfachsten.
Es ist ein fortlaufendes Datum immer aufsteigend.
Danke. Auch an die die ich nicht genommen habe.

[OnlineExcel]

Hallo Ralf,
warum schreibst du, dass bei deiner Lösung aufsteigend sein muss. Ist doch egal, max ist max.
Ist m.E. die allerbeste Lösung.

Gruß Peter

[RPP63]

Moin Peter!
Werner sucht ja den untersten Eintrag.
MAX findet den nur, wenn aufsteigend eingetragen wird.
Edgars Formel funktioniert immer, Reginas Formel funktioniert, wenn keine Leerzellen innerhalb des Wertebereichs sind.

Da ein Datum ja eine Zahl ist, funktioniert das unterste Datum (muss nicht das maximale sein) auch mittels
=EDATUM(INDEX(A:A;VERGLEICH(0;A:A;-1));15)

oder noch einfacher mittels
=EDATUM(VERWEIS(9^9;A:A);15)

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D
1	Datum
2	16.04.2025		17.11.2025	42
3	14.02.2025		17.11.2025	66
4	28.03.2025		17.11.2025	28
5	26.03.2025
6	07.03.2025
7
8	03.05.2025
9	11.03.2025
10
11	02.03.2025
12	23.05.2025
13	13.02.2025
14	27.05.2025
15
16	12.05.2025
17
18	17.08.2024
19

Zelle	Formel
C2	=EDATUM(INDEX(A:A;VERGLEICH(0;A:A;-1));15)
C3	=EDATUM(INDEX(A:A;VERWEIS(9;1/(A1:A1000<>"");ZEILE(A1:A1000)));15)
C4	=EDATUM(VERWEIS(9^9;A:A);15)
D2	=LÄNGE(FORMELTEXT(C2))

Gruß Ralf