Effizientere Alternative zur Wenn-Funktion?

[Arkadien]

Liebes Forum,

da dies mein erster Post ist, hoffe ich, dass ich hier richtig bin. Ich habe eine recht lange Wenn-Formel erstellt und ich wollte fragen, ob jemand einen effizienteren Weg für das bestehende Problem kennt.

Ich habe folgende Ausgangssituation:

In einer Tabelle stehen gestaffelt Anzahlen an Verkäufen, eine Kumulation dieser Beträge und der Betrag der Provision.

Darstellung der Tabelle:
Verkäufe
A2: 1000
A3: 2000
A4: 3000
A5: 4000
A6: 5000

Kumulation der Verkäufe (vgl. Spalte A)
B2: 1000
B3: 3000
B4: 6000
B5: 10000
B6: 15000

Provision in €
C2: 1,00
C3: 0,90
C4: 0,80
C5: 0,70
C6: 0,60

Nun steht mir eine Person gegenüber, die 1.517 Verkäufe (Zelle C14) erzielt hat. Dieser erhält also 1000*1,00€+517*0,9€=1465,3 € Provision.

Die Formel, die hierfür auch durchaus funktioniert lautet (für die Übersichtlichkeit mit Absätzen getrennt):

=WENN(C14<$B$2;C14*$C$2;
WENN(C14<$B$3;$A$2*$C$2+(C14-$B$2)*$C$3;
WENN(C14<$B$4;$A$2*$C$2+$A$3*$C$3+(C14-$B$3)*$C$4;
WENN(C14<$B$5;$A$2*$C$2+$A$3*$C$3+$A$4*$C$4+(C14-$B$4)*$C$5;
WENN(C14<$B$6;$A$2*$C$2+$A$3*$C$3+$A$4*$C$4+$A$5*$C$5+(C14-$B$5)*$C$6)))))

Für jegliche Hinweise, die Formel einzukürzen oder ggf. einen anderen Weng zu gehen, bin ich dankbar - gerade auch mit Hinblick darauf, dass der ganze Sachverhalt noch viel umfangreicher werden könnte.

Ich danke euch vielmals!

Arkadien

[LCohen]

=SUMMENPRODUKT(WENNFEHLER(EXP(LN(C14-{0.1.3.6.10.15}*1000));)*-{-10.1.1.1.1.1}/10)

Ich habe mir gestattet, 0,5 ab 15.000 zu gewähren. Sonst einfach .15 und die letzte .1 löschen!

=SUMMENPRODUKT(WENNFEHLER(EXP(LN(C14-B1:B6));)*(C2:C7-C1:C6)) mit Zeile 1 leer

[Der Steuerfuzzi]

Hallo,

hier noch eine Variante:
=SUMMENPRODUKT((C14>=B2:B6)*A2:A6*C2:C6)+VERWEIS(C14;B2:B6;C3:C7)*AGGREGAT(15;6;(C14-B2:B6)/(C14>=B2:B6);1)

[Arkadien]

Vielen Dank euch beiden. Die Varianten haben super funktioniert und werden ab sofort verwendet.