Dropdownliste wenn Bedingung erfüllt

[neuerUser_00123]

Hallo zusammen, ich stehe seit über eine Woche vor meinem Problem und komme einfach nicht weiter. Ich kann für die Bearbeitung nur Excel 2016 nutzen.

Was brauche ich? In meiner Zieltabelle muss pro Zeile eine Dropdownliste eingefügt werden. Pro Spalte muss ich eine bestimmte ID referenzieren. Ich brauche also eine Formel, die ich bei der Datenüberprüfung für die Dropdownliste eingeben kann.

Das Beispiel wäre also: "Gib mir alle Werte aus Spalte B, bei denen in Spalte A die ID 'xy' steht."

Ich stehe scheinbar so auf dem Schlauch dass ich hier alleine wirklich nicht mehr weiterkomme. Ich habe noch eine Beispieldatei angefügt (welche stark (!) vereinfacht wurde), mit der es hfftl ganz klar wird, was ich genau brauche.

Die Quell-Tabelle ist enorm groß mit über 80 verschiedenen Ids, insgesamt über 12k Zeilen. Und pro Id gäbe es dann (im Beispiel wäre es dann Spalte B "Nummer" pro Id teilweise bis zu mehr als 100 Treffer. Es würde mir also nichts bringen, die Tabelle einmal zu filtern etc.

Wer hat denn einen Tipp für mich?

[Ralf A]

Hi,

bei 2016 dürfte es formeltechnisch nicht funktionieren. Da müsstest Du wahrscheinlich VBA bemühen. Falls aber 2016 doch schon die Filterfunktion kennt, dann schau mal in den Anhang in Tabelle1 (2)...
die gelben Felder sind die Dropdonws

[el-rettev]

Hallo,

hier meine Idee:
habe ein weiteres Tabellenblatt erstellt bei dem nach jeweiliger ID gefiltert wird und dafür die Aggregat-Funktion benutzt. Sollte mit Excel 2016 funktionieren.
Dann habe ich beispielhaft den dynamischen Namesbereich für ID_1 erstellt. Dafür den Namensmanager aufrufen und die Formel für ID_1 für die anderen IDs erstellen und anpassen.
Dann Dropdownmenü erstellt und dort "=ID_1" angeben. Siehe Beispiel in Zelle I17

Formel für dynamischen Namensbereich ID_1
Für ID_2 müsste dann auf Spalte B angepasst werden.

Code:

=Dopdown!$A$3:BEREICH.VERSCHIEBEN(Dopdown!$A$3;VERGLEICH("";Dopdown!$A:$A;-1)-2;0)

[Fred11]

Hallo neuerUser_00123,

noch eine Möglichkeit:
- gesamten Zielbereich selektieren (I5:L21)
- Datengültigkeit -> Zulassen: Liste -> Quelle:
=BEREICH.VERSCHIEBEN($B$3;VERGLEICH(I$4;$A$4:$A$50;0);;ZÄHLENWENN($A$4:$A$50;I$4))
Dollarzeichen beachten
bei größerer Quelltabelle Bereiche entsprechend anpassen

Alternativ kann auch die folgende (etwas längere) Formel mit INDEX statt BEREICH.VERSCHIEBEN verwendet werden:
=INDEX(Tabelle1!$B$4:$B$50;VERGLEICH(Tabelle1!I$4;Tabelle1!$A$4:$A$50;0)):INDEX(Tabelle1!$B$4:$B$50;ZÄHLENWENN(Tabelle1!$A$4:$A$50;Tabelle1!I$4)+VERGLEICH(Tabelle1!I$4;Tabelle1!$A$4:$A$50;0)-1)
Allerdings kann diese Formel nicht direkt im Dropdown als Quelle eingetragen werden, sondern muss im Namensmanager definiert werden.
Im Dropdown dann Verweis auf den für die Formel vergebenen Namen.

Hinweis:
In der Quelltabelle müssen die IDs  in Spalte A zwingend ordentlich blockweise / sortiert aufgelistet sein - so wie dies in deinem Beispiel der Fall ist.
Wenn die IDs  durcheinander sind, also weiter unten zum Beispiel auch nochmal ID 1 vorhanden ist, funktionieren diese Formeln nicht (richtig)

Gruß
Fred

[tasibi90]

Hallo zusammen,

ich habe im Prinzip das gleiche Problem, allerdings ist es durchaus möglich, dass die Daten in der Quelltabelle nicht blockweise untereinander stehen.

Gibt es hierzu auch eine Möglichkeit? Ich benutze Excel 365, vielleicht gibt es hier auch nochmal andere Funktionaliäten.

Ich kann auch nochmal ein neues Thema erstellen, aber ich dachte mir im ersten Schritt probiere ich es mal hier.

Ich habe ein Bild und auch die xlsx angehängt, in E3 sollen dann nur die Dropdown-Items angezeigt werden, die in Tabelle 1 auch Obst sind.

Vielen Dank für die Hilfe und LG Tami :)

[rate mit]

Hallo,

hier mein Vorschlag....

[Fred11]

Hallo tasibi90,

verwende 2 Hilfsspalten, in denen du Mithilfe der Funktion FILTER alle Elemente der Kategorie Obst bzw. Gemüse separat auflistest.
Diese Hilfsspalten dann als Quelle für die Dropdowns verwenden.

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G	H	I
1	Tabelle 1			Tabelle 2				Hilfsspalten
2	Kategorie	Name			Obst	Gemüse		Obst	Gemüse
3	Obst	Apfel		Korb 1	Aprikose	Gurke		Apfel	Tomate
4	Gemüse	Tomate		Korb 2	Birne	Tomate		Aprikose	Gurke
5	Obst	Aprikose		Korb 3	Aprikose	Zucchini		Birne	Zucchini
6	Obst	Birne		Korb 4	Apfel	Gurke
7	Gemüse	Gurke
8	Gemüse	Zucchini

Zelle	Formel
H3	=FILTER($B$3:$B$8;$A$3:$A$8=H2)
I3	=FILTER($B$3:$B$8;$A$3:$A$8=I2)

Zelle	Gültigkeitstyp	Operator	Wert1	Wert2
E3	Liste		=$H$3#
F3	Liste		=$I$3#

Verwendete Systemkomponenten: [Windows (64-bit) NT 10.00] / MS Excel 2021

Diese Tabelle wurde mit Tab2Html (v2.7.1) erstellt. ©Gerd alias Bamberg

Gruß
Fred