Den zuarbeitenden Monatstunden ausrechnen

[Gert-J]

Hallo,

bei die Erstellung eines Dienstplan Musters möchte ich gerne an der Hand des Anzahl Arbeitstage im Monat (Mo-Fr) und den Wochenstunden
die abzuleistende Arbeitsstunden pro Monat ausrechen.

Die ausgerechnete Stunden sollten bei den Mitarbeitern in der Zelle unter Std. stehen. Z.B. bei Victoria in G3, bei Peter in L3 usw.

Ich habe dies mit die Funktion NETTOARBEITSTAGE versucht aber dabei weiß ich nicht ob ich dabei das richtige Zellenformat angegeben habe

Weiß jemand welche Funktion ich hierfür nutzen kann bzw. welche Zellenformat?

Vielen Dank!

[steve1da]

Hola,

Code:

=NETTOARBEITSTAGE(C6;C66;C77:C84)

Deine "Wochenstunden" sind nicht wirklich Stunden mit denen man rechnen kann. Die ergeben bei 38:30 Stunden in deinem Format 7:66 Stunden. Warum arbeitest du nicht mit echten Zeiten oder mit Tages-Sollstunden?

Gruß,
steve1da

[BoskoBiati]

Hi,

oder so:

Arbeitsblatt mit dem Namen 'Dienstplan'
	B	C	D	E	F	G
1	Mai	2018
2	Tag	Datum	Bemerkungen	Victoria		Std.
3	Soll-Stunden					570
4	Wochenstunden					30:00
5				von	bis
6	Dienstag	01.05.2018
7
8	Mittwoch	02.05.2018
9
10	Donnerstag	03.05.2018
11

Name	Bezug
FT	=Tabelle1!$A$1:$A$8

Zelle	Formel
C6	=DATUM(C1;MONAT(B1&1);ZEILE(A1))
C8	=WENN(ZEILE(A2)/2>TAG(MONATSENDE($C$6;0));"";$C$6+ZEILE(A2)/2)
G3	=NETTOARBEITSTAGE($C$6;MONATSENDE($C$6;0);FT)*(KÜRZEN(G4%;)+REST(G4%;1)/0,6)

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[Sulprobil]

Falls VBA ok ist, google nach sbCountHours.

Viele Grüße, 
Bernd P

[Gert-J]

Vielen Dank euch allen das hilft mir weiter  :19:
Ich hatte ein wenig Zeit gebraucht, hatte andere Sachen am Kopf
Ich schaue jetzt wie ich das für mich anpassen kann.

[LCohen]

A3: Der 1. eines gesuchten Monats (komplettes Datum)

B3: =
NETTOARBEITSTAGE.INTL(A3;MONATSENDE(A3;0);"0000111";FreieTage)*"8:30"+
NETTOARBEITSTAGE.INTL(A3;MONATSENDE(A3;0);"1111011";FreieTage)*"6:00"

kürzt den FR von 8:30 auf 6:00 Stunden; Wochenarbeitszeit hier im Beispiel 40:00

B3: =
NETTOARBEITSTAGE.INTL(A3;MONATSENDE(A3;0);"0000011";FreieTage)*"7:00"

hat eine 5*7-Std.-Woche. Beachte bitte die Einsen und Nullen!

FreieTage: Benannter Feiertagsbereich!

Formatiere die Formel als [h]:mm

B3: =SUMMENPRODUKT(
NETTOARBEITSTAGE.INTL(A3;MONATSENDE(A3;0);TEXT(1111111-10^(7-SPALTE($A:$G));"0000000");FreieTage)*{8.10.8.6.4.2.0}/24)

verteilt eine 38 Std.-Woche individuell auf die Wochentage, inkl. samstags 2 Stunden für die Post.