Dauer zwischen Buchung und Stornierung

[ElPhenomenon]

Hallo zusammen,

ich habe folgendes Problem:
Ich habe in einer Excel-Datei Buchungen und Stornierungen, mit den dazugehörigen Kalenderdaten, wann diese ausgelöst wurden. 
Wenn eine Stornierung getätigt wird, kommt diese mit der gleichen Buchungsnummer wie die Buchung, jedoch mit einer 1 bei neue Stornierung anstatt bei neue Buchung.
Jetzt würde ich gerne für alle Stornierungen wissen (die Datei wird fortlaufend aktualisiert), wie viele Tage zwischen Buchung und Stornierung lagen, um am Ende eine durchschnittliche Stornierungsdauer etc. berechnen zu können.
Leider beiße ich mir hieran die Zähne aus.
Hat einer eine Idee, wie ich (am einfachsten) an diese Zahl kommen kann? 

Vielen Dank im Voraus und freundliche Grüße

[steve1da]

Hola,

eine Excel-Beispieldatei wäre hilfreich.

Gruß,
steve1da

[ElPhenomenon]

Hallo,

vielen Dank für die Antwort.
Ich habe mal eine Test-Datei zur Veranschaulichung erstellt.

  Testdatei.xlsx (Größe: 9,17 KB / Downloads: 12)

Beste Grüße

[shift-del]

Moin

Code:

=[@Datum]-MINWENNS([Datum];[BuchungsNr];[@BuchungsNr];[res. Neu];1)

[WillWissen]

Hi,

ein Vorschlag mit einer Hilfstabelle:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G	H	I
1	BuchungsNr	Datum	res. Neu	storn. Neu	Stornierungsdauer		HS BNr.	HS Buchung	HS Storno
2	111	10.01.2020	1	0	9		222	11.01.2020	20.01.2020
3	222	11.01.2020	1	0	12		333	11.01.2020	23.01.2020
4	333	11.01.2020	1	0	11		666	16.01.2020	27.01.2020
5	444	13.01.2020	1	0
6	555	15.01.2020	1	0
7	666	16.01.2020	1	0
8	222	20.01.2020	0	1
9	777	22.01.2020	1	0
10	333	23.01.2020	0	1
11	666	27.01.2020	0	1

Zelle	Formel
E2	=WENNFEHLER(I2-H2;"")
G2	=WENNFEHLER(INDEX(A:A;AGGREGAT(15;6;ZEILE(Tabelle1[Datum])/(Tabelle1[Datum]=I2);1));"")
H2	=WENNFEHLER(INDEX(B:B;AGGREGAT(15;6;ZEILE(Tabelle1[BuchungsNr])/(Tabelle1[res. Neu]=1)/(Tabelle1[BuchungsNr]=G2);1));"")
I2	=WENNFEHLER(INDEX(B:B;AGGREGAT(15;6;ZEILE(Tabelle1[storn. Neu])/(Tabelle1[storn. Neu]=1);ZEILE(A1)));"")

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[shift-del]

Kam als PN rein.

vielen Dank für deine Mühe.
Deine Funktion sieht sehr schön schlank aus, leider kriege ich immer #Name ausgegeben, wenn ich versuche Sie einzugeben.
Weißt du, woran das liegen könnte?

Beste Grüße und Vielen Dank,

ElPhenomenon

Deine Excel-Version ist nicht aktuell genug.

[tibua]

Moin,

dies wäre mein Vorschlag.

=[@Datum]-SVERWEIS([@BuchungsNr];[[BuchungsNr]:[storn. Neu]];2)

Ich hoffe dir geholfen zu haben.

[ElPhenomenon]

Hallo zusammen und danke schonmal an alle für die Mühe :).

Ich bin mit der MINWENNS Lösung jetzt schon fast am Ziel, jetzt habe ich noch ein letztes Problem.

Teilweise ist es der Fall, dass Stornierungen in der Datei sind, deren Buchung vor der Speicherung der Daten ausgelöst wurden (die Buchung ist also nicht in der Datei enthalten). Für diese Fälle wird eine extrem hohe Stornierungsdauer angezeigt, welche die Statistik kaputt macht. Hat einer eine Idee, wie ich diese Stornierungen unberücksichtigt machen kann bzw. Sie aus der Stornierungsdauer Statistik bekomme?

Vielen Dank und Beste Grüße,

ElPhenomenon

[shift-del]

Moin

Code:

=WENN(ZÄHLENWENNS([BuchungsNr];[@BuchungsNr];[res. Neu];1);[@Datum]-MINWENNS([Datum];[BuchungsNr];[@BuchungsNr];[res. Neu];1);0)

[ElPhenomenon]

Hi zusammen und nochmal danke für die tolle Hilfe.

Bei mir ist jetzt noch ein letztes Problem aufgetreten,
in meiner Datei befinden sich jetzt auch noch Umbuchungen (eine Spalte mit Umbuchung neu), sodass auch für diese die Stornierungsdauer berechnet wird.
Ich habe dann versucht einfach mit der Formel =wenn(storn. neu=1;Stornierungsdauer;"") die Dauer für nur die Stornierungen zu bekommen, jedoch erkennt Excel diese Spalte nicht als Zahl, egal was ich tue (Spalte wurde x mal neu formatiert, neu berechnet, Text in Spalten etc.).


Hat einer eine Idee, woran das liegen könnte, bzw wie ich nur die Stornierungen mit in diese Formel: =WENN(ZÄHLENWENNS([BuchungsNr];[@BuchungsNr];[res. Neu];1);[@Datum]-MINWENNS([Datum];[BuchungsNr];[@BuchungsNr];[res. Neu];1);0) bekomme?

Vielen Dank schonmal und im Voraus frohe Ostern,

ElPhenomenon