Datum zählen

[chris.pin]

Hallo zusammen,

habe folgendes Problem:

Ich habe in Spalte A Datumswerte und in B eine entspr. Anwesendenzahl dazu. Nun möchte ich (in Spalte E) erst die Summe aller Datumswerte eines Monats errechnen, was bereits funktioniert. In Spalte F möchte die Summe der Anwesendenzahlen errechnen, jeweils für einen Monat. Die Formel habe ich auch hinbekommen, allerdings werde ich zwischendurch immer mal wieder Zellen mit Textinhalt zwischen den Datumswerten haben. Ihr seht das Ergebnis: #WERT!. Wie kann ich alles, was kein Datum darstellt in Spalte A herausnehmen? Ich hoffe Ihr könnt mir folgen :)

Vielen Dank schon Mal!

[UweD]

Hallo

vorab:
schreibe in D3: 01.09.2019 und formatiere die Zelle benutzerdefiniert "MMMM". Dann steht auch September drin.
das Gleiche für D4:


in E3: =SUMMENPRODUKT((1)*(MONAT($A$4:$A$999)=MONAT(D3)))
in F3: =SUMMENPRODUKT(($B$4:$B$999)*(MONAT($A$4:$A$999)=MONAT(D3)))


Die 999 ggf. anpassen


Jetzt kannst du beide Formeln markieren und runterkopieren

---

EDIT:

So wird auch das Jahr berücksichtigt.

E3: =SUMMENPRODUKT((1)*(TEXT($A$4:$A$999;"M.JJJJ")=TEXT($D3;"M.JJJJ")))
F3: =SUMMENPRODUKT(($B$4:$B$999)*(TEXT($A$4:$A$999;"M.JJJJ")=TEXT($D3;"M.JJJJ")))

[chris.pin]

Hallo UweD,

vielen Dank für die Hilfe. Mein Problem ist ja aber nicht nur der Text in der Überschrift, sondern es wird zwischendurch immer mal wieder Zwischenüberschriften geben. Es geht also um eine Formel, in die die ganze Spalte A:A einbezogen werden kann und die Texte zwischendurch nicht zu einem #WERT! führen. Außerdem kommt dazu, dass ich in meiner eigentlichen Datei die Monatsnamen in einer anderen Sprache schreibe. Deswegen hatte ich auf einen Zellbezug (wie hier mit D3) verzichtet. Geht es auch ohne Bezug, sondern nur mit der Monatsangabe (1; 2, usw.) ?

LG

[UweD]

Je nach Excelversion ginge es so...

Code:

E3:  =ZÄHLENWENNS($A:$A;">=01.09."&$D$2;$A:$A;"<=30.09."&$D$2)
F3:  =SUMMEWENNS($B:$B;$A:$A;">=01.09."&$D$2;$A:$A;"<=30.09."&$D$2)

LG UweD

[WillWissen]

Hallo Chris,

sondern es wird zwischendurch immer mal wieder Zwischenüberschriften geben.

Zwischenüberschriften haben in einer Tabelle nichts verloren - genauso wenig wie leere Spalten oder leere Zeilen. Hier https://www.online-excel.de/excel/singsel.php?f=52 bekommst du eine nützliche Erklärung.

[schauan]

Hallöchen,

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F
1
2	Datum	Anwesende		2019	Anzahl	Anw.
3				September	4	142
4	04.09.2019	31		Oktober	4	161
5	11.09.2019	35
6	18.09.2019	34
7	25.09.2019	42
8	02.10.2019	38
9	03.10.2019	41
10
11	23.10.2019	37
12	30.10.2019	45

Zelle	Formel
E3	{=SUMME(WENN(ISTZAHL(A:A);N(MONAT(A:A)=9)))}
F3	{=SUMME(WENN(ISTZAHL(A:A);WENN(GANZZAHL(MONAT(A:A))=9;B:B)))}
E4	{=SUMME(WENN(ISTZAHL(A:A);N(MONAT(A:A)=10)))}
F4	{=SUMME(WENN(ISTZAHL(A:A);WENN(GANZZAHL(MONAT(A:A))=10;B:B)))}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg