Datum einer Periode zuweißen

[diving_excel]

Hallo!

Ich habe ein Datum dem ich nun basierend auf zwei anderen Datumsangaben die Bezeichnung einer Periode zuweißen möchte.

C1: Das eingetragene Datum
D2 bis O2: Bezeichnung der Periode
D3 bis O3: Start Datum der jeweiligen Periode
D4 bis O4: End Datum der jeweiligen Periode

Code:

=WENN(UND(C1>=D$3;C1<=D$4);D$2;
WENN(UND(C1>=E$3;C1<=E$4);E$2;
WENN(UND(C1>=F$3;C1<=F$4);F$2;
WENN(UND(C1>=G$3;C1<=G$4);G$2;
WENN(UND(C1>=H$3;C1<=H$4);H$2;
WENN(UND(C1>=I$3;C1<=I$4);I$2;
WENN(UND(C1>=J$3;C1<=J$4);J$2;
WENN(UND(C1>=K$3;C1<=K$4);K$2;
WENN(UND(C1>=L$3;C1<=L$4);L$2;
WENN(UND(C1>=M$3;C1<=M$4);M$2;
WENN(UND(C1>=N$3;C1<=N$4);N$2;
WENN(UND(C1>=O$3;C1<=O$4);O$2;"N/A"))))))))))))

Je nachdem zwischen welchen wert das eingetragene Datum in C1 nun liegt, wird eine andere Bezeichnung für eine Periode ausgegeben. Soweit so gut.

Jetzt habe ich die Formel für ein Jahr geschrieben (ergo 12 Zeilen), möchte diese aber auf 4 Jahre ausweiten. 

Gibt es eine "kompaktere" Formel als für jeden Monat der vier Jahre diese eine Zeile zu wiederholen? Bei 4 Jahren hätte ich demnach ja 48 Zeilen. Das geht doch sicher schlauer?


  Test Datum - Kopie.xlsx (Größe: 9,72 KB / Downloads: 3)

Danke & Gruß!

[echo]

=SUMMENPRODUKT(($E$3:$P$3<=$C$1)*($E$4:$P$4>=$C$1)*SPALTE(A1:L1))

Hallo
die Formel sucht die Spalte raus in der das Suchkriterium Datum aus C1 passt. 
>> (SPALTE(A1:L1) damit das Ergebnis nicht mit 5 [E] sondern mit 1 beginnt.)

Das ganze in Index() liefert dir die Überschrift
=INDEX($E$2:$P$2;SUMMENPRODUKT(($E$3:$P$3<=$C$1)*($E$4:$P$4>=$C$1)*SPALTE(A1:L1)))

Das ganze kannst du jetzt beliebig erweitern
Gruß Holger

[LCohen]

=VERWEIS(C1;D3:O3;D2:O2)

denn Zeile 4 argwöhne ich als Wiedervorlage des nächstfolgenden Eintrags in Zeile 3 (Datei nicht angeschaut).

[diving_excel]

Perfekt!
Vielen Dank auch für die Erklärung!