Daten exportieren

[Hofer197]

Liebes Forum,
liebe HelferInnen!
 
Ich habe folgendes Problem: in der Zelle A1 habe ich einen Eintrag wie folgt:
 
2025-01-01 - 10 - 1
 
Mit folgender Formel habe ich den ersten Teil des Eintrags, nämlich 2025-01-01, ein eine eigene Zelle exportieren können:
 
--LINKS(A1;10)
 
Mit folgender Formel die erste Zahl, nämlich 10, hinter dem Datum, in eine eigene Zelle exportieren können:
 
GANZZAHL(--WECHSELN(TEIL(A1;14;10);" - ";","))
 
Wenn ich nun die Ganzzahl-Formel mit der Endung „+1“ versehe, dann übernimmt Excel die 10 + 1, also 11.
 
Nun möchte ich gerne beide Formeln mit Verknüpfen (&) verbinden, leider funktioniert dies nicht. Ist es bitte möglich, dass ich ohne Hilfsspalten Excel automatisch ausgeben lasse, dass der Eintrag wie vorher übernommen wird, nur eben statt der ersten Zahl hinter dem Datum eine 1 dazugerechnet wird, in meinem Fall also das Wunschergebnis wie folgt aussehen sollte:
 
2025-01-01 - 11 - 1
2025-01-01 - 12 - 1
2025-01-01 - 13 - 1
usw…
 
Solltet ihr einen Tipp haben, wäre ich euch sehr, sehr dankbar!
 
Vielen, vielen Dank für eure Hilfe im Voraus! DANKE!!!
 
Liebe Grüße und noch eine schöne Woche!
 

[cysu11]

Hi,

so sollte es gehen: =GANZZAHL(WECHSELN(TEIL(A1;14;2);" - ";","))+1

LG, Alexandra

---

..du willst es ja ohne Hilfsspalte, dann so:=LINKS(A1;10)&" - "&GANZZAHL(WECHSELN(TEIL($A1;14;2);"  -  ";","))+1&" - 1"

nachdem du in A1 dein "2025-01-01 - 10 - 1" hast, die o.g. Formel in A2 und runterziehen!

LG, Alexandra

[Hofer197]

Hallo Alexandra!
 
Danke für deine schnelle Hilfe! Die Formel passt und funktioniert perfekt, leider nur mit einer kleinen Einschränkung noch:
 
Du hast in der „Teil“-Formel statt 10 die 2 angegeben, also dass 2 Zeichen aus der Zeichenfolge übernommen werden sollen. In A1 können Werte von 1 bis ca. 100.000 hinter dem Datum stehen, also wie folgt:
 
2025-01-01 - 1 - 1
.
.
.
2025-01-01 - 100000 - 1
 
So wie die Formel jetzt ist, funktioniert sie perfekt bis 100, dann nicht mehr korrekt.
 
Gebe ich die ursprünglichen 10 bei „Teil“ wieder ein, bekomme ich ein falsches Ergebnis.
 
Darf ich noch einmal um deine/eure Hilfe fragen?
 
Sonst perfekt – super schnell wie immer! Tolles Forum!!
 
DANKE noch einmal!
 
LG

[cysu11]

...dann so: =LINKS(A1;10)&" - "&GANZZAHL(WECHSELN(TEIL($A1;14;LÄNGE(A1)-19);"  -  ";","))+1&" - 1"

LG, Alexandra

[BoskoBiati]

Hi,

Code:

=LET(xa;LÄNGE(A1);xb;TEIL(A1;14;xa-17)+1;LINKS(A1;13)&xb&RECHTS(A1;4))
=LINKS(A1;13)&TEIL(A1;14;LÄNGE(A1)-17)+1&RECHTS(A1;4)

[{Boris}]

Hi,

=--TEXTNACH(TEXTVOR(A1;"-";-1);"-";-1)

liest Dir die Zahl zwischen dem vorletzten und letzten Bindestrich aus - egal wie lang sie ist.

[BoskoBiati]

Hi Boris,

geht das in 2021?
Wenn ja, dann würde ich das wählen:

Code:

=TEXTVOR(A1;"-";-2)&"- "&TEXTNACH(TEXTVOR(A1;"-";-1);"-";-1)+1&RECHTS(A1;4)

[{Boris}]

Hi Edgar,

das kann uns der Frager beantworten. Ich selbst bin grad nicht sicher.

[Egon12]

Hallo Miteinander,

=TEXTVOR und =TEXTNACH geht leider in O2021 nicht aber vielleicht dann in O2024.

Gruß Uwe

[Hofer197]

Hallo ihr!

Zunächst, vielen Dank für eure Hilfe und den Einsatz - wie immer perfekt!!

Nun, die Text-Vor und -Nach-Formeln gibt es tatsächlich in der Version 2021 nicht. Aber kein Problem, ich konnte es mit den anderen von euch genannten Formeln lösen. Danke noch einmal!

LG