Code Schriftart und Farbe in Kopfzeile

[Primo Centurio]

Hallo zusammen

Die Kopf- und Fusszeile lassen sich ja über der Funktion des Blattschutzes nicht schützen.
Deswegen habe ich mir mit folgendem Code geholfen

Code:

Private Sub Workbook_BeforeClose(Cancel As Boolean)

Dim Blatt As Object
For Each Blatt In Sheets
        With Blatt.PageSetup

        .LeftHeaderPicture.FileName = Sheets("Tabelle2").Range("A3").Value
        .LeftHeader = vbLf & "&G"

        .CenterHeader = Sheets("Tabelle2").Range("A1").Value
        .RightHeader = Sheets("Tabelle2").Range("A2").Value

        .LeftFooter = Sheets("Tabelle2").Range("A4").Value & Sheets("Tabelle2").Range("A5").Value
      .CenterFooter = Sheets("Tabelle2").Range("A6").Value
      .RightFooter = "Seite &P von &N"

  End With
Next

End Sub

Ich würde jedoch gerne im Befehl drin haben, dass er mir die Schriftfarbe und Schriftgrösse ändert (zB vom .CenterHeader), leider habe ich es nicht hingekriegt und wollte fragen ob das überhaupt möglich ist und falls ja, wie das geht.

Danke für eure Hilfe

Lg Primo

[Case]

Hallo,  

im folgenden Beispiel wird in der Kopfzeile von Tabelle2 in der Mitte etwas mit der Schriftgröße 40 in Arial/Fett geschrieben. Eine Zeile drunter der Wert aus Tabelle2 A3 in Schriftgröße 16.:  

Code:

Option Explicit
Public Sub Main()
    Worksheets("Tabelle2").PageSetup.CenterHeader = "&""Arial,Fett""&40Beispiel" & vbLf & "&""Arial,Standard""&16" & Worksheets("Tabelle2").Cells(3, 1).Value
End Sub
'&L Richtet nachfolgende Zeichen links aus
'&C Zentriert das nachfolgende Zeichen
'&R Richtet nachfolgende Zeichen rechts aus
'&E Schaltet Doppelt Unterstreichen ein oder aus
'&X Schaltet Hochstellen ein oder aus
'&Y Schaltet Tiefstellen ein oder aus
'&B Schaltet Fettdruck ein oder aus
'&I Schaltet Kursivdruck ein oder aus
'&U Schaltet Unterstreichen ein oder aus
'&S Schaltet Durchstreichen ein oder aus
'&D Druckt das aktuelle Datum
'&T Druckt die aktuelle Zeit
'&F Druckt den Namen des Dokuments
'&A Druckt den Namen des Registers einer Arbeitsmappe
'&P Druckt die Seitenzahl
'&P+Zahl Druckt die Seitenzahl zuzüglich der angegebenen Zahl
'&P+Zahl Druckt die Seitenzahl abzüglich der angegebenen Zahl
'&& Druckt ein einzelnes kaufmännisches Und-Zeichen
'&"Schriftart" Druckt die nachfolgenden Zeichen in der angegebenen Schriftart Schriftart muss von Anführungszeichen eingeschlossen sein
'&nn Druckt die nachfolgenden Zeichen im angegebenen Schriftgrad. Geben Sie eine zweistellige Zahl an, um den Schriftgrad anzugeben
'&N Druckt die Gesamtanzahl der Seiten eines Dokumentes

[RPP63]

Moin!
Schau mal auf diese Seite:
https://docs.microsoft.com/de-de/office/...nd-footers

Gruß Ralf

[Primo Centurio]

Danke Case und Ralf

Diese Codebezeichnungen kannte ich noch nicht und habe ich gestern bei der Googlesuche wohl übersehen 
Danke euch, ich werde es ausprobieren und berichten

Lg Primo

[Primo Centurio]

Das hat alles wunderbar funktioniert :)

Danke

Ich wünsche euch ein schönes Wochenende