Bild ein- und ausblenden

[Tomsta]

Hallo zusammen,

ich bin neu hier und hoffe ihr könnt mir helfen. Ich habe schon das Forum (und andere Foren) durchsucht und es gibt viele
Beiträge zu dem Thema, aber ich bekomme es einfach nicht hin.

Ich möchte folgendes bewerkstelligen:

Wenn im Tabellenblatt4 in der Zelle B3 "Ja" steht, sollen im Tabellenblatt1, Tabellenblatt2 und Tabellenblatt3 alle Bilder mit dem Namen "Logo1"
ausgeblendet werden. Wenn in der Zelle B3 "Nein" steht, sollen alle Bilder mit dem Namen "Logo1" wieder eingeblendet werden.

Vorab danke für eure Hilfe

Viele Grüße

TOM

[Kuwer]

Hallo Tom,

füge in das schon vorhandene VBA-Modul 'DieseArbeitsmappe' folgenden Code ein:

Private Sub Workbook_SheetActivate(ByVal Sh As Object)

  Select Case Sh.Name

    Case "Tabelle1", "Tabelle2", "Tabelle3"

      Sh.Shapes("Logo1").Visible = Worksheets("Tabelle4").Range("B3").Value = "nein"

  End Select

End Sub

Gruß Uwe

[Tomsta]

Hallo Uwe,

das klappt fürs erste ganz hervorragend - vielen Dank

Es bleiben nur 2 Probleme:

1) Es wird immer nur das Originalbild aus- und eingeblendet (die Kopien des Originalbildes jedoch nicht, obwohl derselbe Name)
2) Ich habe noch 2 weitere Bilder, die aus- und eingeblendet werden müssen (ist mir gerade erst aufgefallen). Kann ich diese nachträglich umbenennen oder die Formel entsprechend erweitern?

Viele Grüße

TOM

[Kuwer]

Hallo Tom,

in den Select Case-Zeilen werden die gesuchten Namen eingetragen:

Private Sub Workbook_SheetActivate(ByVal Sh As Object)

  Dim oShape As Shape

 

  Select Case Sh.Name

    Case "Tabelle1", "Tabelle2", "Tabelle3"

      For Each oShape In Sh.Shapes

        Select Case oShape.Name

          Case "Logo1", "Banner1"

            oShape.Visible = Worksheets("Tabelle4").Range("B3").Value = "nein"

        End Select

      Next oShape

  End Select

End Sub

Gruß Uwe

[Tomsta]

Hallo Uwe,

vielen lieben Dank! Klappt perfekt  :17: 

Viele Grüße

TOM