Bezug auf Registerkarten automatisch erweitern

[Mueslie30]

Ich habe 100 Registerkarten und einen Übersichtsreiter. 
In der Übersicht habe ich in F6 folgendes Formel:
=SUMME('1'!F:F)

Es soll also von Blatt "1" die Summe in F angezeigt werden.

Wie bekomme ich das Gleiche für Blatt 2-99 hin F7=SUMME('2'!F:F), F8=SUMME('3'!F:F) usw, ohne jedes mal die Forma per Hand zu verändern?

[WillWissen]

Moin,

Code:

=SUMME(INDIREKT("'"&ZEILE()-5&"'"&"!"&"F:F"))

[Niclaus]

oder in F6:

Code:

=SUMME(INDIREKT(ZEILE(A1)&"!F:F"))

und diese Formel nach unten kopieren

Grüsse Niclaus

[{Boris}]

Hi,

falls Deine Blätter mal namentlich nicht indexierbar sein sollten (also nicht: 1, 2, 3 - sondern "Hund", "Katze", "Maus" etc.), dann kannst Du das mit der alten Excel4-Macro-Funktion ARBEITSMAPPE.ZUORDNEN lösen.
Dazu definiere den Namen Mueslie (Strg+F3) mit Bezug auf:

=ARBEITSMAPPE.ZUORDNEN(1+0*JETZT())

Wenn Dein Übersichtsblatt das erste in der Mappe ist (also das ganz links bei den Reitern), dann in irgendeine Zelle diese Formel

=SUMME(INDIREKT("'"&INDEX(Mueslie;ZEILEN($1:2))&"'!F:F"))

und so weit runterkopieren, wie es Blätter gibt.

[snb]

Strukturiere die Daten besser: sie gehören alle in nur ein Arbeitsblatt.

Dann kann man autofilter, advancedfilter, pivottable usw. verwenden.

[Niclaus]

Hallo Boris

Es ist schon lange her mit Excel-4-Makros!! Toll, dass Du darauf aufmerksam machst! Es funktioniert bestens.

Eine Frage habe ich zu Deiner Formel im Namensmanager:
=ARBEITSMAPPE.ZUORDNEN(1+0*JETZT())

Ich habe es folgendermassen versucht:
=ARBEITSMAPPE.ZUORDNEN(1)
Also ohne "+0*JETZT()"

Und in meiner Datei funktioniert es auch mit dieser verkürzten Formel richtig. Kannst Du mir sagen, warum Du diesen Teil "+0*JETZT()" eingesetzt hast?
Habe ich irgendetwas übersehen bei meiner "Verkürzungsaktion"?

Vielen Dank und freundliche Grüsse
Niclaus

[schauan]

Hallöchen,

"+0*JETZT()"

der Punkt ist, wann die Formel erneut rechnet ...

[{Boris}]

Hi Niclaus,

André hat es schon gesagt: Durch den Zusatz 0*JETZT() wird die Funktion "flüchtig" - kapiert damit also auch sofort, wenn neue Blätter eingefügt oder bestehende Blätter gelöscht werden.
Reine Vorsichtsmaßnahme sozusagen
Wenn Deine Dateistruktur fix ist, kannst Du den Zusatz natürlich entfernen, wie Du ja selbst gemerkt hast.

[Mueslie30]

Nach ein wenig rumprobieren hat die Lösung von Niclaus geholfen. (=SUMME(INDIREKT(ZEILE(A1)&"!f:f")))
Ich hatte zwar ca 10x dsas Problem, dass die Tabellenblätte 10,5 hießen, aber das habe ich dann manuell mit =Summe erledigt. 

Der Vorschlag von  {Boris}  mit dem Zuordnen hätte zwar auch geklappt, ich habe allerdings kein Dateiformat gefunden, indem ich das korrekt hätte speichern können. Excel hat mir nur "Excel5" vorgeschlagen.

[Niclaus]

Hallo Boris, hallo André

«Durch den Zusatz 0*JETZT() wird die Funktion "flüchtig"»
«wann die Formel erneut rechnet ...» 

Das leuchtet mir ein. Vielen Dank für Eure Hinweise.
Grüsse Niclaus