Bereich mit Cells kopieren

[lapunta]

Hab jetzt mein Programm so prinzipiell zum Laufen gebracht. (Wenn ich mich nicht bei allen bedankt habe, die mir geholfen haben, möchte ich das jetzt nachholen.)

Jetzt möchte ich das Handling verbessern und bin prompt wieder auf was gestoßen, was so nicht funzt, wie ich mir das gadacht habe.

im Netz habe ich folgenden Schnipsel gefunden:

Code:

Sub Schaltfläche1_BeiKlick()


   Worksheets("Tabelle1").Range("A7:D140").Copy _
   'Destination:=Worksheets("Tabelle2").Range("A7")
   
End Sub

Der funktioniert auch...

Wenn ich jedoch den Range mit Cells angebe, geht nix.

Code:

Sub Schaltfläche1_BeiKlick()
Dim i As Integer

i = 140

   Worksheets("Tabelle1").Range(Cells(7, 1), Cells(i, 4)).Copy _
   Destination:=Worksheets("Tabelle2").Range("A7")
   
End Sub

Wieso?

[Käpt'n Blaubär]

Hallo,

Wenn ich jedoch den Range mit Cells angebe, geht nix.

da ich persönlich lieber mit Cells als mit Range arbeite ist mir das auch schon einige Male aufgefallen.
Range und Cells sind nicht 1 zu 1 austauschbar.
Genau so ist das mit einigen anderen Funktionalitäten auch. Warum das so ist, wird wohl immer ein
Geheimnis von MS bleiben.

[Kuwer]

Hallo,

man muss halt nur immer einen eindeutigen Bezug herstellen:

Worksheets("Tabelle1").Range(Worksheets("Tabelle1").Cells(7, 1), Worksheets("Tabelle1").Cells(i, 4)).Copy

oder übersichtlicher

With Worksheets("Tabelle1")
 .Range(.Cells(7, 1), .Cells(i, 4)).Copy
End With

Gruß Uwe

[lapunta]

Scheint ja wohl so zu sein.

Irgendwie weigert sich Excel Bereiche aus einem anderen Tabellenblatt zu übernehmen. Ich hab jetzt meine Schaltfläche in die Tabelle1 kopiert und meinen Code  so verkürzt.

Code:

Sub Schaltfläche1_BeiKlick()
Dim i As Integer

i = 140

   Range("A7", Cells(i, 4)).Select
   Selection.Copy
   
End Sub

So zeigt mir Excel zwar den Bereich richtig an und kopiert ihn wahrscheinlich auch.

Bloss ist dann beim Destination Befehl wieder Schluss.

Code:

destination:=Worksheets("Tabelle2").Range("A7")

Wer hat 'ne Lösung parat?

[Steffl]

Hallo,

destination ist der Parameter von der Copy-Methode.

Code:

Sub Schaltfläche1_BeiKlick()
Dim i As Long  ' da Excel mehr als 32.000 Zeilen hat ;-)

i = 140

   Range("A7", Cells(i, 4)).Copy Destination:=Worksheets("Tabelle2").Range("A1")
  
End Sub

[GMG-CC]

Moin,
erst einmal: Dein letzter Code funktioniert einwandfrei! Allerdings nur, wenn er von Tabelle1 ausgeführt wird:

Code:

Sub NichtSauberAberLaeuft()
  Dim i As Integer

  i = 15
  Range("A7", Cells(i, 4)).Select
  Selection.Copy Destination:=Worksheets("Tabelle2").Range("A7")
End Sub

Die sauberste Lösung ist, wenn Quell- und Zielbereich immer gleich groß sind. Auf diese Weise ist es dann auch egal, von wo aus das Makro aufgerufen wird:

Code:

Sub GMG_Copy_MitCells()
  Dim rngQ As Range, rngZ As Range, Ze As Integer, Sp As Integer
 
  With Sheets("Tabelle1")
     Set rngQ = .Range(.Cells(2, 2), .Cells(10, 3))
  End With
  Ze = rngQ.Rows.Count
  Sp = rngQ.Columns.Count
  With Sheets("Tabelle2")
     Set rngZ = .Range(.Cells(4, 2), .Cells(4 + Ze - 1, 2 + Sp - 1))
  End With
  rngQ.Copy Destination:=rngZ
End Sub