Berechne Wochenergebnisse

[cpa]

Hallo Zusammen, ich habe zwei Spalten:

Code:

Donnerstag, 30. Juni 2016    0
Freitag, 1. Juli 2016    39
Samstag, 2. Juli 2016    10
Sonntag, 3. Juli 2016    18
Montag, 4. Juli 2016    29
Dienstag, 5. Juli 2016    30
Mittwoch, 6. Juli 2016    25
Donnerstag, 7. Juli 2016    29
Freitag, 8. Juli 2016    18
Samstag, 9. Juli 2016    0
Sonntag, 10. Juli 2016    8
Montag, 11. Juli 2016    24
Dienstag, 12. Juli 2016    26
Mittwoch, 13. Juli 2016    18
Donnerstag, 14. Juli 2016    31
Freitag, 15. Juli 2016    34
Samstag, 16. Juli 2016    8
Sonntag, 17. Juli 2016    28
Montag, 18. Juli 2016    28
Dienstag, 19. Juli 2016    47
Mittwoch, 20. Juli 2016    39
Donnerstag, 21. Juli 2016    0
Freitag, 22. Juli 2016    4
Samstag, 23. Juli 2016    0
Sonntag, 24. Juli 2016    0
Montag, 25. Juli 2016    0
Dienstag, 26. Juli 2016    6
Mittwoch, 27. Juli 2016    3
Donnerstag, 28. Juli 2016    18
Freitag, 29. Juli 2016    55
Samstag, 30. Juli 2016    8
Sonntag, 31. Juli 2016    29

Ich möchte jetzt die Zahlen in der zweiten Spalte wochenweise summieren. Und zwar immer von Montag bis Sonntag. D.h. ich muss zuerst den ersten Montag finden. Das ist kein Problem, das bekomme ich hin. Aber ich weiß nicht wie ich dann in der Formel angebe, summiere alle Zahlen von dem Suchergebnis plus 7 Tage. Und dann wieder von dort +7 Tage usw. 
Hat da jemand vielleicht eine Lösung einen Pointer wo ich am besten nachschauen könnte. 
BG,
Paul

[Peter]

Hallo,

ich würde ganz einfach eine Hilfsspalte nehmen, dort mit der Funktion Kalenderwoche() die KW auswerfen lassen und dann einfach mit Summewenn() oder einer Pivottabelle arbeiten.

[cpa]

Vielen Dank für die schnelle Antwort. 

Hat Excel 2007 Pivottabellen? ::)

SUMMEWENN geht in Ordnung. Aber da weiß ich noch nicht, wie ich der Formel mitteile, dass sie alle Zahlen einer gleichen Kalenderwoche summiert. 

Also in Worten: Addiere mir die Zahlen, wenn Kalenderwoche gleich ist. Und das dann fortlaufend für mehrere Kalenderwochen. So dass ich dann bei Daten aus 5 Wochen als Ergebnis 5 Zeilen erhalte mir den jeweiligen Summer der Woche.

[Peter]

Hallo,

natürlich hat XL2007 Pivottabellem - die gab es schon bei XL97.

Schau dir einfach mal die Hilfe für die Funktion Summewenn() an - dort ist es eigentlich recht gut beschrieben wie die Funktion funktioniert.

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G
1	Datum	Wert	KW
2	Donnerstag, 30. Juni 2016	0	27			28	139
3	Freitag, 1. Juli 2016	39	27
4	Samstag, 2. Juli 2016	10	27			Zeilenbeschriftungen	Summe von Wert
5	Sonntag, 3. Juli 2016	18	27			27	67
6	Montag, 4. Juli 2016	29	28			28	139
7	Dienstag, 5. Juli 2016	30	28			29	8
8	Mittwoch, 6. Juli 2016	25	28			Gesamtergebnis	214
9	Donnerstag, 7. Juli 2016	29	28
10	Freitag, 8. Juli 2016	18	28
11	Samstag, 9. Juli 2016	0	28
12	Sonntag, 10. Juli 2016	8	28
13	Montag, 11. Juli 2016	8	29
14

Zelle	Formel
C2	=KALENDERWOCHE(A2;2)
G2	=SUMMEWENN(C2:C13;F2;B2:B13)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Allerdings weiß ich im Moment nicht ob die Funktion Kalenderwoche() bei XL2007 den Parameter 2 kennt - das sagt dir aber auch die Hilfe.

[steve1da]

Hola,

Allerdings weiß ich im Moment nicht ob die Funktion Kalenderwoche() bei XL2007 den Parameter 2 kennt - das sagt dir aber auch die Hilfe.

Excel kennt ihn, berechnet ihn aber erst ab 2010 richtig.

Vorher:

http://www.herber.de/excelformeln und bitte suchen .../formeln.html?welcher=7

Gruß,
steve1da

[Jockel]

Hallo,

natürlich hat XL2007 Pivottabellem - die gab es schon bei XL97.
...
Allerdings weiß ich im Moment nicht ob die Funktion Kalenderwoche() bei XL2007 den Parameter 2 kennt - das sagt dir aber auch die Hilfe.

Hallo Peter, Parameter 2 ja - aber wir brauchen 21 und den kennt XL erst ab 2010...

[Peter]

Hallo,

oh Mann - gemeint war eigentlich der Parameter 21, aber beim Erstellen der Formel waren die Finger anscheinend langsamer als der Geist und da ist der 1 auf der Strecke geblieben und im Text ist mir das dann nicht mehr aufgefallen.

Dann alternativ die Formel die steve1da bereits genannt hat.

[cpa]

Vielen Dank Leute. 

Sagen wir mal, ich habe die Spalten A-C. In diesen Spalten möchte ich Daten reinkopieren, die so aussehen wie in der Tabelle oben. Jedes Mal wenn ich neue Daten (unterschiedliche vielen Zeilen usw) einfüge, dann möchte ich die Auswertung automatisch bekommen, ohne dass ich noch was hin und her kopieren muss. Nur einfügen der Daten. 

Dazu kommt, dass ich nur volle Wochen auswerten möchte, beginnend ab dem ersten Montag in den Daten. In dem Beispiel oben müssten dann z.B. die Zeilen 2-5 und 13 nicht ausgewertet werden. 

Noch mal die Vorgehensweise: 
- nach dem ersten Montag suchen und KW nehmen
- dann die 7 Werte dieser KW zusammenrechnen und in einer Zeile ablegen
- in der nächsten Zeile wieder die nächsten 7 Werte mit gleicher KW zusammenrechnen
- dabei jedes mal prüfen, ob auch alle Werte (von Montag bis Sonntag) existieren

Die Frage, ist das überhaupt ohne VBA und nur mit Hilfe von Formeln möglich?

BG,
Paul

[Jockel]

Hallo Paul, schau mal ob das passt..: (wie findest du denn den ersten Montag..?)

Arbeitsblatt mit dem Namen 'Tabelle1'
	I	J	K
2	Mo 04.07.2016	So 10.07.2016	139
3	Mo 11.07.2016	So 17.07.2016	169
4	Mo 18.07.2016	So 24.07.2016	118
5	Mo 25.07.2016	So 31.07.2016	119
6	Mo 01.08.2016	So 07.08.2016

Zelle	Formel
I2	=AGGREGAT(15;6;A1:A33/(REST(A1:A33;7)=2);1)
J2	=I2+6
K2	=WENNFEHLER(SUMME(INDEX(B:B;VERGLEICH(I2;A:A;0)):INDEX(B:B;VERGLEICH(J2;A:A;0)));"")
I3	=J2+1
J3	=I3+6
K3	=WENNFEHLER(SUMME(INDEX(B:B;VERGLEICH(I3;A:A;0)):INDEX(B:B;VERGLEICH(J3;A:A;0)));"")
I4	=J3+1
J4	=I4+6
K4	=WENNFEHLER(SUMME(INDEX(B:B;VERGLEICH(I4;A:A;0)):INDEX(B:B;VERGLEICH(J4;A:A;0)));"")
I5	=J4+1
J5	=I5+6
K5	=WENNFEHLER(SUMME(INDEX(B:B;VERGLEICH(I5;A:A;0)):INDEX(B:B;VERGLEICH(J5;A:A;0)));"")
I6	=J5+1
J6	=I6+6
K6	=WENNFEHLER(SUMME(INDEX(B:B;VERGLEICH(I6;A:A;0)):INDEX(B:B;VERGLEICH(J6;A:A;0)));"")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[cpa]

Den ersten Montag finde ich mit dieser Formel: 

=A2+7-WOCHENTAG(A2-2)

Ich schaue mir mal deine Formeln an bzw. probiere sie aus. Alternativ könnte man es evt. dann doch mit PivotTabellen machen, aber damit kenne ich mich gar nicht aus.