Beim Kopieren mehrere Spalten überspringen

[Oldpet]

Hallo,
vielleicht kann mir jemand helfen

ich habe folgende Funktion
=INDEX('[Ausgaben-2026.xlsx]Material Büro 02'!$3:$3;SPALTE('[Ausgaben-2026.xlsx]Material Büro 02'!G3))

Und beim Kopieren nach rechts, soll die Spalte G3 um 4 Spalten weiterspringen
Ich habe mir schon das Thema von 2017 angesehen, bin selber aber damit nicht weiter gekommen

       
zur Zeit sieht das Ergebnis so aus
33,69   0    0   0  140,62    0    0    0   300,50

so sollte es aber aussehen
33,69  140,62 300,50  usw

VG Peter

[BoskoBiati]

Hi,

nur mal geraten:

Code:

=INDEX('[Ausgaben-2026.xlsx]Material Büro 02'!$3:$3;7+(SPALTE('[Ausgaben-2026.xlsx]Material Büro 02'!A1)-1)*4)

[RPP63]

Moin!
So etwas in der Art?

F

G

H

I

J

K

L

M

N

O

P

Q

R

S

T

3

5

x

x

x

8

x

x

x

7

x

x

x

4

4

5

5

8

7

4

Zelle	Formel
G5	=INDEX($3:$3;SEQUENZ(;4;7;4))

Gruß Ralf

---

Für usw. wäre dies dann:

Code:

=LET(i;INDEX($3:$3;SEQUENZ(;2^10;7;4));FILTER(i;i<>0))

[slowboarder]

Hi

=INDEX('[Ausgaben-2026.xlsx]Material Büro 02'!$3:$3;SPALTE('[Ausgaben-2026.xlsx]Material Büro 02'!$G$3)+(Spalte(A1)-1)*4)


Gruß Daniel

[BoskoBiati]

Hi Daniel,

hatten wir schon in verkürzter Form:

SPALTE('[Ausgaben-2026.xlsx]Material Büro 02'!$G$3)  ergibt 7!

[slowboarder]

Hi Daniel,

hatten wir schon in verkürzter Form:

SPALTE('[Ausgaben-2026.xlsx]Material Büro 02'!$G$3)  ergibt 7!

ja.
aber wenn man jetzt auf dem Tabellenblatt "Material Büro 02" vor der Spalte G eine Spalte einfügt oder löschst, so dass sich die Tabelle verschiebt, dann passt sich " SPALTE('[Ausgaben-2026.xlsx]Material Büro 02'!$G$3) " automatisch an, während die 7 eine 7 bleibt.
Du würdest dann nicht mehr auf die richtige Zelle verweisen und müsstest die Formel korrigieren.
Meine Formel nutzt die Fähigkeit von Excel, beim Löschen oder Einfügen von Zellen betroffene Formeln automatisch mit anzupassen.
(ja, funktioniert hier nur, wenn beide Dateien geöffnet sind, weils ein externer Zellbezug ist, aber so rein aus prinzip)