Bedingten Mittelwert berechnen

[bobbieG]

Hallo,

ich habe 3 variablen:
VpNr Winkel1(grad) Reaktionszeit1(ms) Winkel2(grad) Reaktionszeit2(ms) Winkeln(grad) Reaktionszeitn(ms)
1               40                456                     40                     447                     40                      838
2               90                676                     40                   7474                      90                       898
3               90                789                     90                      838                  130                       898
4               40                786                   130                     8844                    90                      676
5               40                 667                    40                     2828                    90                      787
6              130                599                     90                     2882                    40                      787
n



Nun möchte ich eine Variable erstellen bzw. unter der spalte mit titel WInkel40_Reaktionszeit_Gesamt_MEAN die Gesamtmittelwert für 40 Grad pro VP.
auflisten.
D.h.:


VpNr    WInkel40_Reaktionszeit_Gesamt_MEAN
1          488
2           454
3          3545
4          2343
5          3434
6           343
n ..
...

Weiß jemand wie ich das bei  Excel machen kann?
Bin gerade ziemlich verzweifelt

Viele Grüße

[WillWissen]

Hallo,

stelle deine Zahlen bitte in einem Tabellenausschnitt (klick) dar - abschreiben und eine Tabelle daraus machen will in der Regel niemand.

[BoskoBiati]

Hallo,


die dargestellten Ergebnisse sind auch nicht nachvollziehbar!

[Fennek]

Hallo,
Ein Versuch als Test, ob das Deinen Erwartungen entspricht. Es wäre erheblich einfacher, wenn die Spalte nach Winkel und Zeiten sortiert werden, sonst könnte diese etwas lange Formel event. helfen:

=summenprodukt((c2:cn)*(b2:bn=40)+(e2:en)*(d2dn)+(f2:fn))/zählenwenn(b2:hn)

n ist jeweils durch die Nr der letzten vn zu ersetzen.
Mfg

[BoskoBiati]

Hallo Wüstenfuchs,



Deine Antwort ist zwar nett gemeint, allerdings nicht sehr hilfreich und falsch. Wenn die Daten so angeordnet wären, wie dargestellt, dann genügt ein einfaches MITTELWERTWENN, um ein Ergebnis zu erhalten. Allerdings passen die dargestellten Mittelwerte nicht zu den Zahlen.

[atilla]

Hallo zusammen,

mit Summenprodukt könnte es so gehen:

Arbeitsblatt mit dem Namen 'Tabelle2'
	A	B	C	D	E	F	G	H
10	VpNr Winkel1(grad) Reaktionszeit1(ms) Winkel2(grad) Reaktionszeit2(ms) Winkeln(grad) Reaktionszeitn(ms)							Mittelwert
11	1	40	456	40	447	40	838	580,33

Zelle	Formel
H11	=WENN(ZÄHLENWENN(B11:G11;40);SUMMENPRODUKT((B11=40)*(C11)+(D11=40)*(E11)+(F11=40)*(G11))/ZÄHLENWENN(B11:G11;40);"")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[BoskoBiati]

Hallo,

ich sagte bereits, da reicht ein einfaches MITTELWERTWENN:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G
1	1	40	456	40	447	40	838
2	2	90	676	40	7474	90	898
3	3	90	789	90	838	130	898
4	4	40	786	130	8844	90	676
5	5	40	667	40	2828	90	787
6	6	130	599	90	2882	40	787
7
8
9	1	580,333333	580,333333
10	2	7474	7474
11	3
12	4	786	786
13	5	1747,5	1747,5
14	6	787	787

Zelle	Formel
B9	=WENNFEHLER(MITTELWERTWENN(INDEX($A$1:$F$6;VERGLEICH(A9;$A$1:$A$6;0););40;INDEX($B$1:$G$6;VERGLEICH(A9;$A$1:$A$6;0);));"")
C9	=WENNFEHLER(MITTELWERTWENN(B1:F1;40;C1:G1);"")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[atilla]

Hallo Edgar,

ich sagte bereits, da reicht ein einfaches MITTELWERTWENN

das war für mich nicht energisch genug. :19:

Spaß bei Seite, die nach 2003 und 2007 neu hinzugekommen Formeln habe ich bisher noch wenig bis gar nicht genutzt, deshalb war mir das nicht geläufig.
Ich habe mich mit diesen Formeln auch wenig auseinandergesetzt, weil ich sie bisher nicht brauchte. Aber so lerne ich auch dazu.

[BoskoBiati]

Hallo atilla,

sollte in alten Versionen aber auch so funktionieren:

Code:

{=MITTELWERT(WENN(B1:F1=40;C1:G1))}