Autoausfüllen mit Zeilenabstand

[WillWissen]

Hi Piet,

ich habe vergessen, einen Bereich zu absolutieren; probier's mal so  

Code:

=MITTELWERTWENNS(Daten!$C$2:$C$20;Daten!$B$2:$B$20;Means!A2)

Den Bereich selbst musst du auch an deine Bedürfnisse angleichen.

[RPP63]

Irgendwie kommen wir nicht weiter, Piet!
Die von mir monierten Dollar hängen mit relativer und absoluter Adressierung in Formeln zusammen:
(Basiswissen bei Haserodt, und nicht nur dort)
http://www.online-excel.de/excel/singsel.php?f=56
Wenn Du ein Kriterium hast, kannst Du ruhig =MITTELWERTWENN() (ohne "s") nehmen, weil Du nur eine Bedingung hast.
Hast Du gleichgroße Blöcke, die sich nur errechnen, aber nicht anhand eines Kriteriums bestimmen lassen, dann ist Arithmetik vonnöten.

Ich glaube aber, Günter ist (Formel ohne "s") auf der richtigen Fährte.

[RPP63]

Die 2te Zahlen Reihe wäre dann mit =ZEILE(B1)*200-99  zu berechnen  

Nein!
Richtig ist =Zeile(B2)*100+1

	A	B
1	101	201
2	301	301
3	501	401
4	701	501
5	901	601
6	1101	701

Zelle	Formel
A1	=ZEILE(B1)*200-99
B1	=ZEILE(B2)*100+1

[Piet]

Hi Piet,

ich habe vergessen, einen Bereich zu absolutieren; probier's mal so  

Code:

=MITTELWERTWENNS(Daten!$C$2:$C$20;Daten!$B$2:$B$20;Means!A2)

Den Bereich selbst musst du auch an deine Bedürfnisse angleichen.

Die Formel klappt super! Danke dafür schon ma :)
Nur, wie ich sie richtig auf meinen originalen Datensatz anwenden soll ist mir noch nicht klar
 
Wieso genau wählst du 2 bis 20? Mit $C$ legst du ja die Inputdaten fest und mit $B$ wo sie hinsollen, oder?
Was genau bringt die A2 in der Formel? Dies ist die einzige Variable, die sich verändert, wenn ich die Formel "runterziehe".

[RPP63]

Bin raus!  :19:

[WillWissen]

Hi Piet,

Wieso genau wählst du 2 bis 20?

ich habe dir geschrieben, dass du den Bereich auf deine Bedürfnisse anpassen musst.

Mit $C$ legst du ja die Inputdaten fest und mit $B$ wo sie hinsollen, oder?

Ich empfehle dir, dich einmal mit der Syntax der von mir verwendeten Funktion zu befassen. F1 hilft da ganz ungemein.  :32:

Anstelle MITTELWERTWENNS() kannst du MITTELWERTWENN() verwenden. Auf mein Beispiel umgemünzt müsstest du es so schreiben:

Code:

=MITTELWERTWENN(Daten!$B$2:$B$20;Means!A2;Daten!$C$2:$C$20)

Hier ist die Syntax wieder ein wenig anders.

Bei meinem Lösungsvorschlag habe ich nicht berücksichtigt, dass du den Mittelwertbereich auf 100 Zeilen begrenzen willst. Das habe ich absolut nicht verstanden. Ist bei mir auch mit deiner Beispiel.xlsx nicht angekommen. Erkläre bitte genau, was du beabsichtigst.

[RPP63]

Bin doch noch nicht raus.
Mittelwerte für 100er-Blöcke ab Zeile 2 gehen z.B. (mit der Bezugs-Variante des Index) so:
(ab A2 2er Schritte)

	A	B	C	D	E	F
1	Werte	Zeilen	Mittelwert in 100er-Blöcken		2	101
2	4	2-101	103		102	201
3	6	102-201	303		202	301
4	8	202-301	503		302	401
5	10	302-401	703		402	501
6	12				502	601
7	14				602	701

Zelle	Formel
C2	=MITTELWERT(INDEX(A:A;ZEILE(A1)*100-98):INDEX(A:A;ZEILE(B1)*100+1))
E1	=ZEILE(A1)*100-98
F1	=ZEILE(B1)*100+1

Gruß Ralf

[Frogger1986]

Etwas unkonventionell aber...

Das:

Code:

=MITTELWERT(INDIREKT("data!L"&2+(ZEILE(A1)-1)*100&":L"&101+(ZEILE(A1)-1)*100))

Entspricht das:

Code:

=mittelwert(data!L2:101)

erhöht die Matrix aber beim Ziehen nach unten immer um 100 anstatt  1!

[RPP63]

@Frogger:
Wir reden über 120k Zeilen!
Da wird Dein volatiles INDIREKT() auch moderne Rechner in die Knie zwingen!
Glaub mir einfach, dass "mein" Bereichs-Index hier um den Faktor 120.000 schneller ist (kein Scherz!).
(die Formel wird nur berechnet, wenn sich etwas im Bezug ändert, Deine 120k Formel aber bei JEDER Änderung im Blatt)
http://www.online-excel.de/excel//singsel.php?f=171

Gruß Ralf

[Piet]

Danke Ralf, du hast mein Problem gelöst!

Deine Formel berechnet die Mittelwerte Problemlos.