Auswertung mit Zählenwenns

[Analog Native]

Guten Abend!

Ich fuchse mich gerade (zunächst privat) in die Welt der Excel-Formeln rein und möchte mir im Beruf zukünftig einige Prozesse erleichtern. Häufig müssen spezielle Auswertungen erstellt werden, die in unserer HR-Software nicht vorgesehen sind. Diese enthalten erheblich mehr Daten als das von mir erstellte Beispiel, jedoch ist das Prinzip vergleichbar.

Die Datei "Fortbildung Übung.xlsx"
  Fortbildung Übung.xlsx (Größe: 10,36 KB / Downloads: 14) enthält auf dem 1. Tabellenblatt alle fiktiven Teilnehmer von ebenfalls fiktiven Seminaren. Auf dem 2. Tabellenblatt soll eine Auswertung erstellt werden, wie sich diese Teilnhmer auf die Geschlechter und auf Präsenz- bzw Onlineseminare verteilen. Mit der Zählenwenns-Funktion habe ich es geschafft, diese Auswertung ein Stück weit zu vereinfachen.

Nun soll die Auswertung noch um die Angabe erweitert werden, wie viele der Teilnehmer - ebenfalls getrennt nach Geschlecht und Präsenz-/Onlineseminar - im Home Office arbeiten. Diese Angabe ist jedoch in der zentralen MA-Liste enthalten ("MA-Liste Übung.xlsx"
  MA-Liste Übung.xlsx (Größe: 9,31 KB / Downloads: 13) ).

Aus meiner Sicht muss es doch möglich sein, die Zählenwenns-Formel entsprechend zu erweitern. Hierzu wären zusätzlich zu den bereits definierten Bedingungen zwei weitere Bedingungen zu definieren:

1) Der Name des Mitarbeiters in Spalte A des 1. Tabellenblatts in "Fortbildung Übung.xlsx" taucht auch in Spalte A der zentralen Mitarbeiterliste auf ('[MA-Liste Übung.xlsx]Tabelle1'!$A2:$A28)

und

2) In Spalte F der zentralen Mitarbeiterliste befindet sich ein "x".

Die 2. zusätzliche Bedingung kann ich definieren, jedoch scheitere ich trotz intensiver Recherche und Versuchen daran, die 1. zusätzliche Bedingung zu definieren. Bei meinen lückenhaften Excel-Kenntnisse kann ich es aber natürlich auch nicht ausschließen, dass ich mit der Zählenwenns-Funktion auf dem völlig falschen Dampfer bin..

Falls jemand Zeit und Lust hat, sich mit meiner Frage zu beschäftigen und mir idealerweise ein Feedback geben kann, wäre ich sehr dankbar!

Schönen Abend noch allerseits!

[UweD]

Hallo

- Öffne beide Dateien
- füge in der Datei Fortbildung im Blatt "Fortbildung" in H2 folgende Formel ein
- nach unten kopieren

Code:

=INDEX('[MA-Liste Übung.xlsx]Tabelle1'!$F:$F;VERGLEICH(A2&B2;'[MA-Liste Übung.xlsx]Tabelle1'!$A:$A&'[MA-Liste Übung.xlsx]Tabelle1'!$B:$B;0))

Damit holst du die HomeOfficeInfo aus der MA Liste
Die MA Datei kannst du nun schließen ( nicht wundern, die Formeln erweitern sich automatisch um den Pfad ) 


im Blatt "Auswertung" in B3 dann die erweiterte Formel aus B2

Code:

=ZÄHLENWENNS(Fortbildungen!C2:C18;"m";Fortbildungen!E2:E18;"x";Fortbildungen!H2:H18;"x")

Die anderen Formeln dann analog dazu.


LG UweD

[HKindler]

Hi,

wenn du ein aktuelles Excel hättest, dann könntest du ohne Hilfsspalten auskommen. Die Anzahl der männlichen Teilnehmer eines Präsenzseminars im Homeoffice erhältst du z.B. mit

Code:

=LET(x;FILTER(Fortbildungen!A:B;(Fortbildungen!C:C="m")*(Fortbildungen!E:E="x"));y;'[MA-Liste Übung.xlsx]Tabelle1'!$A:$F;SUMME(ZÄHLENWENNS(INDEX(y;0;1);INDEX(x;0;1);INDEX(y;0;2);INDEX(x;0;2);INDEX(y;0;6);"x")))

Da dein Excel aber zu alt ist, machst du dir am besten im Blatt Fortbildungen eine Hilfsspalte (Spalte G), die sich die Info Homeoffice aus der anderen Datei holt. Folgende Formel gehört in G2 und muss runter gezogen werden:

Code:

=INDEX('[MA-Liste Übung.xlsx]Tabelle1'!$F:$F;VERGLEICH(A2&"|"&B2;'[MA-Liste Übung.xlsx]Tabelle1'!$A:$A&"|"&'[MA-Liste Übung.xlsx]Tabelle1'!$B:$B;0))

Damit hast du in Spalte G x oder 0 stehen. und kannst das ganz normal in dein ZÄHLENWENNS mit aufnehmen.

Wie immer gilt: wenn es zu langsam wird, sollte man keine ganzen Spalten verwenden sondern die Bereiche auf das notwendige Maß begrenzen.

[PIVPQ]

Hallo

Anbei angedachte Lösung mit PQ/Pivot/Datenschnitt.
Zuvereinfachung habe ich aus der Mitarbeiterliste in die andere Datei mit rein kopiert, es ist auch anders möglich falls gewünscht.

[Analog Native]

Wow, vielen herzlichen Dank für die schnellen Antworten und die tollen Tipps! Funktioniert einwandfrei