Artikel Werte mit aktuellsten Datum wiedergeben (Index und Max oder kgrösste)

[rooky]

Hallo zusammen,
ich hoffe ihr könnt mir weiterhelfen. Ich versuche anhand einer Artikelnummer die aktuellsten Werte von Excel wiedergeben zu lassen.
In Tabelle 1 soll die Artikelnummer eingetragen werden (A2, A3,...) Anhand der Artikelnummer soll dann der aktuellste Wert aus Tabelle 2 gefunden werden. Wenn das größte Datum des Artikels gefunden wurde, soll in Tabelle 1 in den Spalten B, C und D jeweils der entsprechende Wert wiedergegeben werden.



  Zwei Suchkriterien.xlsx (Größe: 9,29 KB / Downloads: 7)

Beste Grüße

[steve1da]

Hola,

in B2 als Matrixformel (mit Strg-Shift-Enter abschließen):

Code:

=MAX(WENN(Tabelle2!$A$2:$A$19=A2;Tabelle2!$B$2:$B$19))

In C2:

Code:

=VERWEIS(2;1/(Tabelle2!$A$2:$A$19&Tabelle2!$B$2:$B$19=$A2&$B2);Tabelle2!D$2:D$19)

Die Formel nach rechts und nach unten ziehen.

Gruß,
steve1da

[rooky]

Hi steve1da,

bin total begeistert, das ging sehr schnell. 

Vielen Dank!!! 

Grüße

[Jockel]

Hallo, wenn ich die Formeln eingebe, dort wo sie sollten bekomme ich das..:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D
1	Artikel	Prüfer	Gewicht	Wert
2	A111	01.01.2018	0,5	27
3	B222	01.01.2014	0,8	14
4	C333	01.01.2017	0,7	15
5	D444	01.01.2016	0,5	27
6	E555	01.01.2014	0,8	14
7	F666	01.01.2002	1,7	19

Zelle	Formel
B2	{=MAX(WENN(Tabelle2!$A$2:$A$19=A2;Tabelle2!$B$2:$B$19))}
C2	=VERWEIS(2;1/(Tabelle2!$A$2:$A$19&Tabelle2!$B$2:$B$19=$A2&$B2);Tabelle2!D$2:D$19)

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Jockel]

Hallo, ich biete mit (eine Formel reicht...!)

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D
1	Artikel	Prüfer	Gewicht	Wert
2	A111	Jürgen	0,5	27
3	B222	Hans	0,8	14
4	C333	Hans	0,7	15
5	D444	Ulf	0,5	27
6	E555	Hans	0,8	14
7	F666	Ulf	1,7	19

Zelle	Formel
B2	=INDEX(Tabelle2!C$2:C$100;VERGLEICH(MAX(INDEX(Tabelle2!$B$2:$B$100*(Tabelle2!$A$2:$A$100=$A2);));MMULT((Tabelle2!$A$2:$A$100=$A2)*Tabelle2!$B$2:$B$100;1);0))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

oder mit zwei Formeln - als Hilfsspaltenlösung..:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F
1	Artikel	Prüfer	Gewicht	Wert		HS
2	A111	Jürgen	0,5	27		2
3	B222	Hans	0,8	14		4
4	C333	Hans	0,7	15		7
5	D444	Ulf	0,5	27		11
6	E555	Hans	0,8	14		13
7	F666	Ulf	1,7	19		17

Zelle	Formel
B2	=INDEX(Tabelle2!C$2:C$100;$F2)
F2	=VERGLEICH(MAX(INDEX(Tabelle2!$B$2:$B$100*(Tabelle2!$A$2:$A$100=$A2);));MMULT((Tabelle2!$A$2:$A$100=$A2)*Tabelle2!$B$2:$B$100;1);0)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[steve1da]

Hola,

@Jockel: stimmt, hab ich nicht beachtet. Du hast natürlich Recht. Danke!

Gruß,
steve1da

[rooky]

Hi Jockel,

richtig, das gleiche bekomme ich auch raus. Eigentlich sollte unter Prüfer der Prüfer stehen, jedoch wird hier mit Hilfe von steves ersten Formel das aktuellste Datum des Artikels ermittelt. Mit der zweiten Formel wird anhand des Artikels und des Datums dann die beliebige Spalte und der Zellenwert wiedergegeben. 
Ich habe die Spalte mit dem Prüfer in Tabelle 2 an das Ende kopiert und die Formeln entsprechend in Tabelle 1 nach rechts gezogen (wie steve geschrieben hat), somit wurde  auch der Prüfer angezeigt. Also alles super!
Ich muss die Spalten noch um 17 weitere Werte erweitern, von daher eignet sich diese Lösung sehr gut.

Grüße

[Jockel]

Hallo, ich habe ja auch nicht geschrieben, dass die Lösung von steve1da falsch ist... ... nur das sie nicht ganz zur konkreten Aufgabenstellung passte.  Deswegen habe ich ja auch zwei alternative Lösungen vorgeschlagen.

Zu dem hier..:

Hi Jockel,

...
Ich muss die Spalten noch um 17 weitere Werte erweitern...
Grüße

 
Da würde ich die zweite Variante meiner Vorschläge wählen...

[rooky]

Hallo, ich biete mit (eine Formel reicht...!)

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D
1	Artikel	Prüfer	Gewicht	Wert
2	A111	Jürgen	0,5	27
3	B222	Hans	0,8	14
4	C333	Hans	0,7	15
5	D444	Ulf	0,5	27
6	E555	Hans	0,8	14
7	F666	Ulf	1,7	19

Zelle	Formel
B2	=INDEX(Tabelle2!C$2:C$100;VERGLEICH(MAX(INDEX(Tabelle2!$B$2:$B$100*(Tabelle2!$A$2:$A$100=$A2));MMULT((Tabelle2!$A$2:$A$100=$A2)*Tabelle2!$B$2:$B$100;1);0))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

wow  :23: die ist ja noch eleganter, auch wenn es etwas dauern wird bis ich sie verstehe  :19: Aber so kann ich mir die Hilfsspalte sparen.

Danke schön!!
Grüße

[Elex]

Hi rooky,

alternativ kannst du  Tabelle2 erst nach Datum(absteigend) und dann nach Artikelnummer(A-Z) sortieren. Dann geht es mit Sverweis. Was für die Nachvollziehbarkeit sicher leichter ist.

B2     =SVERWEIS($A2;Tabelle2!$A$2:$E$19;SPALTE(C1);0)