Array Keine Doppelungen

[Hamza420]

Hallo Liebe Kollegen,

ich habe eine Frage und hoffe Ihr könnt mir mittels Makro oder Formel weiterhelfen. Wäre klasse.

Ich habe eine Liste mit Namen (Spalte A). Diese Namen kommen u.a. doppelt vor. Nach den Namen kommen bestimmte Zahlen vor (Spalte B). Nun soll in Spalte C eine 1 eingetragen werden aber nur einmal pro Name. Wenn möglich auf der jeweils größeren Zahl. Ich habe an eine Array Lösung gedacht aber leider weiß ich nicht wie ich das hinbekomme.

Ich hoffe ich konnte mich richtig ausdrücken. Ich habe eine Test Datei hinzugefügt. Außerdem habe ich eine 1 da eingetragen, wo das Endergebnis eine 1 Automatisch eintragen sollte.

Ich hoffe Ihr könnt mir helfen.

Lieben Gruß

[steve1da]

Hola,

als Matrixformel:

Code:

=WENN(B2=MAX(WENN($A$2:$A$7=A2;$B$2:$B$7));1;"")

Müsste bei Sabrina die 1 nicht bei der 55 stehen?

Gruß,
steve1da

[Jockel]

Hallo, und ohne CSE-Abschluss..:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C
1	Name	Zahl	HC
2	Hamza	98	1
3	Hamza	1
4	Hamza	1
5	Sabrina	45
6	Sabrina	55	1
7	Peter	100	1

Zelle	Format	Wert
C2	Standard;;	1

Zelle	Formel
C2	=(B2=MAX(INDEX(B$2:B$3000*(A$2:A$3000=A2);)))*1

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[Hamza420]

Hallo steve1da und jockel,

vielen Dank für eure Lösungen

Steve du hast recht eine 1 sollte immer in der höheren Zahl stehen. Da habe ich ein Fehler gemacht.

Die Lösung von Jockel funktioniert sehr gut. Kannst du mir nochmal die Formel erklären? 

Gruß an alle.

[Jockel]

Hallo...
...
Die Lösung von Jockel funktioniert sehr gut. Kannst du mir nochmal die Formel erklären? 

Gruß an alle.

Hallo, die Lösung von Steve funktioniert genauso gut... und ist wahrscheinlich einfacher zu erklären. Ich bin leider kein ErklärBär...

[Hamza420]

Hallo,

Vielen Dank nochmal. Leider ist einer Freundin etwas aufgefallen, was ich leider auch nicht beachtet habe und daher leider auch nicht im Forum erwähnt hatte. Ich hoffe Ihr könnt mir dennoch helfen.

Ich habe Hierzu wieder eine Datei hinzugefügt. Wenn der Fall auftritt, dass z.b. Ein Name zweimal oder sogar 4 x vorkommt aber exakt die gleiche Zahl drin steht also z.B. 50 und 50 oder 4 x 25 dann soll nur in einer (am besten die oberste muss aber nicht sein) eine 1 stehen in der Spalte C. Gibt es eine alternative zu max in der Formel?

Ich hoffe Ihir könnt mir helfen.

[Jockel]

Hallo, das geht z.B. so..:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D
1	Name	Zahl	HC	HC Soll
2	John	25	1	1
3	John	25
4	John	25
5	John	25
6	Sabrina	55	1	1
7	Peter	75	1	1
8	Peter	25
9	Sabine	100	1	1
10	Joseph	25
11	Joseph	75	1	1
12	Jan	50	1	1
13	Jan	50
14	Sabrina	45

Zelle	Format	Wert
C2	Standard;;	1

Zelle	Formel
C2	=(VERWEIS(1;0/HÄUFIGKEIT(0;1/(1+($A$2:$A$14=A2)*$B$2:$B$14));ZEILE($A$2:$A$14))=ZEILE())*1

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

... oder auch so..:

Arbeitsblatt mit dem Namen 'Tabelle1 (2)'
	A	B	C	D
1	Name	Zahl	HC	HC Soll
2	John	25	1	1
3	John	25
4	John	25
5	John	25
6	Sabrina	55	1	1
7	Peter	75	1	1
8	Peter	25
9	Sabine	100	1	1
10	Joseph	25
11	Joseph	75	1	1
12	Jan	50	1	1
13	Jan	50
14	Sabrina	45

Zelle	Format	Wert
C2	Standard;;	1

Zelle	Formel
C2	=(ZEILE(A1)=VERGLEICH(AGGREGAT(14;6;$B$2:$B$14/($A$2:$A$14=A2);1);MMULT(($A$2:$A$14=A2)*B$2:B$14;1);0))*1

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg