Arbeitstagenzähler

[Unsainted]

Hallo Leute,

ich bräuchte mal eure Hilfe.

Ich möchte eine Zelle, der im Grunde von 26 bis 1 runterzählt (ohne 0). Also wie ein Countdown.
Die 26 steht für die 26 Arbeitstage im Monat (Mo-Sa)
Jeden Tag soll die ExcelTabelle beim Öffnen kontrollieren welchen Tag man hat und die restlichen Arbeitstage wiedergeben und die Sonntage sollen ignoriert werden, da es keine Arbeitstage sind. Am 01.09.2021 soll es "26" zurückgeben und am 30.09.2021 die "1"

Ich hab mich bisschen informiert und wollte mithilfe der Formel " =Heute() " und  " =TAG(Heute()) " etwas basteln aber am Ende kam nichts raus. Ich kriege es nicht hin die Formel richtig zusammen zu stellen .... Ich will es für jeden Monat nutzbar machen egal ob 28, 29, 30 oder 31 Tage.

Ich hoffe ihr könnt mir weiterhelfen. Vielleicht denke ich einfach zu kompliziert.

LG

[shift-del]

Moin

Code:

=NETTOARBEITSTAGE.INTL(A1;$A$30;11)

[RPP63]

Moin!
Ohne Hilfszellen:

Code:

=NETTOARBEITSTAGE.INTL(HEUTE();MONATSENDE(HEUTE();0);11)

Wobei ich mal hoffe, dass Du kein 19 Jahre altes Excel hast.
Das Monatsende könnte man dann mittels DATUM(JAHR(HEUTE());MONAT(HEUTE())+1;0) ermitteln.
Als Ersatz von NETTOARBEITSTAGE.INTL()
https://www.herber.de/excelformeln/pages...Woche.html

Wird dann halt etwas länger:

Code:

=DATUM(JAHR(HEUTE());MONAT(HEUTE())+1;0)+1-HEUTE()-GANZZAHL((WOCHENTAG(HEUTE();2)+DATUM(JAHR(HEUTE());MONAT(HEUTE())+1;0)-HEUTE())/7)

Gruß Ralf

[RPP63]

… und mit einer benamten Feiertagsliste wird die "Altformel" gleich noch einmal flauschiger:
(C1 ist nur für Excel 365 / Online)

	A	B	C
1	Rest 25		01.01.2021
2	Rest 25		02.04.2021
3			04.04.2021
4			05.04.2021
5			01.05.2021
6			13.05.2021
7			23.05.2021
8			24.05.2021
9			03.06.2021
10			03.10.2021
11			01.11.2021
12			25.12.2021
13			26.12.2021

Formeln der Tabelle

Zelle Formel A1 =DATUM(JAHR(HEUTE());MONAT(HEUTE())+1;0)+1-HEUTE()-GANZZAHL((WOCHENTAG(HEUTE();2)+DATUM(JAHR(HEUTE());MONAT(HEUTE())+1;0)-HEUTE())/7)- -SUMMENPRODUKT((Feiertage>=HEUTE())*(Feiertage<=DATUM(JAHR(HEUTE());MONAT(HEUTE())+1;0))*(WOCHENTAG(Feiertage;2)<7)) C1 =SORTIEREN(EINDEUTIG( LET(a;RPP63;j;JAHR(HEUTE()); FFT;DATUM(j;1;{1;121;276;305;359;360})+WENN(MONAT(DATUM(j;2;29))=2;{0;1;1;1;1;1}); OFT;RUNDEN((TAG(MINUTE(j/38)/2+55)&".4."&j)/7;)*7-6+{-2;0;1;39;49;50;60}; x;ZEILEN(FFT);y;ZEILEN(OFT);z;SEQUENZ(x+y); WENN(z<x+1;INDEX(FFT;z);INDEX(OFT;z-x)) ))) A2 =NETTOARBEITSTAGE.INTL(HEUTE();MONATSENDE(HEUTE();0);11;Feiertage)

Namen in Formeln Zelle Name Bezieht sich auf A1 Feiertage =Tabelle1!$C$1:$C$13 A2 Feiertage =Tabelle1!$C$1:$C$13

Gruß Ralf

[RPP63]

Immer wieder erstaunlich!
Da macht sich jemand die Mühe, sich hier zu registrieren, formuliert sogar eine lesbare Threaderöffnung, und dann … isser wech.

[shift-del]

Moin Ralf

Erinnert mich an diesen Zeitgenossen:
https://www.clever-excel-forum.de/User-froooast

Ich erwarte nicht oft Feedback aber hier habe ich mich geärgert und meine Ignore-Liste ist wieder etwas länger geworden.

[BrianMolko1980]

habe das jetzt auch mal ausprobiert und als Ausgabewert kommt bei mir #NAME?

Formel ist diese: =ARBEITSTAGE(A3;C3;Feiertage).

evtl hat jemand eine Idee.

Danke

[BoskoBiati]

Hi,

zum Einen solltest Du mal die Antworten lesen, dann die Excel Funktionen verinnerlichen und die FEIERTAGE solltest Du auch als Name definieren!!!!!

   

[RPP63]

evtl hat jemand eine Idee.

Vorsicht, Gag!
Dann geh doch zu Netto!

[BrianMolko1980]

von meiner Seite her war es ernst gemeint.

möchte halt noch viel lernen und das mit dem #Name hatte ich noch nie gehabt.

Ron

---

hab das INTL vergessen