Anzahl zählen - in Abhängigkeit einer zweiten Variablen.

[bigcuno]

Hallo, 

ich hätte mal wieder ein Problem bei dem ich leider seit mehreren Tagen anstehe. 

Ich habe in der Spalte B "PNR" die Personalnummer stehen. 
In der Spalte F "Monat" die Monate 1 bis 12. 

Nun würde ich gerne für das gesuchte Monat in der Zelle K1 sämtliche Personalnummern zählen die sich im Monat 2, (in diesem Beispiel Februar) befinden und nur einmal vorkommen. 
Das selbe mit Personalnummern die öfter vorkommen - hierbei darf eine doppelte Personalnummer nicht doppelt gezählt werden. 

   

Ich bin für sämtliche Tipps und Tricks dankbar. 
im Anhang die Vorlage. 


  VORLAGE - PKW.xlsx (Größe: 17,28 KB / Downloads: 5)

Vielen Dank im Voraus für eure Hilfe

[BoskoBiati]

Hi,

versuche mal das:

Code:

=ANZAHL2(EINDEUTIG(FILTER(B:B;F:F=K1)))

[oee]

  VORLAGE - PKW222.xlsx (Größe: 18,64 KB / Downloads: 6)

[bigcuno]

Hallo, 


ihr seid großartig von den 2 Fragen bleibt somit nur noch eine übrig. 

• ich würde gerne für das gesuchte Monat in der Zelle K1 sämtliche Personalnummern zählen die sich im Monat 2, (in diesem Beispiel Februar) befinden und nur ein einziges mal vorkommen.    
  
• Das selbe mit Personalnummern die öfter vorkommen hierbei darf eine doppelte Personalnummer nicht doppelt gezählt werden.   --> genial, auf die Formel wäre ich ohne euch nicht gekommen! 
  

  VORLAGE - PKW222 (1).xlsx (Größe: 19,49 KB / Downloads: 1)


Dickes Danke im Voraus. 

LG

[EA1950]

Hallo,

1) Anzahl der PNR, die im Monat 2 nur genau 1x vorkommen: 
=ANZAHL2(EINDEUTIG(FILTER($B:$B;$F:$F=$K$1);;1))

2) Anzahl der PNR, die im Monat 2 mindestens 2x vorkommen: 
=ANZAHL2(EINDEUTIG(FILTER($B:$B;$F:$F=$K$1))) -  ANZAHL2(EINDEUTIG(FILTER($B:$B;$F:$F=$K$1);;1))

oder aber beide Formeln kombiniert:
=LET(mo;$K$1; pnrMo;FILTER($B:$B;$F:$F=mo); Anz1x;ANZAHL2(EINDEUTIG(pnrMo;;1)); Anz2m;ANZAHL2(EINDEUTIG(pnrMo))-Anz1x; VSTAPELN(Anz1x;Anz2m))

[BoskoBiati]

gelöscht, fehlerhaft.

[{Boris}]

Hi,

dafür hat EINDEUTIG noch einen 3. Parameter:

=ANZAHL2(EINDEUTIG(FILTER(B2:B840;F2:F840=K1);0;1))

[bigcuno]

ich bin begeistert - die Formeln funktionieren alle wie sie sollen. 

Wird Zeit dass ich mir diese in Ruhe anschaue und ebenfalls aneigne. 

Vielen Dank an alle Helfer! 

LG