Anzahl eines Wertes je Monat zählen, mit Punktwert versehen und kumulieren

[e.rico]

Hallo zusammen,

ich würde gerne in der beigefügten Tabelle eine Auswertung vornehmen, wie groß der Aufwand in den jeweiligen Monaten ist und in einem Diagramm visualisieren.

Den Wert "gering" würde ich damit gerne mit einem Punktwert von 1 verbinden, "mittel" mit einem Punktwert von 2 und "hoch" mit einem Punktwert von 3. Daraus soll sich ein kumulierter Punktwert je Monat ergeben, der dann in die Hilfstabelle darunter eingetragen wird, die ich dann wiederum in einem Diagramm visualisieren möchte.

Welche Formel muss ich hierfür in den farbig markierten Zellen verwenden?


P.S. Bitte seht mir als blutigem Anfänger die untechnische Ausdrucksweise und mögliche Verkomplizierungen nach. Ich freue mich über jeden Tipp und jede Alternativlösung. Vielen Dank.

[Jockel]

Hallo, das könnte man so machen..:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D
1	Datum	Projekt	Aufwand	Kennzahl
2	15.01.2020	Projekt 1	gering	1
3	29.02.2020	Projekt 2	mittel	2
4	03.03.2020	Projekt 3	hoch	3
5	15.03.2020	Projekt 4	gering	1
6	18.03.2020	Projekt 5	mittel	2
7	02.05.2020	Projekt 6	mittel	2
8	17.05.2020	Projekt 7	hoch	3
9	01.06.2020	Projekt 8	hoch	3
10
11
12	Monat	Aufwand
13	Januar	1
14	Februar	2
15	März	6
16	April	0
17	Mai	5
18	Juni	3
19	Juli	0
20	August	0
21	September	0
22	Oktober	0
23	November	0
24	Dezember	0

Zelle	Formel
D2	=VERGLEICH(C2;{"gering"."mittel"."hoch"};0)
B13	=SUMMENPRODUKT((TEXT($A$2:$A$9;"MMMM")=A13)*1;$D$2:$D$9)

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[e.rico]

Großartig, danke für das schnelle Feedback. Noch eine ergänzende Frage: Wenn ich nicht mit 1, 2 und 3 als Punktwert arbeiten will sondern mit beliebigen Zahlen (z.B. 25, 100 und 200) als Abstufung für den Aufwand, wie müsste ich die Formeln dann modifizieren?

[Jockel]

Hallo, dann die erste Formel abändern in ..:

PHP-Code:

=INDEX({25.100.200};VERGLEICH(C2;{"gering"."mittel"."hoch"};0)) 


oder ..:

PHP-Code:

=VERWEIS(C2;{"gering"."hoch"."mittel"};{25.200.100}) 


Oder du legst eine Wertetabelle an... ... das wäre dann felixbel, du kannst die Werte  ändern, ohne die Formeln händisch anpassen zu müssen..:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G	H
1	Datum	Projekt	Aufwand	Wert			Aufwand	Wert
2	15.01.2020	Projekt 1	gering	25			gering	25
3	29.02.2020	Projekt 2	mittel	100			mittel	100
4	03.03.2020	Projekt 3	hoch	200			hoch	200
5	15.03.2020	Projekt 4	gering	25
6	18.03.2020	Projekt 5	mittel	100
7	02.05.2020	Projekt 6	mittel	100
8	17.05.2020	Projekt 7	hoch	200
9	01.06.2020	Projekt 8	hoch	200

Zelle	Formel
D2	=SVERWEIS(C2;$G$1:$H$4;2;0)

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[e.rico]

Perfekt. Jetzt die hoffentlich letzte Frage. Wenn auch nur in einer Zelle keine Wert für den Aufwand eingetragen ist, funktioniert die Summenproduktformel nicht mehr. Kann man das noch abstellen?

[Jockel]

Perfekt. Jetzt die hoffentlich letzte Frage. Wenn auch nur in einer Zelle keine Wert für den Aufwand eingetragen ist, funktioniert die Summenproduktformel nicht mehr. Kann man das noch abstellen?

Hallo, dann ist es doch nicht perfekt..?!?! Aber ich verstehe die Frage nicht, die Datei habe ich nicht mehr... neu zu bauen bin ich zu faul. Poste doch mal deinen neuesten Stand...

[e.rico]

Aktueller Dateistand

[Jockel]

Hallo, beim nächsten Mal bitte eine Versionsnummer in den Dateinamen einfügen...:

Problemlösung: WENNFEHLER() -->

PHP-Code:

=WENNFEHLER(INDEX({25.100.200};VERGLEICH(C2;{"gering"."mittel"."hoch"};0));0) 


[e.rico]

Jetzt aber: Perfekt. Herzlichen Dank!