Anzahl der Wochentage bei automatischem Kalender ermitteln - Fehler bei Samstagen

[harko38]

Hallo liebe Excel Freunde,

ich kämpfe seit einiger Zeit mit einer Formel die mir bei einem "Kalender" die Anzahl der jeweiligen Wochentage im Monat ausgibt.

Meine Tabelle sieht wie folgt aus:
C1    =DATUM(2018;1;1)

A3:A5 ist zu einer Zelle verbunden und beinhaltet      =C1     Die Zelle ist mit tt. formatiert somit wird  01. angezeigt
B3:B5 ist zu einer Zelle verbunden und beinhaltet      =A3     Die Zelle ist mit ttt formatiert somit wird Mo angezeigt

A6:A8 ist zu einer Zelle verbunden und beinhaltet       =WENN(ISTZAHL(A3);WENN(A3+1<=MONATSENDE($A$3;0);A3+1;"");"0")
B6:B8 ist zu einer Zelle verbunden und beinhaltet      =A6     Die Zelle ist mit ttt formatiert somit wird Di angezeigt

A6 und B6 sind nach unten kopiert bis 31 Felder (Monatstage) vorhanden sind, also bis A95 bzw. B95

Bis hierher funktioniert alles, auch wenn man Jahreszahl und Monat wechselt.

In B100 bis B106 soll nun die Anzahl der jeweiligen Wochentage mit folgender Formel gezählt werden
B100 =SUMMENPRODUKT((WOCHENTAG($B$3:$B$93;2)=1)*1)
B101 =SUMMENPRODUKT((WOCHENTAG($B$3:$B$93;2)=2)*1)
B102 =SUMMENPRODUKT((WOCHENTAG($B$3:$B$93;2)=3)*1)
B103 =SUMMENPRODUKT((WOCHENTAG($B$3:$B$93;2)=4)*1)
B104 =SUMMENPRODUKT((WOCHENTAG($B$3:$B$93;2)=5)*1)
B105 =SUMMENPRODUKT((WOCHENTAG($B$3:$B$93;2)=6)*1)
B106 =SUMMENPRODUKT((WOCHENTAG($B$3:$B$93;2)=7)*1)

Das Ergebnis von Zelle B100 lautet richtig 5, also 5 Montage in diesem Monat.
Die Ergebnisse der anderen Zellen sind auch richtig außer B105. Hier wird der Wert 64 angezeigt.

Ich habe die Tabellen zigmal nach Fehleingaben überprüft. Komplett neu erstellt, aber dieser Fehler kommt ständig.
Ohne verbundene Zellen wird der richtige Wert angezeigt.

Ich hoffe mein Problem ist nachvollziehbar und es kann mir jemand helfen.

mlg
Harald


  Mappe1.xlsx (Größe: 15,21 KB / Downloads: 2)

[Jockel]

Hallo, verbundene Zellen sind Schietkram...:

Versuche mal..: 

PHP-Code:

=SUMMENPRODUKT((REST(ZEILE($A$1:$A$93);3)=1)*(WOCHENTAG($B$3:$B$95;2)=ZEILE(A1))) 


[BoskoBiati]

Hi,

blöder Tabellenaufbau!

Code:

=SUMMENPRODUKT((WOCHENTAG($B$3:$B$93;2)=6)*(B3:B93<>""))

eine leere Zelle hat den Wert 0, der Tag 0 ist ein Samstag!

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D
1			Februar
2	Datum	Tag
3	01.	Do
4
5

Zelle	Format	Wert
C1	MMMM	01.02.2018
D1	MMMM

Zelle	Formel
A3	=WENN($C$1+KÜRZEN(ZEILE()/3;)-1>MONATSENDE($C$1;0);"";$C$1+KÜRZEN(ZEILE()/3;)-1)
B3	=A3

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[harko38]

Hallo Jockel, hallo BoskoBiati

erstmal ein großes Danke für die raschen Antworten.

Wenn ich mir auch eure beiden Lösungsvorschläge erst zerpflücken muß weil ich sie nicht so ganz verstehe scheinen jedoch beide zu funktionieren.

Zu meinen verbundenen Zellen - die Tabelle ist natürlich wesentlich größer als im Beispiel und ich muss die Möglichkeit haben in die Zellen C3, C4 und C5 bis W3, W4 und W5 usw. jeweils Daten einzutragen.

Mit eurer Lösung kann ich jedenfalls sehr gut arbeiten - Danke nochmal.

lg Harald

[Jockel]

Hallo Harald, du solltest in deiner Datei die Formel über den Monatsletzten überarbeiten...  Wenn du den Februar betrachtest gibt's ne Überraschung... 

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B
84	28.	Mi
85
86
87
88
89
90	0	0
91
92
93	0	0
94
95

Zelle	Formel
A84	=WENN(ISTZAHL(A81);WENN(A81+1<=MONATSENDE($A$3;0);A81+1;"");"0")
B84	=A84
A87	=WENN(ISTZAHL(A84);WENN(A84+1<=MONATSENDE($A$3;0);A84+1;"");"0")
B87	=A87

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[BoskoBiati]

Hi,

deswegen habe ich eine eingestellt, die da resistent ist!