Altersberechnung 2000er Jahrgänge

[SirTankALot]

Guten Morgen Community,

ich habe mich hier angemeldet, weil ich auf eure Hilfe hoffe. Momentan arbeite ich mit einer selbst erstellten Berechnungsmaske, die mir meine Arbeit sehr erleichtert. Allerdings bin ich jetzt auf ein Problem gestoßen.

Zur Maske:

Ihr müsst euch das so vorstellen. Ich habe eine Arbeitsmappe, die sich ihre Werte aus einer ausgelagerten Datenbank (ebenfalls eine Excel-Datei) zieht. Ich arbeite also grundsätzlich sehr oft und viel mit SVERWEISen.
Nun habe ich in dieser Datenbank eine Spalte, die Personenkennziffern enthält die so aufgebaut sind:

Bsp: 080482G45850, wobei die ersten 6 Zeichen den Geburtstag darstellen. Das 7. Zeichen ist der Anfangsbuchstabe des Nachnamens und der Rest ist nicht wirklich wichtig.

Ich lese den Geburtstag also mit dieser Formel aus:

=WENN(SVERWEIS('Berechnung'!D5;[Datensatz.xlsx]Datensatz!$A$1:$AG$7030;19;0)="";"";

DATUM(TEIL(SVERWEIS('Berechnung'!D5;[Datensatz.xlsx]Datensatz!$A$1:$AG$7030;19;0);5;2);   --> Für das Jahr
TEIL(SVERWEIS('Berechnung'!D5;[Datensatz.xlsx]Datensatz!$A$1:$AG$7030;19;0);3;2);               --> Für den Monat
TEIL(SVERWEIS('Berechnung'!D5;[Datensatz.xlsx]Datensatz!$A$1:$AG$7030;19;0);1;2)))              --> Für den Tag

Das hat alles wunderbar funktioniert. Bis heute.... :D

Ich habe das erste Mal mit 2000er Jahrgängen zutun deren Geburtstag nun mit 00 endet. Das veranlasst Excel natürlich dazu, dass das Geburtsjahr auf 1900 gesetzt wird und ich denke mit den folgenden Jahrgängen wird das ähnlich laufen. (01, 02, 03 usw.)

Ich hoffe ich konnte das Problem verständlich schildern. Und ihr könnt mir helfen.


Liebe Grüße

[steve1da]

Hola,

ein Problem hast du zwar nicht geschildert aber ich rate mal:

Code:

=DATUM(WENN(TEIL(A1;5;2)="00";2000;TEIL(A1;5;2));TEIL(A1;3;2);LINKS(A1;2))

Gruß,
steve1da

[Der Steuerfuzzi]

Hallo,

oder Du lässt die Excel-Logik für Dich arbeiten:

Code:

=(TEIL(SVERWEIS('Berechnung'!D5;[Datensatz.xlsx]Datensatz!$A$1:$AG$7030;19;0);1;2))&"."&TEIL(SVERWEIS('Berechnung'!D5;[Datensatz.xlsx]Datensatz!$A$1:$AG$7030;19;0);3;2)&"."&TEIL(SVERWEIS('Berechnung'!D5;[Datensatz.xlsx]Datensatz!$A$1:$AG$7030;19;0);5;2))*1

Zur Erläuterung: Excel wandelt bei der Eingabe zweistellige Jahreszahlen bis 29 in Jahre ab 2000 und Jahreszahlen ab 30 in Jahre ab 1900 um.

[SirTankALot]

Wow...ich bin regelrecht beeindruckt, wie einfach sich so manche Sachen umsetzen lassen, obwohl man immer so kompliziert denkt.

Ich habe die Formel geändert und es funktioniert einwandfrei. Auch mit folgenden Jahrgängen (2001 usw.)

Sind die &-Zeichen dann einfach nur ein Ersatz für das "Verketten"?

lg

[Der Steuerfuzzi]

Sind die &-Zeichen dann einfach nur ein Ersatz für das "Verketten"?

Ja, so ist es.

[LCohen]

=--TEXT(TEIL(SVERWEIS('Berechnung'!D5;[Datensatz.xlsx]Datensatz!$A$1:$AG$7030;19;0);1;6);"00\.00\.00")

klappt (wegen der ziemlich besch ... Systematik der Personalnummer, bei der das Jahr nicht am Anfang steht, wie es anzuraten wäre).

[SirTankALot]

Ich danke allen für die Zeit und die überaus schnelle Hilfe. Das Problem hat sich lösen lassen. :)

Liebe Grüße und schönes Wochenende.