Aktueller Tag näher am Mittwoch oder am Samstag

[LCohen]

Bin ja gar nicht sicher, ob ich ihn richtig verstanden habe.

[shift-del]

Zumindest ergeben beide Formeln die gleichen Ergebnisse.

[Meliodas]

Also erstmal vielen Dank für die ganzen Antworten.
Die Formel mit dem Summenprodukt funktioniert scheinbar bei mir.

Folgendes:

Die Formel soll in folgender Formel eingebaut werden:
=WENN(UND(C30="X";C29="X";C35=0);(B5*C27*C32)+(B4*C27*C33);WENN(UND(C29="x";C30="x";C35=1);(C27*D5*C32)+(D4*C27*C33);WENN(UND(C29="x";C35=0);C27*C32*B5;WENN(UND(C29="x";C35=1);D5*C27*C32;WENN(UND(C30="X";C35=0);C27*C33*B4;WENN(UND(C30="X";C35=1);D4*C27*C33;""))))))

Die Formel soll greifen wenn in C29+C30 ein "x" ist.

Kann man das so abändern?

B5*C27*C32 = einzelpreis x Menge x Erscheinungsdatum (Menge 2)
Die andere besagt das gleiche, nur mit einem anderen Einzelpreis.

[LCohen]

OT: Schrumpfung


Ausgangsformel
=WENN(UND(C30="X";C29="X";C35=0);(B5*C27*C32)+(B4*C27*C33);WENN(UND(C29="x";C30="x";C35=1);C27*D5*C32)+D4*C27*C33);WENN(UND(C29="x";C35=0);C27*C32*B5;WENN(UND(C29="x";C35=1);D5*C27*C32;WENN(UND(C30="X";C35=0);C27*C33*B4;WENN(UND(C30="X";C35=1);D4*C27*C33;""))))))


Ausgliederung von C27
=WENN(UND(C30="X";C29="X";C35=0);(B5*C32)+(B4*C33);WENN(UND(C29="x";C30="x";C35=1);(D5*C32)+(D4*C33);WENN(UND(C29="x";C35=0);C32*B5;WENN(UND(C29="x";C35=1);D5*C32;WENN(UND(C30="X";C35=0);C33*B4;WENN(UND(C30="X";C35=1);D4*C33;""))))))*C27


Neuanordnung der Bedingungen
=C27*(
(C35=0)*((C29="X")*(C32*B5)+(C30="X")*(C33*B4))+
(C35=1)*((C29="X")*(C32*D5)+(C30="X")*(C33*D4)))


WAHL-Steuerung per C35
=C27*((C29="X")*(C32*WAHL(C35+1;B5;D5))+(C30="X")*(C33*WAHL(C35+1;B4;D4)))


Mit =SUMME((C29:C30="X")*... könnte man - unter anderen Umständen - noch weiter schrumpfen.

[BoskoBiati]

Hi,

Deine ganze Formel kann man auf das reduzieren:

Code:

=C27*(INDEX(5:5;2+(C35=1)*2)*C32*(C29="x")+INDEX(4:4;2+(C35=1)*2)*C33*(C30="x"))

Edit: LCohen war schneller und kürzer.

[LCohen]

Dafür hat Boskos Formel die notwendige Struktur, um sie wie folgt zumindest logisch noch einzudampfen:

Bosko:
=C27*(INDEX(5:5;2+(C35=1)*2)*C32*(C29="x")+INDEX(4:4;2+(C35=1)*2)*C33*(C30="x"))

ungetestet und evtl. falsch (ohne Gewähr):
{=C27*SUMME(INDEX(4:5;3-ZEILE($1:$2);2+(C35=1)*2)*C32:C33*(C29:C30="x"))}

[Meliodas]

Vielen Dank für die Info. Wusste gar nicht das man das kürzen kann.
Bin halt nur ein Anfänger.

Da muss ich mich mal schlau lesen um das nachvollziehen zu können.
Danke!

[Meliodas]

Aber wie ist das nun mit dem Näher am Mittwoch/Samstag..

Da ich die neue Formel von BoskoBiati und LCohen noch nicht ganz nachvollziehen kann, verstehe ich noch nicht, wie ich die Formel
von Shift-Del einsetzen kann..

[LCohen]

Wusste gar nicht das man das kürzen kann. Bin halt nur ein Anfänger.

Das hat nichts mit Excel zu tun, sondern mit Mathe Unterstufe.

[BoskoBiati]

Hi, 

ich würde sagen, es wäre Zeit für eine Mustertabelle, in der die verschiedenen Möglichkeiten dargestellt sind, damit man das an konkreten Zahlen fest machen kann.