Dieses Forum nutzt Cookies
Dieses Forum verwendet Cookies, um deine Login-Informationen zu speichern, wenn du registriert bist, und deinen letzten Besuch, wenn du es nicht bist. Cookies sind kleine Textdokumente, die auf deinem Computer gespeichert werden. Die von diesem Forum gesetzten Cookies werden nur auf dieser Website verwendet und stellen kein Sicherheitsrisiko dar. Cookies aus diesem Forum speichern auch die spezifischen Themen, die du gelesen hast und wann du zum letzten Mal gelesen hast. Bitte bestätige, ob du diese Cookies akzeptierst oder ablehnst.

Ein Cookie wird in deinem Browser unabhängig von der Wahl gespeichert, um zu verhindern, dass dir diese Frage erneut gestellt wird. Du kannst deine Cookie-Einstellungen jederzeit über den Link in der Fußzeile ändern.

Aggregat - KKleinste - ohne Duplikate mit Bedingung
#1
Hallo zusammen ,

ich steh seit ein paar Tagen auf dem Schlauch bei der Suche nach einer Lösung für folgendes Thema - da geschäftlich ein bissel abstrahiert.
Ich habe eine Excelliste mit Tierfutter (Spalte N - dargestellt in Zahlen) und Tieren (Spalte S - Text). Ich will alle Tiere (einmal) auflisten wenn ich ein bestimmtes Tierfutter eingestellt habe, also ohne Duplikate.
Sprich ich habe eine Gesamtliste, aus der nur die Tiere übernommen werden die dem Tierfutter zugeordnet sind. Ohne die Einschränkung des Tierfutters habe ich es hinbekommen (besser gesagt zusammenkopiert Smile ; siehe Zelle S152 nach unten)
=WENNFEHLER(INDEX($S$1:$S$140;AGGREGAT(15;6;ZEILE($S$1:$S$140)/(($S$1:$S$140<>"")*(VERGLEICH($S$1:$S$140&"_";$S$1:$S$140&"_";0)=ZEILE($S$1:$S$140)));ZEILE(S2)));"")

Ich habe es aber leider nicht geschafft die Einschränkung mit dem Tierfutter zu integrieren und hoffe auf Eure Hilfe!

Vielen Dank im Voraus,

Joe


Angehängte Dateien
.xlsx   200726_Template_Tierfutter_v003.xlsx (Größe: 188,99 KB / Downloads: 9)
Antwortento top
#2
O152: =EINDEUTIG(FILTER(S41:S49;N41:N49=S149)) für Excel 365 oder das kostenlose XL-Online oder GDocs
[-] Folgende(r) 1 Benutzer sagt Danke an LCohen für diesen Beitrag:
  • JayDi
Antwortento top
#3
Hallo LCohen,

vielen Dank für die Hilfe & die Lösung - in dem Fall werde ich noch ein oder 2 Monate warten bis Office 365 ausgerollt wird, wie von Dir angedeutet ist das eine Lösung die nicht abwärts kompatibel ist (zumindest mit Excel 2016 funktioniert sie noch nicht).

Vielen Dank für die Hilfe & ein großes Lob an alle, die die Zeit aufbringen und sich engagieren anderen zu helfen!
Antwortento top
#4
Hallo,

hier noch eine Möglichkeit mit einer Version vor 365:
Zitat:O152 =WENNFEHLER(INDEX($S:$S;AGGREGAT(15;6;ZEILE($N$1:$N$140)/($N$1:$N$140=$S$149);1));"")
O153 =WENNFEHLER(INDEX($S:$S;AGGREGAT(15;6;ZEILE($N$1:$N$140)/(($N$1:$N$140=$S$149)*(ZÄHLENWENN($O$152:O152;$S$1:$S$140)=0));1));"")
Gruß
Michael
[-] Folgende(r) 1 Benutzer sagt Danke an Der Steuerfuzzi für diesen Beitrag:
  • JayDi
Antwortento top
#5
Hallo Michael,

vielen Dank für Deine Hilfe - ich habe Deine Antwort noch ein bissel abgeändert, damit - für den Fall dass in Spalte S noch kein Tier steht - in der Zusammenfassung keine "0" angezeigt wird, somit bekomme ich jetzt eine komplette Liste und bin am Ziel!  100 15 18

O153= {=WENNFEHLER(INDEX($S:$S;AGGREGAT(15;6;ZEILE($N$1:$N$140)/(($N$1:$N$140=$S$149)*(WENN($S$1:$S$140<>"";ZÄHLENWENN($O$152:O152;$S$1:$S$140)=0)));1));"")}

{} mit Strg + Shift + Enter

Danke für Eure Hilfe!
Antwortento top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste