Abfrage mit WENN(ISTFEHLER(FINDEN UND

[AJ13]

Hallo,
ich habe eine Tabelle mit Veranstaltungsorten bei denen ich eine bestimmte Abfrage nicht hin bekomme. 
Wenn ich wissen will, ob in meiner Spalte "Veranstaltungsort" in Spalte H irgendwo in den Zellen die Begriffe "kirche", "Kirche" oder "St." auftauchen bekomme ich da hin.
=WENN(ISTFEHLER(FINDEN("kirche";H3;1));WENN(ISTFEHLER(FINDEN("Kirche";H3;1));WENN(ISTFEHLER(FINDEN("St.";H3;1))"";"K");"K");"K")
Diese Formel funktioniert und ich bekomme das gewünschte "K" als Ergebnis.
Nun will ich diese Formel kombinieren mit der Abfrage ob der Veranstaltungsort "Kirche" in einer bestimmten Stadt (Spalte G) ist. Die Stadt, die mich interessiert, ist immer dieselbe, aber in der Spalte stehen noch hunderte andere Städte. Ach ja, im Gegensatz zur Spalte Veranstaltungsort füllt der Name der gesuchten Stadt die jeweilige Zelle vollständig aus, steht also nicht irgendwo. Hat jemand eine Idee?

[steve1da]

Hola,

Code:

=WENN(SUMME(ZÄHLENWENNS(H3:H10;{"kirche";"st."};G3:G10;"köln"));"K";"")

Gruß,
steve1da

[AJ13]

Das funktioniert leider noch nicht ganz.
Häufig taucht der Begriff "Kirche" nicht allein in der Zelle auf, sondern ist Teil eines Namens deshalb habe ich zuvor mit der Funktion "finden" gearbeitet.
Ich will hier auch noch nicht zählen, sondern nur wissen, ob in genau einer Zelle die Begriffe "kirche", "Kirche", "St." etc auftauchen und zugleich in derselben Zeile in einer anderen Spalte eine bestimmte Stadt auftaucht.

[steve1da]

Hola,

sorry, hab ich überlesen..

Code:

=WENN(SUMME(ZÄHLENWENNS(H3:H10;{"*kirche*";"*st.*"};G3:G10;"köln"));"K";"")

Gruß,
steve1da

[AJ13]

Super! Vielen Dank, es funktioniert großartig! Das erspart mir bei mehreren tausend Einträgen und zahlreichen Abfragen ähnlicher Struktur enorm viel Handarbeit! :19:

[AJ13]

Noch eine ergänzende Frage:
Was muss ich machen um die Formel zu erweitern um mehrere Städte gleichzeitig abzufragen?

Code:

=WENN(SUMME(ZÄHLENWENNS(H3:H10;{"*kirche*";"*st.*"};G3:G10;"köln"));"K";"")

Wenn ich statt"köln" mehrere Städte in geschweiften Klammern eingebe, funktioniert es leider nicht.
Irgend eine Idee?

[Jockel]

Hallo, kannst du bitte (d)eine (Beispiel)Datei mit Wunschergebnis posten, das könnte beim Helfen helfen...

[AJ13]

Anbei eine Beispieldatei, die hoffentlich mein Problem erklärt. Alles grün markierte funktioniert. Rot leider nur zum Teil. Wie kann ich mehrere Kriterien gleichzeitig abfragen?
Irgendeine Idee?

Browserwechsel hat geholfen. Mit Opera hat der Upload funktioniert, Danke!

[Jockel]

Anbei eine Beispieldatei, die hoffentlich mein Problem erklärt...

Hallo, ich sehe keine Datei... Ich konnte heute auch keine hochladen. Andere können das... Komisch, vielleicht liegt's am Browser...

[Jockel]

Hallo, meinst du so..? Nachtrag:CES-Abschluß tut nicht not... (^_-)

Arbeitsblatt mit dem Namen 'Tabelle1'

A

B

C

D

E

F

G

H

I

J

K

L

2

Jahr

M

T

M

T

Land

Stadt/Gemeinde

Veranstaltungsort

alle [n] -unbek.

alle -Kirche

Heimat -Kirche

National -Kirche

3

1931

DR

Köln

xkirche

AK

HK

NK

4

1948

ABZ

Köln

Freiheitskirche

AK

HK

NK

5

1950

BRD

München

Kathedrale

AK

NK

6

1960

BRD

Köln

Kirche

AK

HK

NK

7

1965

BRD

Köln

Dom

AK

HK

NK

8

1970

BRD

Köln

St. XY

AK

HK

NK

9

1975

Italien

Rom

Basilica

AK

10

1980

Italien

Neapel

Kloster

AK

Zelle	Formel
I3	=WENN(H3="#unbekannt#";"u";"")
J3	=WENN(SUMME(ZÄHLENWENN(H3;{"*kirche*";"*St.*";"*Dom*";"*Kathedrale*";"*Eglise*";"*Chiesa*";"*Münster*";"*Kloster*";"*Kyrka*";"*Basilica*"}));"AK";"")
K3	=WENN(SUMME(ZÄHLENWENNS(H3;{"*kirche*";"*Ev. Vereinshaus*";"*Friedhof*";"*Diakonissenhaus*";"*St.*";"*Dom*";"*Kathedrale*";"*Münster*";"*Kloster*";"*Basilica*"};G3;"Köln"));"HK";"")
L3	{=WENN(SUMME(ZÄHLENWENNS(H3;{"*kirche*";"*Ev. Vereinshaus*";"*Friedhof*";"*Diakonissenhaus*";"*St.*";"*Dom*";"*Kathedrale*";"*Münster*";"*Kloster*";"*Basilica*"};F3;MTRANS({"DR";"ABZ";"BRD"})));"NK";"")}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Verwendete Systemkomponenten: [Windows (32-bit) NT :.00] MS Excel 2013

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg