AGGREGAT-Formel bei mehrer Suchkriterien

[David Volker]

Guten Tag zusammen,

ich habe ein Problem, an dem ich seit 2 Tagen hänge und benötige fachkundigen Rat.

Ich habe eine Tabelle angelegt, in der Aktenordner mit deren Inhalt und ihrer Position im Aktenarchiv verzeichnet sind. Über Datenüberprüfung habe ich drei Dropdown Auswahlfelder angelegt, über die ich wiederum mit Hilfe einer AGGREGAT-Formel meine Tabelle schnell auf das Gesuchte filtern kann. Soweit bekomme ich auch die gewünschte Ergebnisse. Allerdings erhalte ich nur Ergebnisse, wenn ich bei allen drei Auswahlfelder auch eine Auswahl treffe. Ich stelle mir allerdings vor, dass wenn ich nur zwei Einschränkungen treffe, ebenfalls Ergebnisse erhalte?
Habe probiert WENN-Formeln zu integrieren, allerdings nicht mit gewünschtem Ergebnis ...

Meine Formel sieht so aus:

=WENNFEHLER(INDEX(tab_Hilfstabelle[Projektnummer];AGGREGAT(15;6;ZEILE(tab_Hilfstabelle[Projektnummer])/((tab_Hilfstabelle[Kombi Projekt]=Übersicht!$D$3)*(tab_Hilfstabelle[Kombi Ordner]=Übersicht!$D$6)*(tab_Hilfstabelle[Spalte1]=Übersicht!$D$9));ZEILE()-12)-1;1);"")

Hab auch im Internet bereits lange geschaut aber nichts entsprechendes gefunden.
In einem Youtube-Video habe ich eine ähnliche Tabelle mit Auswahlfeldern gefunden, leider geht auch dort  der Autor, Herr Thehos, nicht darauf ein, wie man Ergebnisse bei nur zwei Auswahl-Einschränkungen bekommt. (https://www.youtube.com/watch?v=He3dblboncw)

Daher hoffe ich sehr darauf, dass mir jemand hier helfen kann!
Für jeden Hinweis bin ich sehr dankbar!

Beste Grüße an alle,
David

[Jonas0806]

Hallo David,

sollen wenn, wenn die entsprechenden Dropdowns ausgewählt sind, alle Bedingungen zutreffen, oder nur mindestens eine von ihnen?

Lade am besten mal eine Beispieldatei hoch.

[David Volker]

Hallo Jonas,

leider ist meine Datei viel zu groß geworden um sie hoch zuladen. Ich muss deshalb auf das Beispiel aus dem Video zurückgreifen. Aber die Systematik ist die gleiche und ich kann es nachher übertragen.

In der Beispieldatei geht es um Aufträge die in die Auswahlgruppen "Land", "Kunde" und "Verkäufer" unterteilt werden können. Wähle ich ein "Land" und einen "Kunden", aber gebe keinen "Verkäufer" an, so erhalte ich zur Zeit keine Ergebnisse. Allerdings möchte ich in diesem Fall alle Aufträge angezeigt bekommen, die in dem "Land" für den "Kunden" vorliegen, egal mit welchem "Verkäufer".



Beste Grüße

[Jonas0806]

Guten Morgen,

genau das macht doch der Autofilter?!

[David Volker]

Guten Morgen,

dass das mit dem Autofilter geht ist mir bewusst, finde ich aber optisch nicht sehr ansprechend.
Ich möchte am Ende auf einem Tabellenblatt eine Übersicht mit den Auswahlfeldern sowie den Ergebnissen und auf einem zweiten die eigentliche Tabelle darstellen.

Falls sich das nicht über die AGGREGAT-Funktion und die Auswahlfelder/Dropdowns realisieren lässt, werde ich wohl auf den Autofilter zurückgreifen müssen.

Vielleicht findet sich ja noch eine Lösung

Beste Grüße

[Jonas0806]

Hallo,

was hälst Du von Datenschnitten? Ich persönlich finde die sehr elegant ;)

[neopa]

Hallo David,

hab mir jetzt die PIVOTlösung von Jonas nicht weiter angeschaut. Diese wäre aber für Massendaten auf jeden Fall auch mein Favorit.

Die von Dir gesuchte  Formellösung würde so aussehen:

in I4:   

Code:

[b]=ZÄHLENWENNS(B:B;I1;C:C;WENN(I2=""[/b][b];"*";I2);E:E;WENN(I3="";"*";I3))[/b]

in H7:

Code:

=WENNFEHLER(INDEX(tab_Afrika[Auftrag];AGGREGAT(15;6;ZEILE(tab_Afrika[Auftrag])/
(tab_Afrika[Land]=I$1)/(tab_Afrika[Kunde]=WENN(I$3="";tab_Afrika[Kunde];I$2))/
(tab_Afrika[Verkäufer]=WENN(I$3="";tab_Afrika[Verkäufer];I$3));ZEILE()-6)-1;1);"")

und nach unten kopieren.

[David Volker]

Hallo Jonas,
hallo Werner,

vielen Dank euch!
An Datenschnitte habe ich bisher nicht gedacht, ist aber auch evtl. auch eine sehr gute Lösung. Werde ich auf jeden Fall auch mal probieren.

Meinen Fehler bei der WENN-Formel habe ich mit deiner Lösung gefunden. Vielen Dank, jetzt geht es.
Bei dir ist auch noch ein kleiner Fehler drin:
Es muss [...]/(tab_Afrika[Kunde]=WENN[I$2="";tab_Afrika[Kunde];I$2))[...] sein.


Code:

Code:

=WENNFEHLER(INDEX(tab_Afrika[Auftrag];AGGREGAT(15;6;ZEILE(tab_Afrika[Auftrag])/
(tab_Afrika[Land]=I$1)/(tab_Afrika[Kunde]=WENN(I$2="";tab_Afrika[Kunde];I$2))/
(tab_Afrika[Verkäufer]=WENN(I$3="";tab_Afrika[Verkäufer];I$3));ZEILE()-6)-1;1);"")

Nochmals herzlichen Dank!

Beste Grüße