2er Pasch anzeigen (WENN Befehl)

[mavsn]

Hallo, also ich haben einen Button der immer wieder 3 zufällige Zahlen ausgibt. Wenn 2 davon identisch sind soll der Text "2er" ausgegeben werden. Das Habe ich so hingekriegt :

 =WENN(ODER(A25=A26;A25=A27;A26=A27);"2er";"Niete")

Aber das Problem ist, der Text wird auch ausgegeben wenn ein 3er Pasch gewürfelt wird. Wie kriege ich hin dass bei einem 3er auch "Niete " ausgegeben wird?

Danke im Voraus.

[Hydronaut]

Mavsn,

vielleicht so:

Code:

=WENN(ZÄHLENWENN(A25:A27;MODUS.EINF(A25:A27))=2;"2er";"Niete")

[mavsn]

Top, funktioniert.

Danke dir!

[BoskoBiati]

Hi,

oder so:

Code:

=wenn(ZÄHLENWENN(A1:C1;MEDIAN(A1:C1))=2;"Pasch";"Niete")

[Der Steuerfuzzi]

Hallo,

ich würde das so machen:
=Wenn(((A25=A26)+(A25=A27)+(A26=A27))=1;"Pasch";"Niete")

[Jonas0806]

Hallo,

oder so

PHP-Code:

=WENN(MAX(HÄUFIGKEIT(A25:A27;A25:A27))=2;"Pasch";"") 


[mavsn]

Hey weitere Frage, nun möchte ich die beides verbinden. Bei einem zweier soll "2er" und bei einem 3er "3er", und bei einer Niete "Nix" ausgegeben werden.
Die Funktionen die ich ausprobiert habe waren alle "zu lang" laut Excel. Kann mir jemand weiter helfen

[Jonas0806]

Hallo,

sollte dann so klappen

PHP-Code:

=WAHL(MAX(HÄUFIGKEIT(A25:A27;A25:A27));"Niete";"Pasch";"Drilling") 


[mavsn]

Hat alles geklappt, vielen dank!

[mavsn]

Eine letzte Frage hätte ich noch wenn ich darf :)

=WAHL(MAX(HÄUFIGKEIT(A25:A27;A25:A27));A25+A26+A27;"2er";(A25+A26+A27)*3)

Dort wo 2er ausgegeben wird, sollten die 2 identischen zahlen zusammengerechnet (addiert) und dann mit 2 multipliziert werden.


Danke im Voraus.