Datumsangaben in Excel, die unterschiedliche Rechenschritte auslösen?

[Blödi]

Hallo Excel-Experten!

Folgendes Problem:

Spalte A: Datumsangaben
Spalte B: Zahlen
Spalte C: Zahlen aus Spalte B um 0,50 aufgerundet (also z.B. 5,55 auf 6,00, 5,45 auf 5,50).
(Keine Abrundung, nur Aufrundung).
 
   A               B      C     
1 01.06.2017 6,50  6,50  
2 05.06.2017 4,75  5,00  
3 15.06.2017 9,25  9,50  
4 15.06.2017 5,64  6,00  
5 22.06.2017 4,60  5,00  

Jetzt das Problem:
Wenn sich in Spalte A ein Datum wiederholt, dann sollen die dazugehörigen Werte aus Spalte B vor Aufrundung addiert werden und erst danach die Summe aufgerundet werden.

In A3 und A4 wiederholt sich ein Datum. 
Die dazugehörigen Werte aus Spalte B sind 9,25 und 5,64. Wenn man diese addiert bekommt man 14,89. Dieser Wert soll dann aufgerundet werden (also auf 15,00).
Wenn man die beiden Werte separat aufrundet (9,25 -> 9,50 und 5,64 -> 6,00) und danach addiert, erhält man 15,50, also einen höheren Wert. Dies soll vermieden werden.

Ich würde also eine weitere Spalte D einfügen, in der dann die Summe aus B3 und B4 abgebildet würde:


   A               B      C     D
1 01.06.2017 6,50  6,00  
2 05.06.2017 4,75  5,00  
3 15.06.2017 9,25  9,50  15,00
4 15.06.2017 5,64  6,00  15,00
5 22.06.2017 4,60  5,00  


Ich benötige also eine Formel, die in Spalte A erkennt, wenn sich eine Datumsangabe wiederholt und danach die gewünschten Rechenschritte vornimmt.

Kann mir jemand helfen?

Vielen Dank im Voraus!

[shift-del]

Hallo

Da passt SUMMEWENN().

[Blödi]

Vielen Dank! Ich versuch mal mein Glück!

[Blödi]

Hmmm leider komm ich mit der Funktion der Lösung meines Problems nicht näher. 
Habe vergessen zu sagen dass ich Excel-Novize bin und mir die Syntax mühsam zurechtlegen muss, habe hier keine Automatismen wie die Profis.

Vielleicht kann mir auch die Wenn-Dann Funktion helfen?
Im Sinne von: Wenn der Wert in A4 dem Wert in A5 entspricht, dann Wert in B4 und B5 nicht aufrunden, sondern Summe in D 4 bilden. In D4 dann Wert aufrunden.

[lupo1]

Da sich das Datum nach Deinen Worten und Deinem Beispiel nur einmal wiederholen kann (!) und die Werte in A sortiert sind:

D2: =(A2=A1)*AUFRUNDEN((B2+B1)*2;)/2+(A2=A3)*AUFRUNDEN((B2+B3)*2;)/2 runterkopieren

[Blödi]

Vielen Dank für diese Formel! Ich werde sie gleich am Montag mal ausprobieren, wenn ich wieder in der Arbeit bin!

[atilla]

Hallo,

hier die Lösungsmöglichkeit mit Summewenn, wie von shift-del vorgeschlagen:

Arbeitsblatt mit dem Namen 'Tabelle5'
	A	B	C	D
1	01.06.2017	6,5	6,50	7
2	05.06.2017	4,75	5,00	5
3	15.06.2017	9,25	9,50	15
4	15.06.2017	5,64	6,00	15
5	22.06.2017	4,6	5,00	5

Zelle	Formel
D1	=AUFRUNDEN(SUMMEWENN($A$1:A102;A1;$B$1:B102);)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[lupo1]

D2: =WENNFEHLER(1/(1/(AUFRUNDEN(SUMME(INDEX(B:B;VERGLEICH(A2-1%;A:A)+1):INDEX(B:B;VERGLEICH(A2;A:A)))*2;)/2-C2))+C2;"")

für mehr als 2 gleiche Datümer (sortiert!)

EDIT: Attilas Formel ist viel schicker (Datümer können unsortiert sein!), allerdings leicht zu korrigieren auf gewünschte halbe Rundungen:
D2: =AUFRUNDEN(SUMMEWENN($A$1:A$99;A2;$B$1:B$99)*2;)/2

bzw. mit Unterdrückung neben Nicht-Wiederholern:
D2: =WENNFEHLER(1/(1/(AUFRUNDEN(SUMMEWENN($A$1:A$99;A2;$B$1:B$99)*2;)/2-C2))+C2;"")

Der Vorteil meiner Formel ergibt sich erst bei einer großen Datenmenge.

[lupo1]

Genauer:

Bei 10.000 Zeilen benötigt meine Formel knapp 1 Sekunde, die mit SUMMEWENN jedoch 24 Sekunden.
Bei 100.000 Zeilen benötigt meine Formel etwa 4 Sekunden, die mit SUMMEWENN jedoch ca. 2400 Sekunden.

Daher: Aufpassen mit SUMMEWENN! Entweder wenige SUMMEWENNs über viele Daten, oder viele SUMMEWENNs über wenige Daten.

[Blödi]

An beide von Euch, Lupo und Attila, ganz herzlichen Dank!!
Die Formeln funktionieren, habe jetzt alles mal durchgespielt, auch die Ergänzungen von Lupo in Attilas Formel haben sich gut bewährt.
Bei mir geht es nur um 10 Felder insgesamt, sodass die Formel von Attila ausreicht. Mit der Rundung um 0,5 gab es ein kleines Problem, welches sich durch Lupos Ergänzung der Formel beheben ließ.

Also nochmal ganz herzlichen Dank an beide!