Formel anpassen

[coemm]

Hallo all,

ich schaffe es leider nicht, eine Formel anzupassen 

Die Ausgangstabelle

	A	B	C
1	34	1	34
2		2	17

Zelle	Formel
B1	{=WENN(ISTFEHLER(KKLEINSTE(WENN(REST($A$1;ZEILE(INDIREKT("1:"&KÜRZEN($A$1^0,5))))=0;ZEILE(INDIREKT("1:"&KÜRZEN($A$1^0,5))));ZEILE()));"";KKLEINSTE(WENN(REST($A$1;ZEILE(INDIREKT("1:"&KÜRZEN($A$1^0,5))))=0;ZEILE(INDIREKT("1:"&KÜRZEN($A$1^0,5))));ZEILE()))}
C1	=WENN(ISTFEHLER(WENN(B1^2=$A$1;"";$A$1/B1));"";WENN(B1^2=$A$1;"";$A$1/B1))
B2	{=WENN(ISTFEHLER(KKLEINSTE(WENN(REST($A$1;ZEILE(INDIREKT("1:"&KÜRZEN($A$1^0,5))))=0;ZEILE(INDIREKT("1:"&KÜRZEN($A$1^0,5))));ZEILE()));"";KKLEINSTE(WENN(REST($A$1;ZEILE(INDIREKT("1:"&KÜRZEN($A$1^0,5))))=0;ZEILE(INDIREKT("1:"&KÜRZEN($A$1^0,5))));ZEILE()))}
C2	=WENN(ISTFEHLER(WENN(B2^2=$A$1;"";$A$1/B2));"";WENN(B2^2=$A$1;"";$A$1/B2))

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Die Zieltabelle

	A	B
1	Zahl
2	34
3	Teiler	Teiler
4	ab hier soll Spalte B hin	ab hier soll Spalte C hin

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[lupo1]

Spalte B und C in jeweils eine Zelle? Da stehen doch je 2 Werte.

Hast Du schon mal mit dem Bruch-Format iVm =TEXT() experimentiert (und dann Teile aus dem Ergebnis verwendet)? Vermutlich kommst Du da erheblich eleganter zum Ziel.

[coemm]

Spalte B und C in jeweils eine Zelle? Da stehen doch je 2 Werte.

Hast Du schon mal mit dem Bruch-Format iVm =TEXT() experimentiert (und dann Teile aus dem Ergebnis verwendet)? Vermutlich kommst Du da erheblich eleganter zum Ziel.

1. Die Teiler sollen ab Zeile 4 abwärts aufgeführt werden.
2. Die von mir verwendete Formel findet man im Internet, wenn man alle Teiler einer Zahl finden möchte. Siehe hier

[atilla]

Hallo Conny,

ich verstehe nicht ganz, was Du erreichen möchtest.
Aber vielleicht ist ja eine der Formeln zielführend.

Arbeitsblatt mit dem Namen 'Tabelle3'
	A	B
1	Zahl
2	34
3	Teiler	Teiler
4	1	34
5	2	1

Zelle	Formel
A4	{=KKLEINSTE(WENN(REST(A$2;ZEILE(INDIREKT("1:"&KÜRZEN(A$2^0,5))))=0;ZEILE(INDIREKT("1:"&KÜRZEN(A$2^0,5))));ZEILE(A1))}
B4	=INDEX(Tabelle2!$A$1:$C$20;VERGLEICH(Tabelle3!$A$2;Tabelle2!$A$1:$A$20;0)+ZEILE(B1)-1;SPALTE(C1))

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[lupo1]

Aha. Mit WENNFEHLER gekürzt. Gab es 2003 noch nicht. Falls Du xl2003- hast, behältst Du Deine Formel und ergänzst darin A1 zweimal:

A4: {=WENNFEHLER(KKLEINSTE(WENN(REST($A$2;ZEILE(INDIREKT("1:"&KÜRZEN($A$2^0,5))))=0;ZEILE(INDIREKT("1:"&KÜRZEN($A$2^0,5))));ZEILE(A1));"")}
B4: =WENNFEHLER($A$2/A4;"")

Beachte den im Original sträflicherweiser weggelassenen großgeschriebenen Bezug A1. Und {} kennst Du ...

[Jockel]

Hallo Conny, ich hatte das so verstanden..:

Arbeitsblatt mit dem Namen 'Die Zieltabelle'
	A	B
1	Zahl
2	34
3	Teiler	Teiler
4	1	34
5	2	17
6
7
8
9
10
11
12
13

Zelle	Formel
A4	=WENNFEHLER(KKLEINSTE('Die Ausgangstabelle'!B:B;ZEILE(A1));"")
B4	=WENN(A4="";"";VERWEIS(A4;'Die Ausgangstabelle'!B:C))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[coemm]

Danke an euch !

Mir war klar, dass ich in der Formel A1 durch A2 ersetzen muss, was ich nicht wusste war die Änderung von ZEILE() in ZEILE(A1).
Und ja, {} kenne ich!
Ich habe auch keinen Bezug zu einer anderen Tabelle, es ging mir nur um den anderen Tabellenaufbau.