Dieses Forum nutzt Cookies
Dieses Forum verwendet Cookies, um deine Login-Informationen zu speichern, wenn du registriert bist, und deinen letzten Besuch, wenn du es nicht bist. Cookies sind kleine Textdokumente, die auf deinem Computer gespeichert werden. Die von diesem Forum gesetzten Cookies werden nur auf dieser Website verwendet und stellen kein Sicherheitsrisiko dar. Cookies aus diesem Forum speichern auch die spezifischen Themen, die du gelesen hast und wann du zum letzten Mal gelesen hast. Bitte bestätige, ob du diese Cookies akzeptierst oder ablehnst.

Ein Cookie wird in deinem Browser unabhängig von der Wahl gespeichert, um zu verhindern, dass dir diese Frage erneut gestellt wird. Du kannst deine Cookie-Einstellungen jederzeit über den Link in der Fußzeile ändern.

Daten auflisten, die in allen (3) Spalten auftauchen
#1
Hallo zusammen,

ich habe eine Liste mit drei Spalten, in der verschiedene Daten des Jahres 2016 aufgelistet sind.

Ich möchte in einer separaten Spalte in nur die Daten haben, die in allen drei Ursprungsspalten auftauchen.

Auszug:
[
Bild bitte so als Datei hochladen: Klick mich!
]

In der Lösung sollten dann in der Spalte D jeweils einmal der 04.01.2016 und 05.01.2016 angezeigt und der 06.01.2016 NICHT, da dieses Datum nicht bei allen Kategorien aufgelistet ist.


Könnt ihr mir bitte helfen?
Vielen Dank und viele Grüße

Fredde
Antworten Top
#2
Hola,

mach dir eine Hilfsspalte:


Code:
=ZÄHLENWENNS($A$2:$A$4;A2;$B$2:$B$4;A2;$C$2:$C$4;A2)

und filtere nach 1.

Gruß,
steve1da
Antworten Top
#3
Danke für die schnelle Info, jedoch geht das für mein Beispiel nicht ganz auf. Habe mein Anliegen wohl nicht komplett/falsch dargestellt.

Es kann vorkommen, dass ein Datum (im Bsp. der 19.01.2016) bei allen drei Kategorien vorkommt, jedoch nicht in der gleichen Zeile.
Wie schaffe ich, das Daten, die bei allen Spalten vorkommen, aber evtl nicht in der gleichen Zeile berücksichtigt werden?

Meine Wunschvorstellung ist, dass in einer separaten Spalte die Daten, die dreimal vorkommen in chronologischer Reihenfolge aufgelistet werden.


DANKE im Voraus!


[
Bild bitte so als Datei hochladen: Klick mich!
]
Antworten Top
#4
Hola,

meine Formel mit der Hilfsspalte nach unten ziehen. Dann erscheint in jeder Zeile eine 1, wo ein Datum allen 3 Spalten vorkommt.
Zeig mal bitte eine Beispieldatei (kein Bild).

Gruß,
steve1da
Antworten Top
#5
D2: =SUMMENPRODUKT(--(ZÄHLENWENN(BEREICH.VERSCHIEBEN(D:D;;-SPALTE(A2:C2));A2)>0))*(A2<>A1)
- als Hilfsspalte
- und dann diese autofiltern =3. Dafür ist eine Zeile 1 mit Überschriften nötig (die Du vorliegen hast).
- Spalte A muss sortiert sein, oder NACH Spalte A muss sortiert sein (egal)!
Antworten Top
#6
Hallo,

da würde ich immer noch die Hilfsspaltenlösung mit ZÄHLENWENN anwenden:

Arbeitsblatt mit dem Namen 'Tabelle1'
 ABCDE
111.01.1613.02.1605.03.16022.01.16
220.01.1605.01.1624.01.16005.02.16
322.01.1627.03.1606.04.16121.02.16
405.02.1608.01.1619.01.16125.02.16
521.02.1606.04.1622.01.161 
625.02.1612.01.1605.02.161 
716.03.1615.02.1621.02.161 
821.03.1610.04.1625.02.160 
926.03.1622.01.1616.03.160 
1027.03.1605.02.1623.02.160 
1129.03.1621.02.1628.03.160 
1231.03.1625.02.1607.02.160 
1303.04.1616.03.1613.01.160 
1403.04.1607.03.1611.02.160 
1509.04.1603.02.1609.01.160 

ZelleFormel
D1=(ZÄHLENWENN(A:A;A1)+ZÄHLENWENN(B:B;A1)+ZÄHLENWENN(C:C;A1)=3)*1
E1=WENNFEHLER(AGGREGAT(15;6;($A$1:$A$15)/($D$1:$D$15=1);ZEILE(A1));"")
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg


Sortierung der Spalte A ist nicht notwendig.
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Antworten Top
#7
Hallo Fredde,

Edgars Formel (Spalte D) ist richtig, wenn die Daten innerhalb der einzelnen Spalten eindeutig sind. Der erste Summand ist hierbei aber nicht notwendig, da er immer 1 ist.

Folgende Formel ist möglich, auch wenn die Daten innerhalb der einzelnen Spalten nicht eindeutig sind.

Code:
=(ZÄHLENWENN(B:B;A1)>0)*(ZÄHLENWENN(C:C;A1)>0)
helmut

Für mich ist die Möglichkeit in Excel an Zellen und Bereichen Namen zu vergeben die wichtigste Funktionalität.
Sie macht Formeln und den VBA-code verständlicher. Für Makros gilt die Regel: "Nur über benannte Bereiche auf den Inhalt der Zellen zugreifen."
Und wofür sind Regeln da? Um nachzudenken bevor man sie bricht.





Antworten Top
#8
@Bosko:
Bei 2 gleichen Datümern in A:A (und einem Auftreten in C:C) werden bei Dir auch beide ausgeworfen, statt richtig keins. Bei 3 gleichen gar keines!

Bei 1 Datum in A:A und 2 gleichen in C:C (keins in B:B) wird es auch ausgeworfen.
Antworten Top
#9
Hallo lupo,

stimmt, aber das hat ego ja schon verbessert. Allerdings hat das Muster keine Doppler, somit gehe ich davon aus, dass das alles Unikate sind.
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Antworten Top
#10
Hallo,

wenn jedes Datum nur einmal "ausgeworfen" werden soll kann man diese Formel nutzen:


Code:
=(ZÄHLENWENN(B:B;A1)>0)*(ZÄHLENWENN(C:C;A1)>0)*(ZÄHLENWENN($A$1:A1;A1)=1)
helmut

Für mich ist die Möglichkeit in Excel an Zellen und Bereichen Namen zu vergeben die wichtigste Funktionalität.
Sie macht Formeln und den VBA-code verständlicher. Für Makros gilt die Regel: "Nur über benannte Bereiche auf den Inhalt der Zellen zugreifen."
Und wofür sind Regeln da? Um nachzudenken bevor man sie bricht.





Antworten Top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste