Excel überträgt falsches Datum

[plaze]

Hallo,

ich entschuldige mich vorab schon mal für meine Formulierungen. Ich bin Excel-Anfängerin und habe daher sicherlich nicht euren "Slang" drauf.
Dennoch wäre ich sehr froh, wenn ihr mir helfen würdet.  :100:

Also: ich habe zwei Tabellen.

Wenn in der ersten Tabelle in der Spalte D der Wert "Polytec" zu finden ist, soll die Zeile in die zweite Tabelle übertragen werden. Diese ist aufgebaut wie Tabelle 1.

Dazu benutze ich folgende Formel:

=WENN(ZÄHLENWENN(Übersicht!$D:$D;"Polytec") < ZEILE(A1);"";INDEX(Übersicht!A:A; KKLEINSTE(WENN(Übersicht!$D$1:$D$99="Polytec";ZEILE($1:$99));ZEILE(A1))))

Diese Übertragung und das "Herausziehen" der Zeile in die zweite Tabelle klappt super (dauert allerdings ewig, da die Prozessoren ganz schön rattern).
ALLERDINGS befinden sich Datums-Daten in der ersten Tabelle (Spalte L). Ist das Feld noch leer, wird nicht dieses leere Feld in die zweite Tabelle übertragen, sondern "00.01.1990". Das Feld soll allerdings leer bleiben.

Die Formatierung dieser Spalten ist in der Ausgangstabelle sowie in der zweiten Tabelle "Datum kurz".

Kann mir jemand dabei behilflich sein, dass das leere Feld in die zweite Tabelle übertragen wird und dieses nicht mit 00.01.1990 ausgefüllt wird?


Vielen Dank für eure Hilfe.

[BoskoBiati]

Hallo,

ungetestet:

Code:

=WENN(ZÄHLENWENN(Übersicht!$D:$D;"Polytec") < ZEILE(A1);"";wenn(INDEX(Übersicht!A:A; KKLEINSTE(WENN(Übersicht!$D$1:$D$99="Polytec";ZEILE($1:$99));ZEILE(A1)))=0;"";INDEX(Übersicht!A:A; KKLEINSTE(WENN(Übersicht!$D$1:$D$99="Polytec";ZEILE($1:$99));ZEILE(A1))))

man könnte auch Nullwert ausblenden, dann würde Deine Formel reichen.

[Jockel]

Hallo,

ich entschuldige mich vorab schon mal für meine Formulierungen. Ich bin Excel-Anfängerin und habe daher sicherlich nicht euren "Slang" drauf. :-P
Dennoch wäre ich sehr froh, wenn ihr mir helfen würdet.  :100:
...
folgende Formel:

=WENN(ZÄHLENWENN(Übersicht!$D:$D;"Polytec") < ZEILE(A1);"";INDEX(Übersicht!A:A; KKLEINSTE(WENN(Übersicht!$D$1:$D$99="Polytec";ZEILE($1:$99));ZEILE(A1))))

Diese Übertragung und das "Herausziehen" der Zeile in die zweite Tabelle klappt super (dauert allerdings ewig, da die Prozessoren ganz schön rattern).
...
Vielen Dank für eure Hilfe.

Hallo, ich würde a duf verite gnSpalten zu "beackern" - die Bereiche solten so groß, wie nötig, aber so klein, wie möglich sein... Zum Anderen würde ich hier auf zwei weitere Sachen verzichten. Auf den Teil..:

WENN(ZÄHLENWENN(Übersicht!$D:$D;"Polytec") < ZEILE(A1) Dafür kannst du WENNFEHLER(deine_formel;"") nehmen. Und: Ich würde AGGREGAT() benutzen; die Formel braucht man nicht speziell abzuschließen.

Mein Vorschlag..:

Code:

=WENNFEHLER(WENN(INDEX(Übersicht!$A$1:$A$100;AGGREGAT(15;6;ZEILE(Übersicht!$A$1:$A$100)/(Übersicht!$D$1:$D$100="polytec");ZEILE(A1)))=0;"";INDEX(Übersicht!$A$1:$A$100;AGGREGAT(15;6;ZEILE(Übersicht!$A$1:$A$100)/(Übersicht!$D$1:$D$100="polytec");ZEILE(A1))));"")

[plaze]

@BoskoBiati:

Vielen Dank für deine Lösung. Hat super geklappt!

@Jockel:


Als ich deine Formel in die Spalte A eingefügt habe, hat sie auch super funktioniert.
ABER als ich sie dann nach rechts in die anderen Spalten rüber ziehen wollte, zum Übertragen der Formel, hat sie sich leider nicht automatisch angepasst.
Das liegt aber wahrscheinlich an mir und meinem "Können".
Ich danke auch dir sehr!