Unterschiedliche Anzahl an Messpunkten über gleichen Zeitraum synchronisieren

[manuel]

Hallo, 

ich habe folgendes Problem:
Aus einer Versuchsreihe mit zusätzlicher Videoanalyse habe ich unterschiedliche Messdaten erhalten. 
In Spalte 1 ist der Kräfteverlauf mit z.B. 40 Werten abgebildet.
In Spalte 2 ist die zugehörige Dehnung mit insgesamt nur 17 Werten abgebildet (aus der Videoanalyse).

Beide Messungen gehen jeweils über exakt den gleichen Zeitraum, nur die Anzahl der Messungen in diesem Zeitraum variiert.
Ziel ist es, dass beide Spalten gleich viele Werte haben und in einem X,Y-Diagramm dargestellt werden können. 

Mit dieser Formel klappt es annäherungsweise, jedoch verändern sich Start- und Endwert und die Kurve verläuft steiler oder flacher:
=MITTELWERT(BEREICH.VERSCHIEBEN(A$1;(ZEILE(A1)-1)*FAKTOR;;FAKTOR))

Über den Faktor kann ich den Grad der "Zusammenstauchung" bestimmen und somit die Anzahl auf z.B. 20 Werte je Spalte verkleinern oder vergrößern. 
Jemand eine passende Idee?

WICHTIG: Start- und Endwerte MÜSSEN erhalten bleiben. (Startwert immer 0, Endwert maximale Kraft/Dehnung)

Ich habe mich schon dumm und dämlich gesucht, um hierzu eine passende Lösung zu finden. 

Vielen Dank für eure Hilfe!

Grüße, 
Manuel

[Gast 123]

Hallo Manuel

ich habe eine Zeilang überlegt wie man die Aufgabe lösen könnte und sende dir meine Messwert Verteilung Tabelle. Mich interessierte wie die Zahlenwerte sind, wenn man die Messreihen in 40/17 Steps aufteilt und sich die Teilergebnisse ansieht. Dabei viel mir auf das man die Zwischenwerte im 2/3 er Step oder 5er Step berechnen kann. Der Mittelwert beim 2/3er Step kommt nicht immer genau hin. Schau mal inweiweit dir diese Tabelle bei der Lösung helfen kann. 

Eine dazu passende Formel erstellen ist dann bitte deine Aufgabe. Formeln sind nicht mein Fachbereich.

mfg  Gast 123

[Ego]

Hallo Manuel,

warum willst du die Anzahl der Y-Werte fpr eine Messreihe künstlich reduzieren oder erweitern?

Du kannst doch für jede Kurve in einem XY-Diagramm sowohl den Bereich der X-Werte als auch den Bereich der Y-Werte gesondert angeben.

[manuel]

Hallo Manuel,

warum willst du die Anzahl der Y-Werte fpr eine Messreihe künstlich reduzieren oder erweitern?

Du kannst doch für jede Kurve in einem XY-Diagramm sowohl den Bereich der X-Werte als auch den Bereich der Y-Werte gesondert angeben.

Hallo Ego, 

Danke für deine Antwort. Das funktioniert leider nicht, da er dann nur in diesem Beispiel die ersten 17 Werte aus beiden Spalten benutzt und daraus eine Kurve zeichnet. 

@Gast 123
Vielen Dank auch für deine Antwort! Ich denke das bringt mich weiter. 
Ich setze mich nochmal dran. 


EDIT: 
Das Anpassen mit den Steps funktioniert, jedoch sind keine Regelmäßigkeiten in den Steps wenn ich sie jeweils dem nächsten Wert zu ordne.
Mal 3 und mal 4 steps ohne erkennbares Muster. 

Ein weiteres Problem, es sind über 200 Versuche mit jeweils unterschiedlichen Anzahlen von Werten. Wenn ich für jeden einzelnen Versuch das per Hand zuordnen würde, bin ich die nächsten 2 Jahre beschäftigt. 

Hat jemand noch eine Idee für eine passende Formel?
Bin leider Excel/Formeltechnisch nicht so fit. 

Grüße, 
Manuel

[Ego]

Hallo Manuel
 du hast geschrieben:

Das funktioniert leider nicht, da er dann nur in diesem Beispiel die ersten 17 Werte aus beiden Spalten benutzt und daraus eine Kurve zeichnet.

Das gilt nicht für ein XY-Diagramm. Siehe Anlage.

Für mich sieht es so aus als ob du ein Liniendiagramm nutzt. Dabei bist du sehr viel eingeschränkter.

[manuel]

Hallo Manuel
 du hast geschrieben:


Das gilt nicht für ein XY-Diagramm. Siehe Anlage.

Für mich sieht es so aus als ob du ein Liniendiagramm nutzt. Dabei bist du sehr viel eingeschränkter.

Ich möchte ja eine Kurve aus beiden Spalten.. 
Ich habe mal deine Datei modifiziert und meine Kurvenwerte angehängt und nach deinem Beispiel in einem Diagramm abgebildet. 
Spalte G - Y-Werte
Spalte H - X-Werte

Es werden jeweils nur die ersten 29 Werte genommen, egal wieviele Werte ich in Spalte G auswähle. 

1. und letzter Wert jeder Spalte sollen fest bleiben und dazwischen die Punkte in beiden Spalten sollen auf die gleiche Anzahl gebracht werden.

Grüße,
Manuel

[Ego]

Hallo manuel,

ich hatte deine Anfrage falsch verstanden. Ich dachte es sollten zwei Kurven über die Zeit angezeigt werden.

In der Anlage jetzt eine Interpolation der Werte mit der geringeren Anzahl.
Diese Interpolation ohne zusätzliche Zeitangaben macht aber nur dann Sinn, wenn in beiden Messreihen die Zeitabstände zwischen den einzelnen Messwerten immer gleich waren. Im anderen Fall müsten bei der Interpolation auch die Zeitpunkte berücksichtigt werden.

Interpolation:

PHP-Code:

=INDEX(Dehnung;GANZZAHL((A3-1)/(ANZAHL(Kraft)-1)*(ANZAHL(Dehnung)-1)+1))+
 REST((A3-1)/(ANZAHL(Kraft)-1)*(ANZAHL(Dehnung)-1)+1;1)*
    (INDEX(Dehnung;GANZZAHL((A3-1)/(ANZAHL(Kraft)-1)*(ANZAHL(Dehnung)-1)+2))
    -INDEX(Dehnung;GANZZAHL((A3-1)/(ANZAHL(Kraft)-1)*(ANZAHL(Dehnung)-1)+1))) 


[manuel]

Wow!!!
Vielen Dank Helmut! Das sieht sehr kompliziert aus, scheint aber genau das zu machen, was ich wollte!
Darauf wäre ich nie gekommen. 

Das Ganze wird für eine Arbeit benötigt und ich muss die Formel auch kurz beschreiben. 
Könntest du mir in kurzen Sätzen schildern was sie macht?
Letztendlich eine Interpolation der Daten von der Dehnung. 

Die Zeitabstände zwischen den einzelnen Messpunkten waren immer gleich. 

Vielen vielen Dank nochmal!
Das Suchen hat ein Ende  :19:


EDIT:

Eine letzte Frage:
Ich möchte gerne alle Messreihen auf 100 Werte interpolieren.
Also auch die Kräfte, wenn es zu viele oder zu wenige Punkte sind.
Geht das?
Ich muss dann von jeweils 6 Versuchen die Mittelwerte bilden, daher wird das benötigt.
Wenn das noch hinhaut ist alles perfekt.


Viele Grüße, 
Manuel

[Gast 123]

Hi  und  Danke,

wenn ich mir in Ruhe das Fachgespraech zwischen manuel und Ego ansehe muss ich kleinmütig zugeben wei wenig ich von der Materie verstehe. Aber es hat Spass gemacht mal meine Idee vorstellen zu dürfen. Wünsche euch viel Erfolg. Die Formel sieht auf meinem PC so aus. Könnt ihr daraus was lesen ??   (auf Landessprache eingestellt)  Ich arbeite lieber mit Makros, an die Befehle habe ich mich gewöhnt.   viele Grüsse an euch ....

PHP-Code:

=İNDİS(Dehnung;TAMSAYI((A5-1)/(BAĞ_DEĞ_SAY(Kraft)-1)*(BAĞ_DEĞ_SAY(Dehnun

g)-1)+1))+MOD((A5-1)/(BAĞ_DEĞ_SAY(Kraft)-1)*(BAĞ_DEĞ_SAY(Dehnung)-1)+1;1)

*(İNDİS(Dehnung;TAMSAYI((A5-1)/(BAĞ_DEĞ_SAY(Kraft)-1)*(BAĞ_DEĞ_SAY(Dehnun

g)-1)+2))-İNDİS(Dehnung;TAMSAYI((A5-1)/(BAĞ_DEĞ_SAY(Kraft)-1)*(BAĞ_DEĞ_SA

Y(Dehnung)-1)+1))) 


[Ego]

Hallo manuel,

Erst einmal zu der neuen Datei:

In der Anlage die Grafik in der beide Spalten berechnet werden.

Wenn in den Zellen A3:A102 die Zahlen von 1-100 stehen hier die Formeln für 100 interpolierte Werte:

Kraft:

Code:

=INDEX(Kraft;GANZZAHL(($A3-1)/99*(ANZAHL(Kraft)-1)+1))
 +REST(($A3-1)/99*(ANZAHL(Kraft)-1)+1;1)
   *(INDEX(Kraft;GANZZAHL(($A3-1)/99*(ANZAHL(Kraft)-1)+2))
    -INDEX(Kraft;GANZZAHL(($A3-1)/99*(ANZAHL(Kraft)-1)+1)))

Dehnung:

Code:

=INDEX(Dehnung;GANZZAHL(($A3-1)/99*(ANZAHL(Dehnung)-1)+1))
 +REST(($A3-1)/99*(ANZAHL(Dehnung)-1)+1;1)
   *(INDEX(Dehnung;GANZZAHL(($A3-1)/99*(ANZAHL(Dehnung)-1)+2))
    -INDEX(Dehnung;GANZZAHL(($A3-1)/99*(ANZAHL(Dehnung)-1)+1)))

Achtung: Damit der obere Grenzwert auch ermittelt werden kann muss die untere Zelle des  benannten Bereiches "Kraft" bzw "Dehnung" um eine Zeile grösser als der letzte Wert sein.

Jetzt zur Erklärung der Formel:

Sie ist eine einfache Interpolation und sieht nur dadurch komplexer aus, da ich in der einen Zelle auch die notwendigen Parameter (wiederholt) berechne. Im Prinzip steht dort:

Code:

UntererWert + Intervallanteil * (ObererWert-UntererWert)

Hierbei ist:

($A3-1)/99*(ANZAHL(Dehnung)-1) eine Umparametrierung von 99 Intervalle (100 Werte= 99 Intervalle) auf die Anzahl der Intervalle der Werte.

GANZZAHL(($A3-1)/99*(ANZAHL(Dehnung)-1)+1) die Position des unteren Wertes

GANZZAHL(($A3-1)/99*(ANZAHL(Dehnung)-1)+2) die Position des oberen Wertes

INDEX(Dehnung;GANZZAHL(($A3-1)/99*(ANZAHL(Dehnung)-1)+1)) der untere Wert und

REST(($A3-1)/99*(ANZAHL(Dehnung)-1)+1;1) der Intervallanteil zwischen unterem und oberen Wert.