BMI Auswertung

[Faym91]

Hallo zusammen,

Aktuell versuche ich aus den Daten einer Umfrage den bereits berechneten BMI mir auswerten zu lassen wie in der Tabelle unten zu sehen in Untergewicht, Normalgewicht, Übergewicht etc.
Nur merke ich leider das ich alleine dabei nicht weiterkomme und hoffe Ihr könnt mir helfen.

Vorab vielen Dank!


[img]
Dateiupload bitte im Forum! So geht es: Klick mich!
]

[Luffy]

Hallo,

Kannst du deine Umfrage Werte, bzw eine Beispieldatei hochladen ? Um zu sehen wie die Struktur deiner Tabelle ist

[Faym91]

Natürlich kommt sofort^^
Hier ist der betreffende Teil der Auswertung ( ich habe erstmal exemplarisch 4 Probanden eingepflegt)

[url=
Dateiupload bitte im Forum! So geht es: Klick mich!
]

[steve1da]

Hola,

Bildchen sind Mist, da die Daten in deiner Excel Datei mit Sicherheit woanders stehen als in unseren.

Edit: auch interessant: http://www.clever-excel-forum.de/thread-3037.html

Gruß,
steve1da

[Luffy]

Hi,

probier mal das:

Code:

=WENN(B2="m";WENN(G2<16;"Starkes Untergewicht";WENN(G2<17;"Mäßiges Untergewicht";WENN(G2<18,5;"leichts Untergewicht";WENN(G2<25;"Normalgewicht";WENN(G2<30;"Übergewicht (Präadipositas)";WENN(G2<35;"Adipositas (Fettleibigkeit) Grad I";WENN(G2<40;"Adipositas Grad II";"Adipositas Grad III")))))));WENN(G2<15;"Starkes Untergewicht";WENN(G2<16;"Mäßiges Untergewicht";WENN(G2<17,5;"leichts Untergewicht";WENN(G2<24;"Normalgewicht";WENN(G2<29;"Übergewicht (Präadipositas)";WENN(G2<34;"Adipositas (Fettleibigkeit) Grad I";WENN(G2<39;"Adipositas Grad II";"Adipositas Grad III"))))))))

edit: ich gehe davon aus dass das Geschlecht in Spalte B Steht und der BMI in Spalte G, und es ab Zeile 2 beginnt.

[Faym91]

Ah entschuldigung! Datei kommt :)

[Faym91]

Oh die Funktion klappt wunderbar.
Ich danke dir wirklich vielmals !!
Du hast mir so unglaublich viel Arbeit erspart, ich habe schon befürchtet ich muss das per Hand bei über 400 Probanden eingeben :D

[WillWissen]

Hi,

so geht's doch einfacher:

Tabelle1

	B	C	D	E	F	G	H	I	J	K
1	Geschlecht	Geburtsjahr	Alter	Größe	Gewicht	BMI	Gewichtsklasse
2	w	13.06.1999	17	1,8	80	24,691358	Übergewicht		m
3	m	08.09.2000	16	1,75	60	19,5918367	Normalgewicht		0	starkes Untergewicht
4	w	05.10.1990	25	1,89	50	13,9973685	starkes Untergewicht		16	mäßiges Untergewicht
5	w	02.09.1993	23	1,7	100	34,6020761	Adipoditas II		17	leichtes Untergewicht
6	m					24,99	Normalgewicht		18,5	Normalgewicht
7	m					25,1	Übergewicht		25	Übergewicht
8									30	Adipoditas I
9									35	Adipoditas II
10									39,9	Adipoditas III
11									w
12									0	starkes Untergewicht
13									15	mäßiges Untergewicht
14									16	leichtes Untergewicht
15									17,5	Normalgewicht
16									24	Übergewicht
17									29	Adipoditas I
18									34	Adipoditas II
19									38,9	Adipoditas III

Formeln der Tabelle

Zelle Formel H2 =WENN(B2="w";SVERWEIS(G2;$J$12:$K$19;2;1);SVERWEIS(G2;$J$3:$K$10;2;1))

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

[Jockel]

gelöscht, weil doppelt... ;-(

[Jockel]

Hallo Günter, oder ..:

Code:

=SVERWEIS(G2;WENN(B2="w";$J$12:$K$19;$J$3:$K$10);2;1)

oder auch..:

Code:

=VERWEIS(G2;WENN(B2="w";$J$12:$K$19;$J$3:$K$10))