Datenüberprüfung: Auswahl abhängig von vorheriger Auswahl

[schaluppi]

Hallo zusammen,

es geht um eine Datei zur Zeiterfassung. Für jeden Mitarbeiter gibt es eine Datei. Momentan gibt es ein Arbeitsblatt (Blatt 1), auf dem alle Projekte aus einer anderen Datei referenziert sind (externer Bezug). Auf Blatt 2 kann man nun in einer Spalte eines dieser Projekte im drop down Menü auswählen (Datenüberprüfung).

Natürlich ist nicht jeder Mitarbeiter in jedem Projekt. Ich würde also gerne die Auswahl personalisieren.
Auf Blatt 2 wird schon der Name des Mitarbeiters eingegeben (könnte ich auch in eine Auswahl ändern).
Mein Gedanke ist also, auf Blatt 1 hinter den Projekten pro Mitarbeiter eine Spalte zu erstellen, in der markiert wird, ob derjenige das Projekt in der Auswahl erhalten soll oder nicht und über die Namensangabe dann diese Auswahl zu treffen.

Hoffe ich habe das verständlich erklärt.
Lässt sich das möglichst ohne VBA irgendwie umsetzen?

[silex1]

Hallo,

ne anonymisierte Bsp.-Datei hilft beim helfen! :15:

[schaluppi]

Hier mal eine stark vereinfachte Beispieldatei.

Im Moment werden jedem MA alle Projekte zur Auswahl gegeben. Mein Wunsch wäre es eben, in Blatt "Projektliste" die Auswahl pro Mitarbeiter zu treffen*, die dann im ersten Blatt angezeigt wird.

*prinzipiell egal wie, ob mit Kreuzchen oder anders

edit: mal als .xlsx hochgeladen anstatt .xlsm

[Jockel]

Hallo, ich habe noch nicht verstanden, was du vorhast... Willst du den Mitarbeiter vorgeben und nur die Projekte in der Auswahl (Dropdown) haben, die mit einem x markiert sind..?

[IchBinIch]

Hi,

ich glaube das was Du vor hast, ist eine bedingte Gültigkeitsprüfung. Keine Ahnung ob das mit einer Gültigkeitsprüfung möglich ist.
Wenn in Tabelle "Projektliste" beim Mitarbeiter ein "x" für das jeweilige Projekt eingetragen ist, dann zeige in Tabelle "Time sheet" nach Auswahl eines Mitarbeiters in Zelle "C2" nur die für ihn eingetragegen Projekte in Spalte "D".
Habe ich das  so in etwa richtig verstanden?

Gruß
Ich

[IchBinIch]

Geht doch.

Gruß
Ich

[Jockel]

Hallo, ich hatte das so verstanden..:

Arbeitsblatt mit dem Namen 'Projektliste'
	A	B	C	D
1	Project Description	Mitarbeiter1	Mitarbeiter2	Mitarbeiter3
2	Projekt A	x		x
3	Projekt B	x	x
4	Projekt C	x	x
5	Projekt D	x	x	x

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Arbeitsblatt mit dem Namen 'Time sheet'
	A	B	C	D	E	F	G	H	I	J
1	Time sheet
2	Employee name		Mitarbeiter2
3
4	CW	Date	Day	Project description	Working hours		Projekt B		Projekt B
5	35	01.09.2016	Thursday	Projekt C	5		Projekt C
6	35	02.09.2016	Friday	Projekt D	4		Projekt D
7					9		#ZAHL!

Name	Bezug
Projekt_Auswahl	='Time sheet'!$G$4:INDEX('Time sheet'!$G:$G;VERGLEICH("*";'Time sheet'!$G:$G;-1))

Zelle	Formel
G4	=INDEX(Projektliste!$A$1:$A$5;AGGREGAT(15;6;ZEILE(Projektliste!$A$1:$A$5)/(INDEX(Projektliste!$B$1:$D$5;;VERGLEICH($C$2;Projektliste!$B$1:$D$1;0))="x");ZEILE(A1)))
I4	=$G$4:INDEX($G:$G;VERGLEICH("*";$G:$G;-1))
A5	=WENN(B5<>"";KALENDERWOCHE(B5;21);"")
C5	=WENN(B5<>"";TEXT(B5;"[$-409]TTTT");"")
G5	=INDEX(Projektliste!$A$1:$A$5;AGGREGAT(15;6;ZEILE(Projektliste!$A$1:$A$5)/(INDEX(Projektliste!$B$1:$D$5;;VERGLEICH($C$2;Projektliste!$B$1:$D$1;0))="x");ZEILE(A2)))
A6	=WENN(B6<>"";KALENDERWOCHE(B6;21);"")
C6	=WENN(B6<>"";TEXT(B6;"[$-409]TTTT");"")
G6	=INDEX(Projektliste!$A$1:$A$5;AGGREGAT(15;6;ZEILE(Projektliste!$A$1:$A$5)/(INDEX(Projektliste!$B$1:$D$5;;VERGLEICH($C$2;Projektliste!$B$1:$D$1;0))="x");ZEILE(A3)))
E7	=TEILERGEBNIS(109;E5:E6)
G7	=INDEX(Projektliste!$A$1:$A$5;AGGREGAT(15;6;ZEILE(Projektliste!$A$1:$A$5)/(INDEX(Projektliste!$B$1:$D$5;;VERGLEICH($C$2;Projektliste!$B$1:$D$1;0))="x");ZEILE(A4)))

Zelle	Gültigkeitstyp	Operator	Wert1	Wert2
C2	Liste		Mitarbeiter1;Mitarbeiter2;Mitarbeiter3
D5	Liste		=Projekt_Auswahl
D6	Liste		=Projekt_Auswahl

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[schaluppi]

@Jockel: Das geht genau in die richtige Richtung, muss ich mir mal anschauen, wenn ich die Zeit dazu finde. Vielen Dank.

@IchBinIch: Bei deiner Variante müsste ich pro Mitarbeiter jedes Projekt auflisten. Am saubersten finde ich es, wenn die Projektliste nur einmal gepflegt werden muss, vor allem da die Liste in der Originaldatei mit externem Bezug erstellt wird.