Dieses Forum nutzt Cookies
Dieses Forum verwendet Cookies, um deine Login-Informationen zu speichern, wenn du registriert bist, und deinen letzten Besuch, wenn du es nicht bist. Cookies sind kleine Textdokumente, die auf deinem Computer gespeichert werden. Die von diesem Forum gesetzten Cookies werden nur auf dieser Website verwendet und stellen kein Sicherheitsrisiko dar. Cookies aus diesem Forum speichern auch die spezifischen Themen, die du gelesen hast und wann du zum letzten Mal gelesen hast. Bitte bestätige, ob du diese Cookies akzeptierst oder ablehnst.

Ein Cookie wird in deinem Browser unabhängig von der Wahl gespeichert, um zu verhindern, dass dir diese Frage erneut gestellt wird. Du kannst deine Cookie-Einstellungen jederzeit über den Link in der Fußzeile ändern.

Aus "Sehr geehrter Herr" "Herrn machen"
#1
Hallo,

für die Excel-Experten wahrscheinlich eine einfach Aufgabe: Wie lautet die Formel wenn ich aus A1 = Herrn Jansen werden soll, aus A2 =  B2 leer bleiben soll  und aus A3 = Frau Adam werden soll?

[url=
Dateiupload bitte im Forum! So geht es: Klick mich!
]
[url=http://www.fotos-hochladen.net][/url]
Vielen lieben Dank für die Hilfe!
Antworten Top
#2
Hallo, dann fang ich mal an..:

Arbeitsblatt mit dem Namen 'Tabelle1'
 AB
1Sehr geehrter Herr Jansen,Herrn Jansen,
2Sehr geehrte Damen und Herren, 
3Sehr geehrte Frau Adam,Frau Adam,

ZelleFormel
B1=WENN(ISTZAHL(SUCHEN("Damen und";A1));"";WENN(ISTZAHL(SUCHEN("frau";A1));"Frau "&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));50);"Herrn"&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));50)))
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

P.S.: Änderung bei Sonderfällen..:

Zitat:=WENN(ISTZAHL(SUCHEN("Damen und";A1));"";WENN(ISTZAHL(SUCHEN("frau ";A1));"Frau "&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));50);"Herrn"&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));50)))
Gruß Jörg
ich muss mich erst wieder ganz langsam heran robben. Also bitte ich um Nachsicht

"Wer immer tut, was er schon kann, bleibt immer das, was er schon ist." - Henry Ford
[-] Folgende(r) 1 Nutzer sagt Danke an Jockel für diesen Beitrag:
  • Sefrie
Antworten Top
#3
(02.09.2016, 13:28)Jockel schrieb: Hallo, dann fang ich mal an..:

Arbeitsblatt mit dem Namen 'Tabelle1'
 AB
1Sehr geehrter Herr Jansen,Herrn Jansen,
2Sehr geehrte Damen und Herren, 
3Sehr geehrte Frau Adam,Frau Adam,

ZelleFormel
B1=WENN(ISTZAHL(SUCHEN("Damen und";A1));"";WENN(ISTZAHL(SUCHEN("frau";A1));"Frau "&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));50);"Herrn"&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));50)))
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

P.S.: Änderung bei Sonderfällen..:


Hallo,

unglaublich, hat funktioniert. Vielen Dank! Habe die Formel ausgeführt und nun ist mir noch aufgefallen, das ein Komma hinter dem Namen steht, also zB Herrn Müller,

Könntest du vielleicht die Formel noch einmal abändern? Vielen Dank im Voraus!
Antworten Top
#4
Hallo,

quick and dirty:

=WECHSELN(WENN(ISTZAHL(SUCHEN("Damen und";A1));"";WENN(ISTZAHL(SUCHEN("frau";A1));"Frau "&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));50);"Herrn"&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));50)));",";)
Gruß
Peter
Antworten Top
#5
Hallo, Peters Idee, ist schon cool...
Gruß Jörg
ich muss mich erst wieder ganz langsam heran robben. Also bitte ich um Nachsicht

"Wer immer tut, was er schon kann, bleibt immer das, was er schon ist." - Henry Ford
Antworten Top
#6
Hallo

Warum nicht einfach wechseln bis der Arzt kommt?
Code:
=WECHSELN(WECHSELN(WECHSELN(WECHSELN(A1;"Sehr geehrter ";"");"Sehr geehrte ";"");"Damen und Herren";"");",";"")
Grüsse
Detlef

Bitte keine PN!
Seit Nikolaus 2012 mit Excel 2010. Seit Ostern 2015 mit Office 365
Antworten Top
#7
Hallo Jockel,

wobei ich jetzt gerade festgestellt habe, dass deine erste Formel beim Herrn Frauenstein ein Problem hat. Die zweite Formel funktioniert bei diesem Beispiel.

Arbeitsblatt mit dem Namen 'Tabelle1'
 ABC
1Sehr geehrter Herr Jansen,Herrn JansenHerrn Jansen
2Sehr geehrte Damen und Herren  
3Sehr geeehrte Frau Adam,Frau AdamFrau Adam
4Sehr geehrte Frau Hermann,Frau HermannFrau Hermann
5Sehr geehrter Herr Frauenstein,Herrn FrauensteinFrau Frauenstein

ZelleFormel
B1=WENN(ISTZAHL(SUCHEN("Damen und";A1));"";WENN(ISTZAHL(SUCHEN("frau ";A1));"Frau"&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));VERWEIS(9^9;FINDEN(",";A1;SPALTE(1:1)))-SUCHEN("#";WECHSELN(A1;" ";"#";3)));"Herrn"&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));VERWEIS(9^9;FINDEN(",";A1;SPALTE(1:1)))-SUCHEN("#";WECHSELN(A1;" ";"#";3)))))
C1=WECHSELN(WENN(ISTZAHL(SUCHEN("Damen und";A1));"";WENN(ISTZAHL(SUCHEN("frau";A1));"Frau "&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));50);"Herrn"&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));50)));",";)
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

@Detlef: Die Ergebnisse deiner Formel passen nicht zu dem gewünschten Ergebnis mit Herrn und Frau:

Arbeitsblatt mit dem Namen 'Tabelle1'
 AB
1Sehr geehrter Herr Jansen,Herr Jansen
2Sehr geehrte Damen und Herren 
3Sehr geeehrte Frau Adam,Sehr geeehrte Frau Adam
4Sehr geehrte Frau Hermann,Frau Hermann
5Sehr geehrter Herr Frauenstein,Herr Frauenstein
6Sehr geehrter Frau Herrenstein,Frau Herrenstein

ZelleFormel
B1=WECHSELN(WECHSELN(WECHSELN(WECHSELN(A1;"Sehr geehrter ";"");"Sehr geehrte ";"");"Damen und Herren";"");",";"")
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg
Gruß
Peter
Antworten Top
#8
(02.09.2016, 14:18)Hydronaut schrieb: Hallo

Warum nicht einfach wechseln bis der Arzt kommt?
Weil ich einfach nicht grauf gekommen bin...?

Wobei nach der richtigen Anmerkung von Peter so heißen müßte..:

Code:
=WECHSELN(WECHSELN(WECHSELN(WECHSELN(A1;"Sehr geehrter Herr ";"Herrn ");"Sehr geehrte ";"");"Damen und Herren";"");",";"")
Gruß Jörg
ich muss mich erst wieder ganz langsam heran robben. Also bitte ich um Nachsicht

"Wer immer tut, was er schon kann, bleibt immer das, was er schon ist." - Henry Ford
Antworten Top
#9
(02.09.2016, 14:26)Peter schrieb: Hallo Jockel,

wobei ich jetzt gerade festgestellt habe, dass deine erste Formel beim Herrn Frauenstein ein Problem hat. Die zweite Formel funktioniert bei diesem Beispiel.

Hi Peter, jupp, ist mir auch aufgefallen...

Dann müsste es so..:

Code:
=WECHSELN(WENN(ISTZAHL(SUCHEN("Damen und";A1));"";WENN(ISTZAHL(SUCHEN("frau ";A1));"Frau "&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));50);"Herrn"&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));50)));",";"")
Gruß Jörg
ich muss mich erst wieder ganz langsam heran robben. Also bitte ich um Nachsicht

"Wer immer tut, was er schon kann, bleibt immer das, was er schon ist." - Henry Ford
Antworten Top
#10
(02.09.2016, 14:26)Peter schrieb: @Detlef: Die Ergebnisse deiner Formel passen nicht zu dem gewünschten Ergebnis mit Herrn und Frau:
Ach, das 'n' ist mir gar nicht aufgefallen.
Grüsse
Detlef

Bitte keine PN!
Seit Nikolaus 2012 mit Excel 2010. Seit Ostern 2015 mit Office 365
Antworten Top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste