Dieses Forum nutzt Cookies
Dieses Forum verwendet Cookies, um deine Login-Informationen zu speichern, wenn du registriert bist, und deinen letzten Besuch, wenn du es nicht bist. Cookies sind kleine Textdokumente, die auf deinem Computer gespeichert werden. Die von diesem Forum gesetzten Cookies werden nur auf dieser Website verwendet und stellen kein Sicherheitsrisiko dar. Cookies aus diesem Forum speichern auch die spezifischen Themen, die du gelesen hast und wann du zum letzten Mal gelesen hast. Bitte bestätige, ob du diese Cookies akzeptierst oder ablehnst.

Ein Cookie wird in deinem Browser unabhängig von der Wahl gespeichert, um zu verhindern, dass dir diese Frage erneut gestellt wird. Du kannst deine Cookie-Einstellungen jederzeit über den Link in der Fußzeile ändern.

Variables Minimum oder Maximum auslesen
#1
Hallo,

ich habe noch eine Frage. Ich habe einen Spalte "M" mit Aktienwerten von Zeile 1 bis 22461
In Spalte "O" lese ich aus, wann der aktuelle Wert der jeweiligen Zelle (hier M62)  um einen % Satz X (hier 1%) - überschritten wird. Dieser wirft mir dann die Zeile aus.
={MIN(WENN(M63:M$22461>=M62*1,001;ZEILE(M63:M$22461)))}

Z.B. Steht in Zelle M62 der Kurs 9.286,5
und in Zelle M65 der Kurs 9.300,3 - dies ist der erste Kurs in der Spalte der von der Zelle 62 an den Wert um da 1,001 fache übersteigt.
Ergebnis = 65
da ja der Wert in Zeile 65 steht

Nun möchte ich zusätzlich wissen - in welcher Zeile zwischen der Zelle 62 und der Zelle 65 das Minimum steht.
und dass dann aber Flexibel aus einer Formel die sich die jeweilige Grenze aus dem Zellwert aus Spalte O ausliest

Da die Werte ja von Zeile zu Zeile variiert ... hier mal als Bild
[
Bild bitte so als Datei hochladen: Klick mich!
]

Wie berechne ich die Werte in Spalte P ?

Herzlichen Dank für die Hilfe

:100:

LG
Maria
Antworten Top
#2
Hallo Maria,

... in P62: =VERGLEICH(MIN(M63:INDEX(M:M;O62));M63:M$22461;)+ZEILE() und Formel nach unten kopieren
Gruß Werner
.. , - ...
Antworten Top
#3
SUPER ... KLAPPT

DANKE - DU BIST SPITZE !!!!!!!!!!!! :45: :84: :84:

:18: :100:
Antworten Top
#4
Hallo Maria,

... wollte gestern eigentlich schon fragen, warum Du die Hilfsspaltenwerte in O ermittelst und in Spalte P nur die Zeilenwerte?

Die Hilfsspalte O ist für die Ermittlung Deiner Wunschergebnisse in Spalte P nicht notwendig und das (auch in Deiner Excelversion) ganz ohne {}-Formel.

Die Formel ohne Hilfssspalte O würde in P62 wie folgt lauten:

=VERGLEICH(MIN(M63:INDEX(M:M;VERGLEICH(0;INDEX(--(M63:M$22461 < M62*1,001););)+ZEILE())); M63:M$22461;)+ZEILE()

Die Ergebnisse dieser Formel (wie auch der mit der Hilfsspalte) würde am Ende der Datenauswertung teilweise #NV-Fehlermeldungen erzeugen, wenn es keine Datenwerte gibt die größer 1,001 des akt. Wertes sind.

Wenn Dich diese Fehlerwertergebnisse stören sollten, dann:

=WENN((M63="")+ISTNV(VERGLEICH(0;INDEX(--(M63:M$22461 < M62*1,001););));""; VERGLEICH(MIN(M63:INDEX(M:M;VERGLEICH(0;INDEX(--(M63:M$22461 < M62*1,001););)+ZEILE())); M63:M$22461;)+ZEILE())

oder eben gleich die Ausgabe der Werte aus M:

=WENN((M63="")+ISTNV(VERGLEICH(0;INDEX(--(M63:M$22461 < M62*1,001););));""; INDEX(M:M;VERGLEICH(MIN(M63:INDEX(M:M;VERGLEICH(0;INDEX(--(M63:M$22461 < M62*1,001););)+ZEILE())); M63:M$22461;)+ZEILE()))
Gruß Werner
.. , - ...
Antworten Top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste