Daten eingeben, benutzerdefiniert ausweisen
#1
Hallo Excel Gemeinde,
ich habe in kleines Problem. Ich möchte mit der excel-Liste im anhang meine aufwände zur bearbeitung einer Q-Meldung erfassen.  Folge Vorgehensweise:
1. Es gibt für die Bearbeitung der Aufwände verschiedene Leistungsarten siehe Eingabe Spalte C.
2. Unter Spalte B sind die Mitarbeiter aufgeführt, die in dem Bereich arbeiten und ihre Minuten unter der jeweiligen Q-Meldung erfassen. Z.B. MA Katja bearbeitet die Q-Meldung 200010000 und hat einen Logistigaufwand bearbeitet und dies dauerte 30 min. Jetzt hat aber auchnoch der Philipp einen Logistaigaufwand gehabt vom 30 min. so können halt verschiede zeiten für leitungsarten erfasst werden, immer zu einer Q-Meldung.
3. Jetzt nöchte ich gerne unter dem feld „auswertung“ dass:
a)            In Spalte A die Q-Meldung automatisch integriert ist,sobald unter dieser meldung eine             Leistungsart erbracht ist.
b)           Unter Spalte B immer die Sendnummer aus Feld „Eingabe“ B2 für jede Zeile angeziegt wird
c)            Unter Spalte C alle Leistungsarten die für die betreffende Q-Meldung angefallen sind, so wie                das beispielhaft und händisch engetragen istà auch automatisch
d)           Spalte D muss leer bleiben
e)           Das alle zeiten einer jeden Leistungsart pro Q-Meldung und aller Mitarbeiter unter spalte E    aufsummiert werden und als Dezimalzahl ausgewiesen wird. Z.B. Spalte E2 50min= 0,83H à               ausweis 0,83
f)            Unter spalte F muss für alle Leistungsarten die Einheit H stehen außer für die Leistungsart       QSCM11 dort M2.
 
Ich möchte möglichst zur im Feld „Eingabe“ die Zeiten händisch eintragen und die Liste so formatieren, dass das „Feld“ Auswertung möglichst automatische sich füllt.
Es gibt noch weiter Leistungsarten, die habe ich erstmal nicht mit aufgeführt!
Ich hoffe ich konnte das Problem und die Aufgabenstellung gut erläutern und freue mich über hilfestellungen. vllt gibt es da eine VBA Lösung???
 
Beste Grüße


Angehängte Dateien
.xlsm   Stundenerfassung_Abweichung.xlsm (Größe: 346,46 KB / Downloads: 5)
Antwortento top
#2
Hallo

Zu einer möglichen VBA-Lösung kann ich leider nichts beitragen aber ich vermute der Code wird auch nicht "leichter" sein als eine Formellösung.
Ich kann leider nur eine teilweise Lösung anbieten. Die orange-farbenen Zellen benötigen noch Formeln.


Eingabe

CLCMCNCO
1521
2
3
41230
5
6#NV#NV#NV
72#DIV/0!#DIV/0!
83#NV#NV
Formeln der Tabelle
ZelleFormel
CL1=SUMMENPRODUKT(--ISTZAHL(CL$6:CL$57))
CL4=F4
CL6{=WENN(ZÄHLENWENN(CL$5:CL5;1/((F6>0)/VERGLEICH($C6;$C$6:$C$57;0)))=0;1/((F6>0)/VERGLEICH($C6;$C$6:$C$57;0));NV())}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Auswertung

ABCDEFGHI
1Qualitätsmeldung SendstelleSLstArtEmpf/AuftragMengeMEEintrag n von Anzahl EinträgeAnzahl EinträgeSpalte
211234QSCM02Platzhalter50H151
311234QSCM03Platzhalter60H251
411234QSCM04Platzhalter30H351
511234QSCM07Platzhalter60H451
611234QSCM11Platzhalter4M2551
721234QSCM02Platzhalter90H122
821234QSCM04Platzhalter30H222
931234QSCM07Platzhalter15H113
Formeln der Tabelle
ZelleFormel
A2=INDEX(Eingabe!$CL$4:$FM$4;I2)
B2=Eingabe!B$2
C2{=INDEX(Eingabe!$C$6:$C$57;KKLEINSTE(WENN(ISTZAHL(INDEX(Eingabe!$CL$6:$FM$57;0;I2));INDEX(Eingabe!$CL$6:$FM$57;0;I2));G2))}
E2=SUMMENPRODUKT((Eingabe!$F$4:$CG$4=A2)*(Eingabe!$C$6:$C$57=C2)*Eingabe!$F$6:$CG$57)
F2=WENN(C2="QSCM11";"M2";"H")
H2=INDEX(Eingabe!$CL$1:$FM$1;I2)
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8
Wir sehen uns!
... shift-del
Hinweise zu meiner Hilfe in Foren
Excel Super-Funktionen: VERWEIS(), INDEX(), WAHL()
[-] Folgende(r) 1 Benutzer sagt Danke an shift-del für diesen Beitrag:
  • PhilippB.
Antwortento top
#3
Danke shift-del,

was ich nicht verstehe ist, was du bei der Eingabe von CL Bis C... zählst?


Beste Grüße
Antwortento top
#4
Hallo Philipp

Das ist mein Versuch die Duplikate rauszukegeln.
Wir sehen uns!
... shift-del
Hinweise zu meiner Hilfe in Foren
Excel Super-Funktionen: VERWEIS(), INDEX(), WAHL()
Antwortento top
#5
Ok,

Ich versuche mich mal weiter!

VG
Antwortento top
#6
Mit der Summenprodukt-Formel liegen wir schon ziemlich gut! Hat vllt noch jemand eine Idee? Spezial im Bezug auf die Auswertung?

VG
Antwortento top
#7
ích komme nicht weiter,

unter dem Feld Auswertung Spalte "I" soll er die Q-Meldung ausweisen, unter der alles eine Leristungsart verbucht worden ist. In Spalte "G" sollen dann die Leistungsarten ausgewiesen werden, die verbucht worden ist... gibt es da möglichkeiten? 

BG


Angehängte Dateien
.xlsm   Stundenerfassung_Abweichung_2.xlsm (Größe: 349,83 KB / Downloads: 2)
Antwortento top
#8
Bahnhof?

Bisher waren das Spalte A und C und dafür habe ich Formeln genannt.
Wir sehen uns!
... shift-del
Hinweise zu meiner Hilfe in Foren
Excel Super-Funktionen: VERWEIS(), INDEX(), WAHL()
Antwortento top
#9
richtig, ich hatte da einen Fehler,

soweit wie du es beschrieben hast, bin ich jetzt auch.. Habe das mal angefügt. Probiere mich weiter!

Vllt hat noch jemand eine weitere idee?

VG


Angehängte Dateien
.xlsm   Stundenerfassung_Abweichung.xlsm (Größe: 349,88 KB / Downloads: 2)
Antwortento top
#10
Für die restlichen Spalten gibt es jetzt auch Formeln. Spalte H ist jetzt überflüssig.

Auswertung

ABCDEFGHI
1Qualitätsmeldung SendstelleSLstArtEmpf/AuftragMengeMEEintrag n von Anzahl EinträgeAnzahl EinträgeSpalte
211234QSCM02Platzhalter50H11
311234QSCM03Platzhalter60H21
411234QSCM04Platzhalter30H31
511234QSCM07Platzhalter60H41
611234QSCM11Platzhalter4M251
721234QSCM02Platzhalter90H12
821234QSCM04Platzhalter30H22
931234QSCM07Platzhalter15H13
Formeln der Tabelle
ZelleFormel
A2=INDEX(Eingabe!$CL$4:$FM$4;I2)
B2=Eingabe!B$2
C2{=INDEX(Eingabe!$C$6:$C$57;KKLEINSTE(WENN(ISTZAHL(INDEX(Eingabe!$CL$6:$FM$57;0;I2));INDEX(Eingabe!$CL$6:$FM$57;0;I2));G2))}
E2=SUMMENPRODUKT((Eingabe!$F$4:$CG$4=A2)*(Eingabe!$C$6:$C$57=C2)*Eingabe!$F$6:$CG$57)
F2=WENN(C2="QSCM11";"M2";"H")
G2=ZÄHLENWENN(I$2:I2;I2)
I2=WENN(ZEILE()=2;1;WENN(SUMME(INDEX(Eingabe!$CL$1:$FM$1;1):INDEX(Eingabe!$CL$1:$FM$1;I1))>ZEILE()-2;I1;I1+1))
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8
Wir sehen uns!
... shift-del
Hinweise zu meiner Hilfe in Foren
Excel Super-Funktionen: VERWEIS(), INDEX(), WAHL()
[-] Folgende(r) 1 Benutzer sagt Danke an shift-del für diesen Beitrag:
  • PhilippB.
Antwortento top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste