Hallöchen,
ohne Makrokenntnisse ist das nicht ganz so einfach.
Gehe mit der Tastenkombination ALT+F11 in den VBA-Editor.
Dort siehst Du auf der linken Seite den Projektexplorer. Du musst dort eventuell Deine Datei auswählen / anklicken.
Gehe dann in die Menüleiste, Menü Einfügen | Modul
Du solltest jetzt auf der rechten Seite ein leeres, weißes "Blatt" erhalten. Dort fügst Du folgenden Code ein:
Code:
Option Explicit
Sub FilterAuslesen()
'Variablendeklarationen
'Objekte
Dim objWS1 As Worksheet
Dim objWS2 As Worksheet
Dim objFLT As Filter
'Integer
Dim iCnt%
'Tabellenblatt 1 an Objektvariable uebergeben
Set objWS1 = Worksheets("Tabelle1")
Set objWS2 = Worksheets("Tabelle2")
'1. Spalte des gefilterten Bereichs
iCnt = 1
'Schleife ueber alle aktiven Filter
For Each objFLT In objWS1.AutoFilter.Filters
'Wenn ein Filter gesetzt ist, dann
If objFLT.On = True Then
'Wenn ein zweites Kriterium gesetzt ist -
'feststellbar ueber Operator (UND / ODER)
If objFLT.Operator Then
'Filter mit 2 Kriterien setzen, Einstellungen aus erster Tabelle uebernehmen
objWS2.Cells(objWS1.AutoFilter.Range.Cells(1, iCnt).Column).AutoFilter Field:=iCnt, Criteria1:= _
objFLT.Criteria1, Operator:=objFLT.Operator, Criteria2:=objFLT.Criteria2
'oder wenn nur ein Kriterium gesetzt ist
Else
'Filter mit 1 Kriterium setzen, Einstellungen aus erster Tabelle uebernehmen
objWS2.Cells(objWS1.AutoFilter.Range.Cells(1, iCnt).Column).AutoFilter Field:=iCnt, Criteria1:=objFLT.Criteria1
'Ende Wenn ein zweites Kriterium gesetzt ist -
End If
'Ende Wenn ein Filter gesetzt ist, dann
End If
'Spaltenzaehler hochsetzen
iCnt = iCnt + 1
'Ende Schleife ueber alle aktiven Filter
Next
End Sub
Du musst eventuell die Tabellennamen in diesen beiden Zeilen anpassen:
Set objWS1 = Worksheets("Tabelle1")
Set objWS2 = Worksheets("Tabelle2")
Das Makro überträgt erst mal die Einstellungen in einer Richtung auf ein zweites Blatt. Es dürfte nicht funktionieren, wenn mehrere Filterbereiche auf einem Blatt sind. Die Listen müssen bei diesem Code auf beiden Tabellenblättern an gleicher Stelle stehen.
Um das Makro zu testen, setzt Du den Cursor irgendwo zwischen Sub... und End Sub und drückst die F5-Taste. Dann schaust Du auf die Blätter. Falls eine Fehlermeldung kommt, postest Du bitte den Wortlaut der Meldung hier. Wenn nicht, auch gut. Dann schauen wir weiter, wie wir das in zwei Richtungen hinbekommen und das es automatisch läuft.
